[Resolvido]Erro Ao Filtrar Tabela Utilizando ComboBoxes

Bom dia.
Mais uma vez preciso da ajuda de vocês!

Possuo um formulário do tipo Dynaset chamado frmRota, onde existem diversos ComboBoxes que eu utilizo para filtrarem a tabela existente nesse formulário. Inclusive fui ajudado aqui no MaximoAccess a construir o código de filtro desses ComboBoxes.

Meu problema é o seguinte: Existem 3 Combos que estão com erro e não consigo determinar o que está errado. Quando eu tento filtrar um valor utilizando algum deles, aparece o seguinte erro:

"Erro em Tempo de Execução'3709':
A chave de pesquisa não foi encontrada em nenhum registro."

Eles são:
cboContrato
cboProtocolo
cboDataEntrega


Abaixo segue o link do projeto:
Sistema.zip
(a senha é 2393)


Desde já agradeço!

Bom dia

Supply.accdb, está a pedir password

Ops, desculpa!
Senha: 2393

Altere esta parte, copia e cola mas primeiro fazer cópia do seu form "frmRota"


'---------------------------------
Private Sub FiltraSubform()
Dim strWhere As String

'1? combo
If Nz(Me.cboModelo, "") <> "" Then
strWhere = strWhere & "[Modelo] = '" & Me.cboModelo & "' AND "
End If
'2? combo
If Nz(Me.cboPlantaInstalada, "") <> "" Then
strWhere = strWhere & "[PlantaInstalada] = '" & Me.cboPlantaInstalada & "' AND "
End If
'3? combo
If Nz(Me.cboEmpresa, "") <> "" Then
strWhere = strWhere & "[Empresa] = '" & Me.cboEmpresa & "' AND "
End If
'4? combo (tem q ser exact match)
If Nz(Me.cboRua, "") <> "" Then
strWhere = strWhere & "[Rua] = '" & Me.cboRua & "' AND "
End If
'5? combo
If Nz(Me.cboStatus, "") <> "" Then
strWhere = strWhere & "[Status] = '" & Me.cboStatus & "' AND "
End If
'6? combo
If Nz(Me.cboContrato, "") <> "" Then
strWhere = strWhere & "[Contrato] = " & Me.cboContrato & " AND "
End If
'7? combo
If Nz(Me.cboPorcentagemToner2, "") <> "" Then
strWhere = strWhere & "[VidaUtilToner] = '" & Me.cboPorcentagemToner2 & "' AND "
End If
'8? combo
If Nz(Me.cboHorario, "") <> "" Then
strWhere = strWhere & "[Horario] = '" & Me.cboHorario & "' AND "
End If
'9? combo
If Nz(Me.cboProtocolo, "") <> "" Then
strWhere = strWhere & "[Protocolo] = " & Me.cboProtocolo & " AND "
End If
'10? combo
If Nz(Me.cboDataEntrega, "") <> "" Then
Dim DataFormatada As String
DataFormatada = Format(Me.cboDataEntrega, "Short Date")
strWhere = strWhere & "[DataEntrega] =# " & Me.cboDataEntrega & "# AND "



End If
'11? combo
If Nz(Me.cboDeptoAlmox, "") <> "" Then
strWhere = strWhere & "[DeptoAlmox] = '" & Me.cboDeptoAlmox & "' AND "
End If

'aplica os filtros
If strWhere <> "" Then
strWhere = Left(strWhere, Len(strWhere) - 5)
Me.Filter = strWhere
Me.FilterOn = True
strCondicao = strWhere
Else
Me.Filter = ""
Me.FilterOn = False
strCondicao = ""
End If
End Sub

Funcionou com cboContrato e cboProtocolo! Só tem um problema, quando filtra o cboDataEntrega nunca consegue aparecer nenhum registro, sempre aparece em branco.

E eu filtrei o cboDataEntrega logo após ter filtrado o cboContrato e apareceu a seguinte mensagem:

"Tipo de dados incompatível na expressão de critério"

Isaac Oliveira

No meu PC não tenho esse problema

Teste, este BD só tem o "formRota"

Muito obrigado!!
Acho que devo ter colado errado o código antes, agora funcionou perfeitamente!!!

Reabri o tópico por causa de um detalhe que deixei passar:

Exemplo: Se eu filtro a data 15/05/2018, tudo bem, filtra normalmente (porque nao existe data 05/15/2018)
Mas se eu filtro por exemplo 11/05/2018
aparecem resultados com o dia 05/11/2018




O que pode estar errado neste caso?
Desde já obrigado!

Formate a data

# & format([SeuCampoData],"mm/dd/yyyy") & #

Exemplo do seu caso

If Nz(Me.cboDataEntrega, "") <> "" Then
strWhere = strWhere & "[DataEntrega] = #" & Format(Me.cboDataEntrega, "mm/dd/yyyy") & "# AND "
End If

Isso!
Obrigado denovo!
Já marquei novamente como resolvido!

Isaac

Obrigado pelo retorno.

Ivan, obrigado pela ajuda.