[Resolvido]Como tornar oculto os objetos (Form, Report, Module, Macros)

Olá pessoal!
Como tornar oculto os objetos (Form, Report, Module, Macros)?

Para tabelas e consulta eu já saquei. Exemplo:
----- TABLES -----
Dim Tb As TableDef
For Each Tb In CurrentDb.TableDefs
If Tb.Name Like "~*" Then
Else
Application.SetHiddenAttribute acTable, Tb.Name, True 'ou False depende se quer ocultar ou não
End If
Next Tb

----- CONSULTA -----
Dim qdf As QueryDef
For Each qdf In CurrentDb.QueryDefs
If qdf.Name Like "~*" Then
Else
Application.SetHiddenAttribute acQuery, qdf.Name, False 'ou True depende se quer ocultar ou não
End If
Next qdf

E para Formulários, Módulos e Macros? Como fazer?

Desde já agradeço!
Paulo César

Para forms:


Application.SetHiddenAttribute acForm, "NomedoSeuFormulário", True 'ou False depende se quer ocultar ou não

Para relatorios:

Application.SetHiddenAttribute acReport, "NomedoSeuRelatorio", True 'ou False depende se quer ocultar ou não

Para módulos tente:

Application.SetHiddenAttribute acModule, "NomedoSeuModulo", True 'ou False depende se quer ocultar ou não

Cumprimentos.

Para utilização no exemplo que enviou:

Form.Name
Report.Name
Module.Name

Ira fazer um loop por todos os objetos segundo o código.


Cumprimentos.

Qual é o objetivo disso ?

Bom dia a todos;

Também gostaria de saber qual o objetivo.

Numa duvida postada aqui em 2009, eu dei este código, veja se ainda funfa;

Para chamar a função:

Esconde:
Call EscondeFormsReportsModulesMacros(True)


Mostra:
Call EscondeFormsReportsModulesMacros(False)

Public Function EscondeFormsReportsModulesMacros(vbln As Boolean)

Dim obj As AccessObject
Dim dbs As Object
Dim db As Database
Dim T As TableDef
Dim TName As String
Dim I As Integer
Dim vCnt As Integer

Set dbs = Application.CurrentProject
Set db = CurrentDb()

    'Esconde formularios
    For Each obj In dbs.AllForms
    Application.SetHiddenAttribute acForm, obj.Name, vbln
    Next obj
    
    'Esconde relatorios
    For Each obj In dbs.AllReports
    Application.SetHiddenAttribute acReport, obj.Name, vbln
    Next obj
    
    'Esconde modulos
    For Each obj In dbs.AllModules
    Application.SetHiddenAttribute acModule, obj.Name, vbln
    Next obj
    
    'Esconde macros
    For Each obj In dbs.AllMacros
    Application.SetHiddenAttribute acMacro, obj.Name, vbln
    Next obj
    
    'Esconde consultas
    Set dbs = Application.CurrentData
    For Each obj In dbs.AllQueries
    Application.SetHiddenAttribute acQuery, obj.Name, vbln
    Next obj
    
    'Esconde tabelas
    For I = 0 To db.TableDefs.Count - 1
    Set T = db.TableDefs(I)
    TName = T.Name
    If Not TName Like "msys*" Then
    On Error Resume Next
    Application.SetHiddenAttribute acTable, TName, vbln
    vCnt = vCnt + 1
    End If
    Next I
End Function