Criar botão salvar em subformulário

Olá Amigos, sou novo no fórum e novo em VBA Access, me u problema é:
Tenho um Formulário com subformulário em um aplicativo de pedidos, o que quero é que quando o usuário finalizar o pedido o mesmo clique em um botão SALVAR, e o mesmo grave em uma outra tabela não vinculada ao Formulário/SubFormulário. No botão salvar do Formulário consegui fazer com êxito, mas o do subformulário não consigo, pois preciso gravar todas as linhas referentes ao pedido em andamento, segue abaixo o código do botão Salvar do Formulário:
Private Sub Botao_Salvar_Pedido_Click()
'Salvar dados da tabela T_Alimport_Pedidos e uma Tabela de Comissões
Dim r As DAO.Recordset
Set r = CurrentDb.OpenRecordset("T_Alimport_Pedido_Enviado")
r.AddNew
r![Nro_Pedido] = Me.Nro_Pedido
r![Data] = Me.Data
r![FantasiaRep] = Me.FantasiaRep
r![RazaoSocialCli] = Me.RazaoSocialCli
r![Cond_Pgto] = Me.Cond_Pgto
r![NomeCons] = Me.NomeCons
r.Update
r.Close
Set r = Nothing
PedEnviado = True
Me.PedEnviado.Visible = True
Me.Rótulo99.Visible = True
MsgBox ("Pedido Enviado com sucesso!!!")
End Sub

E agora a do Subformulário que não está correto:


Private Sub BtnSalvarItens_Click()
Dim s As DAO.Recordset
Set s = CurrentDb.OpenRecordset("T_Alimport_Itens_Enviados")
s.AddNew
s![Nro_Linha_Pedido] = Me.Nro_Linha_Pedido
s![Nro_Pedido] = Me.Nro_Pedido
s![Qtde] = Me.Qtde
s![Alimport_Id] = Me.Alimport_Id
s![TotProdA3] = Me.TotProdA3
s.Update
s.Close
Enviado = True
Set s = Nothing
MsgBox ("Itens Salvos com sucesso!!!")
End Sub

Não sei se consegui me expressar de modo a entender, mas espero ajuda dos amigos.

Olá, seja bem vindo ao fórum! Você quer salvar em uma tabela dados que já estão em outra? Talvez fosse melhor alterar a estrutura do aplicativo para não ter dados duplicados se bem entendi. Pois se os dados já estão em um subformulário, imagina-se que eles já estejam salvos em uma tabela. Se não é isso, explique com mais detalhes por gentileza.

Criquio, tenho duas tabelas uma com o cabeçalho do pedido e outra com os detalhes do pedido. Criei outras duas tabelas, para salvar apenas alguns campos de cada uma das tabelas citadas acima. Pois usarei os dados gravados nestas outras tabelas para conferência de comissões futuras. O que não dá para fazer com os dados nas tabelas vinculadas ao formulário, pois toda a semana recebo tabelas das empresas que sempre alteram valores de produtos, produtos saem de linha, etc.

Tente pegar os dados direto da tabela, utilizando dois Recordsets e filtrando pelo código do registro principal:

Código:

Private Sub BtnSalvarItens_Click()

Dim sO As DAO.Recordset, sD As DAO.Recordset

Set sO = CurrentDb.OpenRecordset("SELECT * FROM NomeDaTabelaDeOrigem WHERE Código=" & Me.Código & "")
Set sD = CurrentDb.OpenRecordset("NomeDaTabelaDeDestino")

Do Wbile Not sO.EOF

sD.AddNew

sD![Nro_Linha_Pedido] = sO!Nro_Linha_Pedido
sD![Nro_Pedido] = sO!Nro_Pedido
sD![Qtde] = sO!Qtde
sD![Alimport_Id] = sO!Alimport_Id
sD![TotProdA3] = sO!TotProdA3

sD.Update
sO.MoveNext
Loop

sD.Close
Enviado = True
Set sD = Nothing
MsgBox ("Itens Salvos com sucesso!!!")

sO.Close
Set sO = Nothing

End Sub

Vou tentar desta forma, posto o resultado!!

Obrigado

Criquio, a rotina que você me passou roda direitinho, a unica coisa que não consigo, e não sei se é possível, é que um dos campos do subformulário (TotProdA3), é um resultado retirado de uma consulta, assim ele não faz parte da tabela, e quando mando gravar na tabela ele grava o valor da ultima linha para todos os registros.

Possível é. Talvez fosse o caso de se criar um terceiro Recordset depois da linha Do While... para filtrar da consulta de acordo o registro atual dentro do Do While, mas se esse campo é um cálculo, talvez seja melhor não gravá-lo na tabela. Cálculos podem ser feitos em tempo de execução nos formulários ou relatórios, sem a necessidade de ocupar espaço em tabelas.