[Resolvido]autocomplentar ou inserir registro

Private Sub CodCliente_NotInList(NewData As String, Response As Integer)
On Error GoTo Trato

Response = acDataErrContinue

If Confirmar("Deseja adicionar  " & NewData & "  automaticamente ao cadastro de Clientes?" & vbCrLf & _
                "Lembre que para imprimir documentos outros dados deverão ser adicionados ao cadastro.") Then
    If CurrentProject.AllForms("for_Clientes").IsLoaded Then DoCmd.Close acForm, "for_Clientes", acSavePrompt

    Dim db As Database
    Dim rs As DAO.Recordset
    Set db = CurrentDb
    Set rs = db.OpenRecordset("tab_Clientes")
    rs.AddNew
    rs!NomeCliente = NewData
    rs.Update
    rs.Close
    Set rs = Nothing
    db.Close
    Set db = Nothing
    Response = acDataErrAdded
Else
    Me.CodCliente.Undo
    If Not Confirmar("Deseja abrir o cadastro de Clientes e cadastrar agora?") Then Exit Sub
    If CurrentProject.AllForms("for_Clientes").IsLoaded Then
        If Confirmar("O formulário já está aberto." & vbCrLf & _
                         "Deseja alternar para o cadastro de Clientes?") Then Forms!for_Clientes.SetFocus
    Else
        DoCmd.OpenForm "for_Clientes"
        DoCmd.GoToRecord , "", acNewRec
    End If
End If

Exit Sub
Trato: MsgBox Err.Description
End Sub

'Faz uma pergunta ao usuário e retorma True se a resposta for SIM, e false se a resposta for NÃO
Public Function Confirmar(sMensagem As String) As Boolean
Dim intResp As Integer
intResp = MsgBox(sMensagem, vbYesNo + vbQuestion, "Confirmação")
If intResp = vbYes Then
    Confirmar = True
Else
    Confirmar = False
End If
End Function

Private Sub CodCliente_NotInList(NewData As String, Response As Integer)
On Error GoTo Trato
Response = acDataErrContinue
If Not Confirmar("Deseja abrir o cadastro de Clientes e cadastrar agora?") Then Exit Sub
If CurrentProject.AllForms("for_Clientes").IsLoaded Then
    If Confirmar("O formulário já está aberto." & vbCrLf & _
                     "Deseja alternar para o cadastro de Clientes?") Then Forms!for_Clientes.SetFocus
Else
    DoCmd.OpenForm "for_Clientes"
    DoCmd.GoToRecord , "", acNewRec
    Forms!for_Clientes.NomeCliente = NewData
End If
End Sub