[Resolvido]Replace arquivo CSV

Boa noite!
Preciso abrir um arquivo csv e fazer um replace, mas não sei porque cargas d'agua nao está funcionando.
Ja fiz meu codigo na unha, nao funcionou, ja achei inumeros codigos, inclusive um aqui e tambem não resolveu.
Na verdade se o excel 2016 ja salvasse em utf-8 separado com virgula, como ele diz, mas salva como ponto e virgula, nao precisaria de nada disso.
Mudei nas configurações regionais do win10 o delimitador, tambem nao resolveu.
Alguma dica?

Att
Luciano

Código:

Option Compare Database
Option Explicit
Public Sub LeArquivoTexto()
    Dim Arquivo As Integer
    Dim CaminhoArquivo As String
    Dim TextoArquivo As String
    Dim TextoProximaLinha As String
    Dim ContadorLinha As Long
     'Configura a leitura do arquivo
    Arquivo = FreeFile
    CaminhoArquivo = "d:\frm_01_demanda_bi.csv"
     'Abre o arquivo para leitura
    Open CaminhoArquivo For Input As Arquivo
    ContadorLinha = 1
    'Lê o conteúdo do arquivo linha a linha
    Do While Not EOF(Arquivo)
        Line Input #Arquivo, TextoProximaLinha
        TextoProximaLinha = Replace(TextoProximaLinha, ";", ",") & vbCrLf
        TextoArquivo = TextoArquivo & TextoProximaLinha
    Loop
     'Coloca na janela de verificação imediata
    Debug.Print TextoArquivo
     'Fecha o arquivo
    Close Arquivo
End Sub


CROSS/SISREG,Origem,Procedimento,Demanda,Data primeira entrada,Tempo de espera primeiro,Data ultima entrada,Tempo de espera ultimo
CROSS,CROSS-ESPECIALIDADE-AGENDAMENTO CR,ALERGOLOGIA,1,25-set-23,0,25-set-23,0
CROSS,CROSS-ESPECIALIDADE-AGENDAMENTO CR,CARDIOLOGIA,1,25-set-23,0,25-set-23,0
CROSS,CROSS-ESPECIALIDADE-AGENDAMENTO CR,CARDIOLOGIA - AVALIACAO MARCA-PASSO,1,17-mai-23,131,17-mai-23,131
CROSS,CROSS-ESPECIALIDADE-AGENDAMENTO CR,CARDIOLOGIA PEDIATRICA,4,21-jun-23,96,20-set-23,5
CROSS,CROSS-ESPECIALIDADE-AGENDAMENTO CR,CIRURGIA CABECA E PESCOCO,1,17-nov-22,312,17-nov-22,312
CROSS,CROSS-ESPECIALIDADE-AGENDAMENTO CR,CIRURGIA ELETIVA - AVALIACAO ARRITMIA CARDIACA,1,11-mai-23,137,11-mai-23,137

Teste por favor;

Código:

Sub SubstituirTexto()
    On Error GoTo E_Handle
    Dim intInFile As Integer
    Dim strOutFile As String
    Dim intOutFile As Integer
    Dim strInput As String
   
'caminho e ficheiro original
  strInFile = "d:\frm_01_demanda_bi.csv"

    intInFile = FreeFile
    Open strInFile For Input As intInFile
'caminho e ficheiro original renomeado para poder salvar
    strOutFile = "d:\frm_01_demanda_bi_NEW.csv"
   
    intOutFile = FreeFile
    Open strOutFile For Output As intOutFile
    strInput = Input(LOF(intInFile), intInFile)
    Print #intOutFile, Replace(strInput, ",", ";")
    Close #intInFile
    Close #intOutFile
'apaga o original
    Kill strInFile
'renomeia o novo com o nome do original
    Name strOutFile As strInFile
sExit:
    On Error Resume Next
    Exit Sub
E_Handle:
    MsgBox Err.Description & vbCrLf & vbCrLf & "SubstituirTexto", vbOKOnly + vbCritical, "Error: " & Err.Number
    Resume sExit
End Sub

Caro Luciano, serviu para as suas necessidades ?

Boa tarde JPaulo!
Desculpe a demora, fiz umas adaptações.
Faz tempo que não uso o access, saudades, estou bem enferrujado.
Ficou top.
Muuuito obrigado
Luciano

Olá a todos

Luciano, obrigado pelo feedback, o fórum agradece.

Faltou dar o tópico como Resolvido, desta vez eu dou, no entanto veja como é efetuado:
https://www.maximoaccess.com/t860-resolucao-de-topicos

Abraço a todos