[Resolvido]Comando vba para, ao clicar no botão salvar ele verificar se houve preenchimento de algum campo ou esta em branco

Boa tarde amigos!

Preciso de auxílio!

uso este comando no botao salvar para novos cadastros através de um formulario:


DoCmd.RunCommand acCmdSaveRecord


Ocorre que se o usuario ao clicar em salvar, mesmo que ele nao tenha preenchido nenhum campo, o access está gerando um registro em branco que vai precisar ser deletado depois...

Gostaria de ajuda para acrescentar um código if talvez, para que se ao clicar no botao salvar, se não houver nenhum campo preenchido, o access não salve, caso haja ele salve, evitando os registros em branco.

Muito grato!

Olá Flavio,

É necessário criar uma função que verifica os campos que são de preenchimento obrigatório, e o retorno desta função seria TRUE (campos preenchidos corretamente, ou FALSE (campos que ainda não foram preenchidos).

No formulário, copie e cole a função abaixo:

Código:


Private Function ValidaCampos() As Boolean

    '-- Inicia a função como verdadeira
   ValidaCampos = True
   
    If IsNull(Me.[Nome_do_campo_obrigatorio_1]) Or Trim(Me.[Nome_do_campo_obrigatorio_1]) = Empty Then
        MsgBox "O campo [Nome_do_campo_obrigatorio_1] é de preenchimento obrigatório.", vbExclamation, "Aviso"
        Me.[Nome_do_campo_obrigatorio_1].SetFocus
        ValidaCampos = False '-- define a função como falsa
        Exit Function
    End If
   
  If IsNull(Me.[Nome_do_campo_obrigatorio_2]) Or Trim(Me.[Nome_do_campo_obrigatorio_2]) = Empty Then
        MsgBox "O campo [Nome_do_campo_obrigatorio_2] é de preenchimento obrigatório.", vbExclamation, "Aviso"
        Me.[Nome_do_campo_obrigatorio_2].SetFocus
        ValidaCampos = False
        Exit Function
    End If

End Function



No botão Salvar, copie e cole a rotina abaixo:

Código:


    '-- Entra na função para verificar preenchimento correto dos campos
   If ValidaCampos = False Then
        Exit Sub '-- a rotina do botão pára aqui se a função voltar como False
    End If

   '-- Se a função for TRUE, segue procedimento para gravação do registro
    DoCmd.RunCommand acCmdSaveRecord
    DoCmd.RunCommand acCmdRefresh
    MsgBox "Registro gravado com sucesso.", vbInformation, "Mensagem"



Espero que tenha entendido.

É isso.

Att,

Alexandre Fim

Obrigado!

Entendi sim, como estou desenvolvendo no horário de expediente só irei testar na segunda, por isso darei o tópico como resolvido e caso não consiga aplicar segunda eu reabrirei para um novo help.

Muito obrigado novamente.

Consegui implementar sem problemas!
Muito grato!

Valeu Flávio,
O fórum agradece.
Sucesso !!!