[Resolvido] Formulário em branco ao não encontrar registro via SELECT

Olá pessoas!  

Tenho uma text box onde após atualizar, ele realiza a instrução SELECT, conforme código abaixo:

Código:


        On Error GoTo Erro
        Dim strSQL As String
        Dim localizar As Variant
        localizar = Me.Ordem_de_Fabricacao_2
        If IsNull(Ordem_de_Fabricacao_2) Then
        MsgBox ("Informe o número da ordem de fabricação"), vbCritical
        Me.Ordem_de_Fabricacao_2.SetFocus
        Else
        strSQL = "SELECT * FROM [Cst_ApontamentoDeProdução] WHERE [Ordem de Fabricação]='" & localizar & "'"
        Me.Form.RecordSource = strSQL
        
        End If
        Exit Sub
Erro:
        MsgBox("Registro não localizado.")



Acontece que a busca está sendo realizada perfeitamente, porém quando digito um valor que o SELECT não encontra, o formulário apenas fica em branco, some todos os campos, todos os botões, sendo necessária a reinicialização do form para que seja normalizado.

O ideal é que apareça uma MsgBox caso não encontre nenhum registro.

Alguém teria alguma ideia de como resolver este problema?

Olá Cristian,

Na instrução abaixo, se a instrução SQL não carregar nenhum registro, seu formulário será atualizado em branco mesmo.
Me.Form.RecordSource = strSQL

É isso
Alexandre Fim

Alexandre, muito obrigado!!

Entendi perfeitamente sua explicação sobre motivo deste acontecimento, porém ainda estou engatinhando em VBA e SQL e não consegui enxergar uma solução para este problema..

Poderia por gentileza detalhar mais a resposta?

Cristian,
Por gentileza, compartilhe uma cópia do seu bd, somente objetos (tabelas/fomulários/consultas e etc.) envolvidos na questão, para análise e solução do problema.
Desta forma, fica mais fácil entender a situação.

Att,
Alexandre Fim

Boas, com a permissão do Alexandre.

Sem ter o banco em mãos, apenas dando um pitaco.

       On Error GoTo Erro
       Dim strSQL As String
       Dim localizar As Variant
       localizar = Me.Ordem_de_Fabricacao_2
       If IsNull(Ordem_de_Fabricacao_2) Then
       MsgBox ("Informe o número da ordem de fabricação"), vbCritical
       Me.Ordem_de_Fabricacao_2.SetFocus
       Else
       strSQL = "SELECT * FROM [Cst_ApontamentoDeProdução] WHERE [Ordem de Fabricação]='" & localizar & "'"
       Me.Form.RecordSource = strSQL

Elseif strSql = "" then
       msgbox" Não há registro a ser mostrado !", " AVISO"
me.requery
       end if

       Exit Sub
Erro:
       MsgBox("Registro não localizado.")

Olá Silvio! Fico muito grato pela ajuda!

Ao aplicar o código sugerido, apareceu a mensagem:

"Erro de Compilação - Else sem If", onde o trecho "ElseIf strSQL = "" Then" foi destacado no erro.

Alexandre, infelizmente não consigo enviar um projeto, uma vez que o BD já está dividido para uso em rede..

Para facilitar na visualização, segue em anexo os prints apresentando o erro.

Lembrando que a consulta do SQL está sendo realizada no evento "Após atualizar" do campo Ordem_de_Fabricacao_2.

Caso necessitem de mais informações, estarei à disposição.

Cristian,
Realmente, os prints não ajudam em nada, mas pelo que vc mencionou na Mensagem nº1, onde os controles "somem" da tela, deve ser por alguma propriedade do formulário.

No Modo Design do formulário, vá em "Folha de Propriedades", na guia "Dados" e mude a propriedade "Entrada de Dados" de Sim para Não.
Acredito que irá funcionar também, se não, copie e cole o código abaixo:

Código:



On Error GoTo Erro
Dim strSQL As String
Dim localizar As Variant
   
    localizar = Me.Ordem_de_Fabricacao_2
   
    '-- Alexandre Fim - 12/07/2022
    '-- Se o campo for nulo ou vazio, emite mensagem ------------------------------------------------------
    If IsNull(Ordem_de_Fabricacao_2) Or Trim(Ordem_de_Fabricacao_2) = Empty Then
        MsgBox "Informe o número da ordem de fabricação", vbExclamation, "Aviso!"
        Me.Ordem_de_Fabricacao_2.SetFocus
        Exit Sub '-- pára aqui e suspende a execução do código restante
    End If
    '-------------------------------------------------------------------------------------------------------
   
    '-- Executa a função para contar registros conforme o campo informado. Se contar ZERO, emite mensagem
    If Nz(DCount("*", "Cst_ApontamentoDeProdução", "[Ordem de Fabricação]='" & localizar & "'"), 0) = 0 Then
        MsgBox "O sistema não localizou os dados de Ordem de Fabricação informada.", vbExclamation, "Aviso!"
        Exit Sub '-- pára aqui e suspende a execução do código restante
    End If
    '-------------------------------------------------------------------------------------------------------
   
   
    '-- Caso não ocorra nenhum erro, carrega o formulário com a instrução SQL ------------------------------
    strSQL = "SELECT * FROM [Cst_ApontamentoDeProdução] WHERE [Ordem de Fabricação]='" & localizar & "'"
    Me.Form.RecordSource = strSQL
    Me.Requery
    '-------------------------------------------------------------------------------------------------------
   
    Exit Sub  '-- Finaliza o procedimento

'-- Tratamento de erro é utilizado somente quando houver erro de sintaxe, execução e processamento.
'-- Não deve ser utilizado para exibir mensagem ao usuário quando o sistema não encontrar o registro, até pq não é um erro.
Erro:
    MsgBox "Erro gerado: " & Err.Number & " - " & Err.Description & "", vbCritical, "Erro"
    Exit Sub

End Sub



OBS: Como vc mesmo mencionou que ainda é iniciante no VBA e Instruções SQL, sugiro que vc estude mais sobre o assunto antes de utilizar a lnguagem em seus sistemas. O COPIAR+COLAR não é o suficiente e o importante é entender o que cada rotina executa e os conceitos de linguagem e banco de dados.

É isso.

Espero ter ajudado

Att,
Alexandre Fim

Alexandre, sua solução funcionou perfeitamente.

Prometo que irei buscar mais conhecimento referente aos assuntos comentados!

Muito obrigado amigo!