[Resolvido]Dados do subformulário não estão sendo salvos na tabela

Boa noite galera!

Abri esse tópico pq não achei resposta aqui no fórum nem no youtube.

Meu problema consiste em que os dados dos campos descricaoResumida, valorUnitario e subtotal não estão sendo salvos na tabela mesmo havendo relação entre elas.




Quando digito o código do produto no campo "txtLeituraSKU do "formPedidos", ele insere esse mesmo código no subform "formDetalhesPedido" e também a quantidade 1. Caso o código já exista no subform, ele apenas coma +1 no campo "qtdeSaida", porém na tabela ele só salva a quantidade, o código e as IDs dos pedidos.

O que vc está vendo no subform do teu fórmulario e uma consulta.

Se queres salvar os outros campos tem que incluir os campos na tua Instrução SQL.

Opa, blz Marcos!

Esse caso envolve aquele código que acabamos de falar no outro tópico.

Tem como adaptar nele? Como faço isso? Pode me ajudar?

Cheguei a pouco do trabalho.
Logo te retorno

Boa noite

Segue código, não testei.

Código:

Dim seq As String, k
Dim objBD As DAO.Database


'\\ Se o campo leituraSku estiver vazio aborta tudo.
If Nz(Me!txtLeituraSKU.Value) = "" Then Exit Sub


    'Se campo leituraSku = 5 Caracteres inicia procedimento
    If Len(Nz(Me.txtLeituraSKU.Text)) = 5 Then


      Me.txtIdRepresentante.SetFocus
      Me.txtCodProd = Right(txtLeituraSKU, 5)
      Me.txtLeituraSKU.SetFocus
    
    
           '\\\ Busca na tabela de produtos os campos: [produto], [descricaoResumida], [ValorUnitario]
           seq = "[Produto] & '|' & [Ativo] & '|' & [descricaoResumida] & '|' & [ValorUnitario] "
           seq = Nz(DLookup(seq, "tblProdutos", "codigoProduto = " & Me!txtLeituraSKU.Value))
             k = Split(seq, "|")
        
        
               '\\ Verifica se a busca na tabela encontrou o produto cadastrado
               If seq = "" Then
                  
                   'Avisa que não encontrou e aborta.
                   MsgBox "Produto não Cadastrado!", vbCritical, "Produto não encontrado"
                  
                   Me.txtLeituraSKU.SetFocus
                  
                   Exit sub
              
                   '\\ Encontrou o produto cadastrado, então verifica se o produto cadastrado está inativo.
                   ElseIf k(1) = "Inativo" Then
          
                   'Avisa que o produto encontrado está inativo e aborta.
                   MsgBox "Produto: " & k(0) & " está inativo!", vbCritical, "Produto inativo"
                  
                   Me.txtLeituraSKU.SetFocus
                  
                   Exit sub
            
               End If
        
            
        '\\ Se chegou até aqui então faz o cadastro.
        
        
                Set objBD = CurrentDb
        
        
                '\\ Tenta fazer um update na tabela "tblDetalhesPedido" se o produto já estiver cadastrado no pedido.
                Call objBD.Execute("update tblDetalhesPedido " & _
                                   "set qtdeSaida = qtdeSaida + 1 " & _
                                   "where idPedido = " & Me!txtIdPedido.Value & " and codigoProduto = """ & Me!txtCodProd.Value & """;")
        
        
                '\\ Se a Update acima não afetou nenhum registro (não encontrou produto) então insere um produto novo.
                If objBD.RecordsAffected = 0 Then
                
                    'Usando a Variavel K
                    'k(0) = produto
                    'k(1) = Ativo
                    'k(2) = descricaoResumida
                    'k(3) = ValorUnitario
            
            
                    '\\O campo subTotal pode continuar usando a expressão na consulta criando um campo calculado, eu não uso campo calculo em tbls.
                    Call objBD.Execute("insert into tblDetalhesPedido (idPedido, codigoProduto, descricaoResumida, ValorUnitario) " & _
                                      "values(" & Me!txtIdPedido.Value & "," & Me!txtCodProd.Value & ",'" & k(2) & "'," & k(3) & ";")
                                      
                End If
        
        
                'Libera memoria
                Set objBD = Nothing
                
                
        Me!txtLeituraSKU.Value = Null
        Me!subformDetalhesPedido.Requery
        Me!txtIdRepresentante.SetFocus
        Me!txtLeituraSKU.SetFocus


    End If




Blz Marcos! Vou testar e retorno aqui. vlw

Blz Marcos?!

Adaptei à minha necessidade e eu certo aqui. Muito obrigado!