[Resolvido]Exportar dados de Formulario principal e dados que estão no subformulario

Prezados boa tarde / boa noite

O cenário é o seguinte.

Tenho um formulário principal e um subformulário.

No FrmPrincipal, há 3 campos fixos e no subformulário continuo esses campos irão variar de 01 até 05 campos.

Como perdi meu hd ( nele eu tinha um "baú" de rotinas prontas para qualquer ou quase qualquer situação ), recorro a vocês para me dar um help.

Preciso exportar os 3 campos do frmprincipal e quantos campos haverem no subformulário para uma determinada tabela.

Desde já fica aqui meus agradecimentos a todos.

Abraços. []

Eu queria poder ajudar, mas tenho muita dificuldade quando tento entender as solicitações e nelas não existem exemplos anexados.

Inclusive tenho isso na minha assinatura.

Anexa um exemplo aí pra uma melhor compreensão do que desejas.

Bom dia.

Nem sempre é possível postar as entidades envolvidas.   Há várias entidades envolvidas nesses dois formulários.
Mas vou tentar retirar o máximo que posso para lhe mandar algo.
Grato mesmo assim.

Obs...fiz um bem bolado aqui, retirei algumas tabelas, consultas, formulários de pesquisa. Deixei apenas o essencial da coisa.

Código:

Private Sub CDebito_Click()

    Dim db1 As DAO.Database
    Dim rs1 As DAO.Recordset
    Dim rs2 As DAO.Recordset
   
    If Me.CDebito = -1 Then
   
        'fazendo do subformulário um recordset
        Set rs1 = Me!SFrmCaixa.Form.RecordsetClone
       
        'verificando se há registros no subformulário
        If rs1.RecordCount > 0 Then
       
            Call rs1.MoveFirst
            Set db1 = CurrentDb
            Set rs2 = db1.OpenRecordset("Ateencerrado", , 8) 'abrindo para somente adição
           
            With rs2
            Do 'iniciando loop

                Call .AddNew
               
                    ![Idcaixa] = Me.Idcaixa
                    ![Proprietario] = Me.Proprietario
                    ![Animal] = Me.Animal
                    ![DataPagamento] = Me.DataPagamento
                    ![Valor] = Me.Valorf
                    ![Dinheiro] = Me.Dinheiro
                    ![Cheques] = Me.Cheques
                    ![Carteira] = Me.Carteira
                    ![CCredito] = Me.CCredito
                    ![CDebito] = Me.CDebito

                    'campos que estão no subformulário
                    ![TipoServico] = rs1!TipoServico
                    ![Servico] = rs1!Servico
                    ![Custo] = rs1!Custo
                    '![Idservico] = Forms![frmcaixa]![SFrmCaixa]!Idservico
                   
                Call .Update
                Call rs1.MoveNext

            'condição para finalizar o loop
            Loop Until rs1.EOF
            End With
           
            Call rs2.Close: Set rs2 = Nothing
            Set db1 = Nothing
           
        End If
       
        Set rs1 = Nothing
       
    End If
   
    Call MsgBox("Entrada Caixa... salva com sucesso!", vbInformation, Me.Caption)
   
End Sub

Bom dia..

Show de bola....o que eu tinha, salvo engano meu, era parecido com o que postou. Mais um que vai ser salvo e com cópias dessa vez.

Grato Damasceno.

Abraços.

O fórum agradece o retorno. Sucesso.