[Resolvido]inserir o conteúdo pelo insert

Boa tarde amigos.
qual o  erro aqui , eu quero colocar o conteúdo que está dentro da caixa não acoplada

Código:

CurrentDb.Execute "INSERT INTO registro" _
            & "(nome, telefone) VALUES " _
            & "(me.teste, me.telefone)
"

Boa tarde Crysostomo,
Estava faltando separar os campos conform abaixo:
"('"& me.teste &"', '"& me.telefone &"')

Sugestão:
Procure separar a instrução em campos e valores.. Segue exemplo

Código:



Dim db      As DAO.Database
Dim sSQL    As String

    Set db = CurrentDb

    sSQL = "INSERT INTO registro"
    'CAMPOS----------------------------------------
    sSQL = sSQL & "("
    sSQL = sSQL & "  nome"
    sSQL = sSQL & " ,telefone"
    sSQL = sSQL & ")"
    'VALORES -------------------------------------
    sSQL = sSQL & " VALUES"
    sSQL = sSQL & "("
    sSQL = sSQL & "  '" & Trim(Me.teste) & "'"
    sSQL = sSQL & " ,'" & Trim(Me.telefone) & "'"
    sSQL = sSQL & ")"

    db.Execute sSQL




Rapaz , falta de atenção em mim que não falta de tanto eu buscar por aqui e dar esse vacilo , Obrigado Alexandre.
vou seguir sua separação.

Tranquilo rapaz....
Estamos sempre aprendendo a cada dia...

Boa sorte.

Abraço

Alexandre não abusando da sua boa vontade , porque depois ou antes do insert o verificador de campos vazios não funcionam?

Código:


  If IsNull(Me.senha) Then
     MsgBox "O campo  é obrigatório.", vbCritical, "Aviso"
end if
.....


Crysostomo,

Utilize desta forma:

If IsNull(Me.senha) or Trim(Me.senha)= Empty Then
MsgBox "O campo é obrigatório.", vbCritical, "Aviso"
end if
.....

Não entendo o porque o operador  " OR " não está funcionando , o usuário pode estar vazio, mas ele grava a senha.
nem conseguindo registrar a entrada e saída do usuário , ma está dando

Boa tarde,

Os Campos, no que respeita ao valor, podem ser Nulos, Vazios, ou de comprimento zero.

Para evitar estes transtornos costumo colocar na condição sempre as 3 opções.

Testei o seu caso com sucesso alterando a linha de código de:

Código:

If IsNull(Me.txtcadstrouser) Or Trim(Me.txtCadastroSenha) = Empty Then

Para:

Código:

If IsNull(txtcadstrouser) Or txtcadstrouser = "" Or txtCadastroSenha = Empty Then

Veja se deu certo.

Abraço

Olá Crysostomo,

Faltou fazer a validação dos dois campos de forma separada.
Segue código:

Código:



Private Sub Comando7_Click()
On Error GoTo trata_erro
Dim db      As DAO.Database
Dim sSQL    As String

    If IsNull(Me.txtcadstrouser) Or Trim(Me.txtcadstrouser) = Empty Then
        MsgBox "O campo Usuário é obrigatório.", vbExclamation, "Aviso"
        Me.txtcadstrouser = ""
        Me.txtCadastroSenha = ""
        Exit Sub
    End If


    If IsNull(Me.txtCadastroSenha) Or Trim(Me.txtCadastroSenha) = Empty Then
        MsgBox "O campo Senha é obrigatório.", vbExclamation, "Aviso"
        Me.txtcadstrouser = ""
        Me.txtCadastroSenha = ""
        Exit Sub
    End If

    Set db = CurrentDb
   
    sSQL = "INSERT INTO tblLogin"
    'CAMPOS----------------------------------------
    sSQL = sSQL & "("
    sSQL = sSQL & "  tbUsuario"
    sSQL = sSQL & " ,tbSenha"
    sSQL = sSQL & ")"
    'VALORES -------------------------------------
    sSQL = sSQL & " VALUES"
    sSQL = sSQL & "("
    sSQL = sSQL & "  '" & Trim(Me.txtcadstrouser) & "'"
    sSQL = sSQL & " ,'" & Trim(Me.txtCadastroSenha) & "'"
    sSQL = sSQL & ")"
    db.Execute sSQL
    Me.Refresh
   
    MsgBox " Senha cadastrada", vbInformation, "Arquivamento-Login"
    Me.txtCadastroSenha = ""
    Me.txtcadstrouser = ""
   
    Exit Sub
trata_erro:
   
    MsgBox "Erro gerado: " & Err.Number & " - " & Err.Description & "", vbCritical, "Erro"
    Exit Sub
     

End Sub



boa sorte

Abraços

E ai?
Deu certo?

Sim deu certo Alexandre, já a do Zcarlos, continua dando erro.

Blza...Valeu

Alexandre, peguei um arquivo sei , mas não esta dando certo comigo, poderia me ajudar?