[Resolvido]Se existir trazer dados

Bom dia a todos,

Tenho um formulário e quero fazer a seguinte operação:

No meu banco não pode existir nº de processo repetido já fiz esse teste, mais quero que ao digitar o nº do processo e se ele existir trazer as informações, ou seja, localizar o registro e mostrar para edição.

Podem em ajudar.

Obrigado

Veja se o exemplo do tópico Ver se já foi cadastrado, ajuda a resolver a sua questão.

Pode descarregar o exemplo utilizando o link abaixo.

Copiar e colar o link no navegador:

Código:

dropbox.com/s/3azdfbeswe1rcor/Cadastro_Kaynan.rar?dl=1

Boa sorte

Ficou bem melhor do que eu esperava.

O que você me enviou ficou ótimo.

O que eu preciso acredito que seja uma coisa mais simples.

Não sei se estou conseguindo me fazer entender, mais vamos lá:

na inclusão ao digitar o número do processo eu checo se existe com esse código.

Private Sub Processo_BeforeUpdate(Cancel As Integer)
If DCount("processo", "processos", "processo =""" & Me!Processo & """") > 0 Then
'A função DCount() contou um ou mais registros existentes
MsgBox "O Processo " & Me!Processo & " já foi cadastrado..."
Me.Undo 'Limpa o campo
Cancel = True 'mantém o foco no campo.
End If
End Sub

o que eu quero é que após a mensagem de processo já cadastrado

ele localize o processo cadastrado e traga para a tela para edição

Obrigado pela paciência

Bom dia,
precisará instanciar o formulário mais uma vez. Vamos lá:

abaixo da linha: Cancel = True, ponha:

Static f As New Form_SeuFormulário 'Instancio o formulário

f.Filter = "processo='" & Me!Processo & "'" 'Filtro os registros para exibi-lo para edição
f.FilterOn = True 'Ativo o filtro

f.Visible = True 'Defino como visível

SeuFormulário, aqui ponha o nome do formulário está tentando inserir as infrmações.

Por exemplo, se o nome do formulário for frmProcessos:
Static f As New Form_frmProcessos

Deu certo, mais está abrindo o formulário várias vezes, aí trava.

Apenas uma vez está configurado para abrir...
Em qual momento trava? Explique melhor...

Olah o código.

Private Sub Processo_BeforeUpdate(Cancel As Integer)
   
   If DCount("processo", "processos", "processo =""" & Me!Processo & """") > 0 Then
       'A função DCount() contou um ou mais registros existentes
       MsgBox "O Processo " & Me!Processo & " já foi cadastrado..."
       'Me.Undo 'Limpa o campo
       Cancel = True 'mantém o foco no campo.
       
       Static f As New Form_Processos 'Instancio o formulário
     
       f.Filter = "processo='" & Me!Processo & "'" 'Filtro os registros para exibi-lo para edição
       
       f.FilterOn = True 'Ativo o filtro

       f.Visible = True 'Defino como visível
       
                     
  End If
End Sub

Fiz como você explicou.

Pois bem, apenas a vez está abrindo e não várias vezes... Poderia postar o aplicativo com as partes envolvidas para que eu dê a olhada?

Bom dia, aí está.

Quando vc digita o nº do processo e ele existe, a tabela é aberta novamente e filtra.

Obrigado

Olá a todos

Dando uma sugestão.

Copie este código e teste:

Código:

Private Sub Processo_BeforeUpdate(Cancel As Integer)
   
Dim rst As DAO.Recordset
   
    Set rst = Me.RecordsetClone
    rst.FindFirst "[processo] = '" & Me!Processo & "'"
   
    If Not rst.NoMatch Then
        'avisa
        If MsgBox("O Processo " & Me!Processo & " já foi cadastrado..." & Space(2) & "" _
            & "Deseja ir para cadastro informado para Conferir ou atualizar dados?", vbYesNo + vbExclamation + vbDefaultButton2, "Confirmação") = vbYes Then
           
            Cancel = True
            Me.Undo
            Me.Bookmark = rst.Bookmark
            'Me.Processo.SetFocus
        Else
            Me.Undo
            Me.Processo.SetFocus
        End If
    'End If
    End If
        rst.Close
        Set rst = Nothing
End Sub

Aguardamos retorno

Abraços

Celso, Boa Tarde!

Deu Certo, mais meus filtros foram inabilitados (Na parte superior tem uma telinha Registro que tem filtros em: Todos  / Encaminhado / A Resolver) não funcionam mais.

Obrigado

Olá..

No anexo que enviou esta ok.
Este código que te enviei não altera nada nos outros eventos de sua programação.
Não identifiquei o problema aqui.

Anexe este exemplo com o problema.

Aguardamos

Abraços

Celso,

Verifiquei aqui e eu tinha tirado o código dos filtros, erro meu.

Está perfeito, totalmente resolvido.

Muito obrigado.

Grande Abraço

olá..

1 - Fiz uma alteração no código anterior para caso clicar em Não, altere o anterior para este:

Código:

Private Sub Processo_BeforeUpdate(Cancel As Integer)
   
Dim rst As DAO.Recordset
   
    Set rst = Me.RecordsetClone
    rst.FindFirst "[processo] = '" & Me!Processo & "'"
   
    If Not rst.NoMatch Then
        'avisa
        If MsgBox("O Processo " & Me!Processo & " já foi cadastrado..." & Space(2) & "" _
            & "Deseja ir para cadastro informado para Conferir ou atualizar dados?", vbYesNo + vbExclamation + vbDefaultButton2, "Confirmação") = vbYes Then
           
            Cancel = True
            Me.Undo
            Me.Bookmark = rst.Bookmark
        Else
            Cancel = True
            Me.Undo
        End If
    'End If
    End If
        rst.Close
        Set rst = Nothing
End Sub

2 - O filtro não este desabilitado, você excluiu o código existente, segue ele abaixo:

No evento apos atualizar do filtro:

Código:

Private Sub FiltroEncaminhado_AfterUpdate()
If FiltroEncaminhado = 1 Then
    Me.FilterOn = False
Else
    If FiltroEncaminhado = 2 Then
   
        Me.Filter = "Situação = 'Encaminhado' OR Situação = 'Concluído'"
       
        Me.FilterOn = True
    End If
    If FiltroEncaminhado = 3 Then
        Me.Filter = "Situação <> 'Encaminhado' AND Situação <> 'Concluído'"
        Me.FilterOn = True
    End If
   
End If

End Sub


Aguardamos retorno

Abraços

Celso,

Tudo 100% resolvido.

Muito Obrigado.

Não tem esta opção Resolvido para clicar.

Olá..

Ficamos felizes por ter ajudado

Mas, para finalizar de o tópico como resolvido para ajudar outros membros que procuram pelo mesma dúvida.

Veja como neste link: https://www.maximoaccess.com/t860-resolucao-de-topicos

Edite uma mensagem clicar primeiro no Resolvido e depois em Enviar

Aguardamos

Abraços e sucesso

Olá..

Realmente quando edita uma mensagem este botão nâo habilita.

Tem que responder com nova mensagem, ai ele habilita.

Abraços

Bom dia a Todos.

Resolvido.

Muito obrigado.

Abençoado dia para todos.

Olá...

Perfeito!!!!!

Um bom término de dia para você também.

Obrigado pelo retorno

Abraços e sucesso