[Resolvido]Inverter a sequência de filtragem nessa rotina

Bom dia aos colegas....

Deu "branco" aqui....

Preciso inverter a sequência de filtragem nessa rotina.


Dim filtro$
Me.FilterOn = False
filtro$ = "DataBaixaPgto between #" & Format(Me.DI, "dd/mm/yyyy") & "# AND #" & Format(Me.DF, "dd/mm/yyyy") & "# And DentistaOculta='" & Me.DenOculta & "'"
Me.Filter = filtro$
Me.FilterOn = True


Preciso que...isto :DentistaOculta='" & Me.DenOculta & "'"

Venha antes disso.... "DataBaixaPgto between #" & Format(Me.DI, "dd/mm/yyyy") & "# AND #" & Format(Me.DF, "dd/mm/yyyy") & "#

Olá Silvio,

Código:

filtro$ = "DentistaOculta='" & Me.DenOculta & "' AND DataBaixaPgto between #" & Format(Me.DI, "dd/mm/yyyy") & "# AND #" & Format(Me.DF, "dd/mm/yyyy") & "#'"

Abraço

Bom dia Alvaro....

Negativo quanto a filtragem.....não ocorre nada " :(O

Bom dia Silvio,

Não funcionava, como postou na mensagem nº 1 ?
Poste base de dados com form em questão com alguns dados de amostragem para se testar.

Abraço

vou te mandar um pvt...explicando...

Olá Silvio,
Uma vez que tem dados sensiveis, mande por MP.
Depois postamos a solução aqui.

Abraço

Não custa testar;

Tem de isolar o segundo filtro entre colchetes;

Código:

Dim filtro$
Me.Filter = vbNullString
Me.FilterOn = False
filtro$ = "DentistaOculta='" & Me.DenOculta.Value & "' AND (DataBaixaPgto between #" & Format(Me.DI.Value, "dd/mm/yyyy") & "# AND #" & Format(Me.DF.Value, "dd/mm/yyyy") & "#)"
Me.Filter = filtro$
Me.FilterOn = True

JPaulo, bom dia...

Nada de resultado concreto, ainda vem uma data que não está dentro do range estabelecido na data inicial e final.

Muito provavelmente o problema está nesse Format da data.

Tente inverter para data americana, "mm/dd/yyyy"

Olá a todos,

Silvio, seguindo a sugestão do JPaulo, teste assim:

Código:

filtro$ = "[DentistaOculta] = '" & Me.DenOculta & "' AND [DataBaixaPgto] between #" & Format(Me!DI, "mm/dd/yyyy") & "# AND #" & Format(Me!DF, "mm/dd/yyyy") & "#"

Abraço a todos

Alvaro, bom dia.

Espero que tenha tido um Santo Natal com o teus !

Já estou na minha cidade. Depois de ficar uns dias em um local que nem internet funcionava correctamente.

Nobre, ficou bom mesmo a filtragem no formulário, creio eu, que resolvemos o problema.

Como eu coloco isso no relatório ? Em qual evento..ao carregar...ao imprimir ?

Pois no relatório aparecem ainda datas que nada tem em haver com a filtragem.

Olá a todos,

Silvio, que bom que resolveu.
Quanto à dúvida do tópico, parece esclarecida, devemos dar o tópico como Resolvido.

Relativamente à ultima questão uma vez relacionada, vou responder aqui a solução.

1º - Na consulta QryFrmImpresso que alimenta o seu reporte adicione o campo [DataBaixaPgto]
2º - No relatório RptPlanotodos altere o código da Sub atualizar por este:

Código:

Public Sub atualizar()
    'sub para filtragem do form
    'jpaulo 2017-10-09
    Dim strFilter As String
    
    If Len(Forms!FrmImpresso.Form!CboDentista & "") > 0 Then
       If Forms!FrmImpresso.Form!CboDentista.Column(0) = "Todos" Then
        strFilter = strFilter & " AND DentistaOculta Like '*'"
       Else
        strFilter = strFilter & " AND DentistaOculta ='" & Forms!FrmImpresso.Form!CboDentista.Column(0) & "'"
       End If
    End If
    
    If Len(Forms!FrmImpresso.Form!CboPlano & "") > 0 Then
       If Forms!FrmImpresso.Form!CboPlano.Column(0) = "Todos" Then
        strFilter = strFilter & " AND PlanoOculta Like '*'"
       Else
        strFilter = strFilter & " AND PlanoOculta ='" & Forms!FrmImpresso.Form!CboPlano.Column(0) & "'"
       End If
    End If
    
    If Len(Forms!FrmImpresso.Form!CboSituacao & "") > 0 Then
       If Forms!FrmImpresso.Form!CboSituacao.Column(0) = "Todos" Then
        strFilter = strFilter & " AND SituacaoOculta Like '*'"
        Else
       strFilter = strFilter & " AND SituacaoOculta ='" & Forms!FrmImpresso.Form!CboSituacao.Column(0) & "'"
       End If
    End If
    
    If Len(Forms!FrmImpresso.Form!CboStatus & "") > 0 Then
       If Forms!FrmImpresso.Form!CboStatus.Column(0) = "Todos" Then
        strFilter = strFilter & " AND StatusOculta Like '*'"
        Else
       strFilter = strFilter & " AND StatusOculta ='" & Forms!FrmImpresso.Form!CboStatus.Column(0) & "'"
       End If
    End If
    
    'ahteixeira inicio
    If Forms!FrmImpresso.Form!BtNomeOculta & "" = "Pesquisa por Data de Pagamento ao Dentista" Then
        strFilter = strFilter & " AND [DataBaixaPgto] between #" & Format(Forms!FrmImpresso.Form!DI, "mm/dd/yyyy") & "# AND #" & Format(Forms!FrmImpresso.Form!DF, "mm/dd/yyyy") & "#"
    End If
    'ahteixeira fim
    
    strFilter = Mid(strFilter, 6)
    
    If Len(strFilter) > 0 Then
        Me.Filter = strFilter
        Me.FilterOn = True
    Else
        Me.Filter = ""
        Me.FilterOn = False
    End If
End Sub


Abraço

Alvaro, JPaulo boa tarde !!

Meus sinceros agradecimentos a vocês dois pela prestimosa ajuda.

Alvaro adicionei mais alguns botões na rotina que me passou, agora está ótimo.

Muito obrigado mesmo aos dois.

[]'s

Olá Silvio, obrigado pelo retorno.

Abraço a todos e votos de um Feliz 2018.