[Resolvido]Relatório com formulário filtro e campo de seleção múltiplas

Caros colegas desenvolvedores Access, estou precisando muito da ajuda de vocês...
A situação é a seguinte: tenho no sistema com um relatório (Atendimentos) que usa como fonte de dados uma consulta (Atendimentos), bem, eu preciso que quando for aberto o relatório, o formulário (Dialogo_Atend) abre e o usuário faz o filtro selecionando os dados, neste form tem um campo (subtipo) que é de seleção múltiplas, então ao selecionar é clicar em visualizar, o form fecha e o relatório abre com os registros selecionados.

Tentei de varias formas, já dei uma olhada por aqui no fórum para ver se tinha algum exemplo, mas nada... coloquei o seguinte código no form ao clicar no botão visualizar, mas não esta funcionando.

Código:

Private Sub Comando1_Click()
  Dim strMsg As String, strTítulo As String
  Dim intEstilo As Integer
  Dim sel As Variant
  Dim strWhere As String
    
 If IsNull([Data]) Then
         strMsg = "Você deve informar a data desejada."
          intEstilo = vbOKOnly
    strTítulo = "Atencao!!!"
        DoCmd.GoToControl "Compe"
        MsgBox strMsg, intEstilo, strTítulo
        Else
        Me.Visible = False
        
    End If

strWhere = "Subtipo in ("
For Each sel In Me.Subtipo.ItemsSelected
strWhere = strWhere & "'" & Me.Subtipo.ItemData(sel) & "',"
Next
strWhere = strWhere & ")"

DoCmd.OpenReport "Atendimentos", acPreview, , strWhere

End Sub

Só mais um detalhe, utilizo um modulo Codigo_dialogo para chamar o form Dialogo_Atend. e em minha consulta fonte utilizo critérios de parâmetros para executar a consulta.

Vou colocar em anexo o BD. para vocês darem uma olhada.

Quem puder me orientar, dar uma ajuda para resolver este problema eu vou agradeço muito.

Um abraço.

Caros, aguem poderia me ajudar... dar uma uma dica, o que devo fazer???

Att,

Veja se é isso que precisa amigo!

Veja que mudei a consulta, e muita coisa no código... Então veja todos eles para entender!

dropbox.com/s/6vaaf1xu96rqls2/SIAtendimento.zip

Ok, vou ver... e te dou um retorno.

Obrigado por responder amigo!

Até mais,

Um abraço.

Amigo FabioPaes, sua solução foi ótima, funcionou bem! mas gostaria se possível de mais uma ajuda sua, ainda com relação ao relatório.
Preciso que o usuário tenha a opção de fazer o filtro informando somente a data ou a data e o profissional, deixando os campos Tipo e Subtipo em branco (nulo), assim selecionaria todos os registros para determinada data e/ou profissional.
Quando faço esta seleção no formulário aparece a seguinte mensagem: 3075 Operador In sem() na expressão de consulta'Subtipo in )'.
O que fazer? como posso colocar estes critérios para a consulta neste relatório.

De ante mão, agradeço pela sua atenção.

Meu amigo se vc usa como criterio Campoxx in() , tem que haver algum valor... In(1,2,3).

Para resolver isso tera que fazer uma verificacao nos Campos antes de construir o filtro...

Ex:

If not isNull(Me.DataCriterio) then
StrWhere = strWhere & criterio da data.
End if

If Not isNulm(me.Profissional) then
StrWhere = strWhere & " AND" & criterio profissional
End if
...


Dessa Forma no final tera na variavel o criterio correto. Se nao preencheu nada na data a variavel nao recebe a data como Criterio.


Tem exemplos disso aqui forum, mas to celular e complicado.
Se nao conseguir avisa que damos sequencia.

Bom dia,

Tomei a liberdade, Fabio Paes.

Acho que a solução resolve, favor verificar o arquivo abaixo.

Abraços,

Cleverson, nao verifiquei seu Anexo, mas é isso aee quando um nao puder o outro pega e corrige!!!!

Aguardar o retorno do colega!

Ok Cleverson, vou verificar seu anexo e retorno.

Obrigado!

Amigos, bom dia!

Verifiquei que a solução não está funcionando como o esperado, quando inserido apenas a data da erro! e quando coloco data e profissional da erro também. Isso faz com que as opções de seleção para o usuário fique muito limitado, entendem?

Quando trabalho com os critérios direto na consulta, dai consigo, mas com este código no formulários para fazer esta seleção dos itens, ai complica pra mim.

E ai, tem solução, o que eu faço colegas?

Aplique a dica da Mensagem Nº 06.

Aqui amigo... Mais dinâmico do que isso Impossivel!

No exemplo que postei, apague o comando que tem no Botão de visualizar...
e Coloque isso la:

Código:


Private Sub Comando1_Click()
On Error GoTo F
  Dim strMsg As String, strTítulo As String
  Dim intEstilo As Integer
  Dim sel As Variant
  Dim strWhere As String
 
 'Usa a data como Criterio
If Not IsNull(Me.Data) Then
    strWhere = "dt_Atend= # " & Format(Me.Data, "mm/dd/yyyy") & "# AND "
End If
 'Usa o Tipo como Criterio
If Not IsNull(Me.Tipo) Then
    strWhere = strWhere & "Tipo= " & Me.Tipo & " AND "
End If
 'Usa o Subtipo como Criterio
If Me.Subtipo.ItemsSelected.Count <> 0 Then
    strWhere = strWhere & "Subtipo in ("
    For Each sel In Me.Subtipo.ItemsSelected
    strWhere = strWhere & Me.Subtipo.ItemData(sel) & "," 'Mudei aqui pois o campo era numero
    Next
    strWhere = Left(strWhere, Len(strWhere) - 1) 'Mudei aqui para remover a ultima ,
    strWhere = strWhere & ") AND "
End If
 'Usa o Profissional como Criterio
If Not IsNull(Me.Profissional) Then
    strWhere = strWhere & "Prof_Atend= " & Me.Profissional & " AND "
End If
'Remove o Ultimo AND extra
strWhere = Left(strWhere, Len(strWhere) - 5)

'Verifica se selecionou algum filtro, se nao abre o relatorio, se sim abra filtrando
If Nz(Len(strWhere), 0) > 0 Then
    DoCmd.OpenReport "Atendimentos", acPreview, , strWhere
Else
    DoCmd.OpenReport "Atendimentos", acPreview
End If

'Tratamento de Erros!
F:
Select Case Err.Number
    Case 0, 2501 '2501 é o erro que ocorre quando eu cancelo a abertura do relatorio, quando ele estiver sem dados
        Exit Sub
    Case Else
    MsgBox Err.Number & " " & Err.Description, vbInformation
End Select
End Sub


Dessa forma fica Aberto... Podendo selecionar qualquer campo como filtrou, ou nao selecionar nenhum...

Ex: Selecionar a data, e o profissional.
Selecionar somente o Profissional
Selecionar somente o Tipo ou o Tipo e o Subtipo....

Veja os comentários para entender!

Ok Fabio, entendi! vou fazer as alterações, dai te retorno.

Obrigado!

Amigo, testei no exemplo, e quando seleciono a data e o profissional está dando um erro, e apresenta a seguinte mensagem: Tipo de dados incompatível na expressão de critério.

A sim... o Profissional e campo do tipo Texto. Apesar de ter numeros la...

Mude essas Linhas:

Código:

 
'Usa o Profissional como Criterio
If Not IsNull(Me.Profissional) Then
    strWhere = strWhere & "Prof_Atend= '" & Me.Profissional & "' AND "
End If


O que mudou foi so isso:
Estava assim: " & Me.Profissional & " AND "
Ficou assim: '" & Me.Profissional & "' AND "

Obs: Certifique-se de que na Consulta Origem do Relatório não haja nenhum Filtro direto na Consulta... Pois estaremos passando os filtro direto no Formulário!

Amigo Fabio, agora sim, deu tudo certo! está ótimo é isso que eu preciso.
Quero te agradecer pela sua atenção, muito obrigado mesmo.

Que Deus te abençoe.

Um abraço, e até mais.

Grato pelo retorno amigo, até a próxima se Deus Quiser!

Ola PedroJr,

Apesar do amigo FabioPaes ter resolvido sua situação, também fiz umas alterações no seu aplicativo. Não consegui mandar ontem (28/03/2017) pq aqui na empresa estava sem internet.
Pra todos os efeitos, segue o exemplo que fiz.
Um abraço.

Att,