[Resolvido]Como Checar se a tabela esta vazia?

Pessoal
Boa Tarde

estou com uma duvida que é a seguinte..

gostaria de saber como posso testar se uma determinada tabela está vazia...
(tabela AuxBancoScheda)

tentei a função isnull e isempty, porem nao obtive sucesso....

se puderem me ajudar..desde ja agradeço

Amigão essa é simples;

If Nz(DCount("*", "[AuxBancoScheda]")) = 0 Then
MsgBox "Tabela Vazia"
Else
MsgBox "Tabela com Registros"
End If

Tambem podemos complicar e fazer por Recordset;

Dim db As DAO.Database
Dim rs As DAO.Recordset

Set db = CurrentDb()
Set rs = db.OpenRecordset("AuxBancoScheda")

If Nz(rs.RecordCount) = 0 Then
MsgBox "Tabela Vazia"
Else
MsgBox "Tabela com Registros"
End If
Set db = Nothing
rs.Close

Obrigado pela ajuda JPaulo!!!

Valew pelo retorno amigo.

Mestre JPaulo

criei um form e coloquei um botao com
a funçao que voce postou.
Coloquei uma caixa de seleção  par ver todas as tabelas que possuo no banco de dados.
Fiz da seguinte forma:
coloquei  na origem da linha
SELECT MSysObjects.Name, MSysObjects.ParentId, *
FROM MSysObjects
WHERE (((MSysObjects.ParentId)=251658241));

Minha duvida é se possivel altera o seu código na seguinte linha:
Set rs = db.OpenRecordset("AuxBancoScheda")
mudar o set para que el busque o valor que esta na minha caixa de seleção.
veja meu código
Private Sub Comando2_Click()
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim busca As String
busca = Me.Lista3
Set db = CurrentDb()
Set rs = db.OpenRecordset("busca")

If Nz(rs.RecordCount) = 0 Then
MsgBox "Tabela Vazia"
Else
MsgBox "Tabela com Registros"
End If
Set db = Nothing
rs.Close
End Sub

estou a perguntar pois acabei
de fechar um sistema com um cliente
precisei migar as tabelas do sistema antigo dele
para começar o novo projeto
existem mais de 300 tabelas
muitas estão vazias pois o sistema antigo ( de 1988 )
possuía muitas coisa que ele nunca usou
queria eliminar essa tabelas vazias.
mas olhar um a uma vai dar muita dor de cabeça.

Desde já agradeço

Att

Ney Santos

Ola;

Como está funciona sem aspas;

Set rs = db.OpenRecordset(busca)

Mas assim terá de escolher uma a uma na mesma, é isso que pretende ?

Ou pretende algo mais elaborado, por exemplo deletar do banco todas as tabelas vazias e ter exceções ?

exatamente mestre, J Paulo
tens alguma sugestão para eu poder fazer essa exclusão?

Obrigado pelo retotno

Ola;

Sim tenho uma solução que funciona sempre, mas cuidado ao testar, faço num backup;

Código:

Public Function DeletaTabelasVazias()
'By JPaulo
'MaximoAccess 03-02-2010
  Dim dbs As DAO.Database
  Dim i As Integer
  Set dbs = CurrentDb
  For i = dbs.Relations.Count - 1 To 0 Step -1
    dbs.Relations.Delete dbs.Relations(i).Name
  Next i
  For i = dbs.TableDefs.Count - 1 To 0 Step -1
  'não deleta as tabelas de sistema
  'nem as tabelas que eu não quero deletar, a tblExemplo1 e a tblExemplo4
  'este segundo passo pode ser ignorado.
    If Left(dbs.TableDefs(i).Name, 4) <> "MSys" _
    And dbs.TableDefs(i).Name <> "tblExemplo1" _
    And dbs.TableDefs(i).Name <> "tblExemplo4" _
    And dbs.TableDefs(i).RecordCount = 0 Then
      dbs.TableDefs.Delete dbs.TableDefs(i).Name
    End If
  Next i
  Set dbs = Nothing
End Function

Mestre J Paulo
Funcionou perfeitamente.
Me poupou Tempo muito precioso pois eu estava a deletar uma a uma
e rem amis de 250 tabelas vazias.

Muito obrigado mesmo.
Que Deus o abençoe

Obrigada pelo retorno o forum agradece.

Aproveite bem esse tempo que poupou.