[Resolvido]Senha no Menu de Controle

Olá,

Sou iniciante em accsess e montei um banco de dados na versão 2007 para minha escola, utilizando as ferramentas básicas a disposição no programa e está funcionando bem legal. Meu problema é que gostaria que alguns relatórios financeiros não ficassem com acesso total. Então pensei em colocar uma senha simples de 4 ou 6 digitos no próprio botão do menu de controle para restringir o acesso a esses dados. Vi que nos fóruns existem diversas explicações mas não estou conseguindo inserir uma senha pois não conheço nada de programação e não sei como inserir os códigos. Gostaria de saber se alguém poderia me ajudar com um procedimento fácil para realizar esta tarefa. Agradeço desde já a atenção despendida.

Grande abraço,

André

Bom dia

Você quer que ao clicar no botão, verifique a senha e entre na aplicação, é isso?

È isso mesmo.

Então no evento click()

If txtpassword="xxxxxxxxxxxxxx" Then
DoCmd.OpenForm"xxxxxxxxxxxx"
Else
Call MsgBox("A password inserida não é válida",vbCVritical,"Aviso")
End If

Em vez de ser no botão, coloque este código no evento VBA ao abrir no seu relatorio ou relatorios...

Private Sub Report_Open(Cancel As Integer)
'By JPaulo ® Maximo Access
Dim strResposta As String
strResposta = InputBox("Entre com a senha...", "Senha", _
"", 2000, 1000)
Select Case strResposta
Case Is = ""
DoCmd.CancelEvent
Case Is = "jpaulo"
Exit Sub
Case Else
MsgBox "Senha incorreta...", vbCritical
DoCmd.CancelEvent
End Select
End Sub

Olá pessoal,

Obrigado pela atenção mas não consegui inserir os códigos que os srs. me enviaram e fazer funcionar.

Então é simples

1- o que enviei....No evento clique do botão que referiu


2- O que O Mestre enviou...No evento ao abrir do seu Relatório.

Basta colocar lá o código escolhido e que melhor se adapte às suas necessidades

Boa noite

Só é pena a máscara de introdução não ser "*******"

Assis, aqui no forum tem um exemplo que coloca máscar na inputbox.

Olá Criquio

Resolvi assim para a máscara ser " ******** "

Adaptado de um exemplo do Mestre JPaulo

Private Sub Form_Open(Cancel As Integer)
'Créditos JPaulo
Dim strResposta As String
strResposta = InputBoxDK(" © Insira a Senha © ", "© Password ©", "© Password ©")
Select Case strResposta
Case Is = ""
DoCmd.CancelEvent
Case Is = "jpaulo"
Exit Sub
Case Else
MsgBox "Senha Incorreta...", vbCritical
DoCmd.CancelEvent
End Select
End Sub


Colar num Modulo Novo

Option Compare Database
Option Explicit

Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _
ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long

Private Declare Function GetModuleHandle Lib "kernel32" Alias "GetModuleHandleA" ( _
ByVal lpModuleName As String) As Long

Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" ( _
ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) _
As Long

Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long

Private Declare Function SendDlgItemMessage Lib "user32" Alias "SendDlgItemMessageA" ( _
ByVal hDlg As Long, ByVal nIDDlgItem As Long, ByVal wMsg As Long, ByVal wParam As Long, _
ByVal lParam As Long) As Long

Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hWnd As Long, _
ByVal lpClassName As String, ByVal nMaxCount As Long) As Long

Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long

'Constants to be used in our API functions
Private Const EM_SETPASSWORDCHAR = &HCC
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
Private Const HC_ACTION = 0

Private hHook As Long

Public Function NewProc(ByVal lngCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Dim retval
Dim strClassName As String, lngBuffer As Long

If lngCode < HC_ACTION Then
NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam)
Exit Function
End If

strClassName = String$(256, " ")
lngBuffer = 255

If lngCode = HCBT_ACTIVATE Then 'A window has been activated
retval = GetClassName(wParam, strClassName, lngBuffer)
If Left$(strClassName, retval) = "#32770" Then 'Class name of the Inputbox
'This changes the edit control so that it display the password character *.
'You can change the Asc("*") as you please.
SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0
End If
End If

'This line will ensure that any other hooks that may be in place are
'called correctly.
CallNextHookEx hHook, lngCode, wParam, lParam

End Function


Public Function InputBoxDK(Prompt As String, Optional Title As String, Optional Default As String, _
Optional Xpos As Long, Optional Ypos As Long, Optional Helpfile As String, _
Optional Context As Long) As String

Dim lngModHwnd As Long, lngThreadID As Long

'// Lets handle any Errors JIC! due to HookProc> App hang!
On Error GoTo ExitProperly
lngThreadID = GetCurrentThreadId
lngModHwnd = GetModuleHandle(vbNullString)

hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID)
If Xpos Then
InputBoxDK = InputBox(Prompt, Title, Default, Xpos, Ypos, Helpfile, Context)
Else
InputBoxDK = InputBox(Prompt, Title, Default, , , Helpfile, Context)
End If

ExitProperly:
UnhookWindowsHookEx hHook

End Function