[Resolvido]como faço pra desabilitar ?

Boa tarde!!!
Como faço pra desabilitar "aquela rodinha do mouse", dentro de um formulário, já que não quero que ao tocá-la.. os registros se movimentem ?
obrigada..
gracy mary

Boa Tarde Gracy

Você necessita em primeiro lugar de um DLL que deve estar sempre junto da sua mdb e viajar com ela.Faça aqui o download
http://dl.dropbox.com/u/8157744/MouseHook.dll

Depois no evento ao abrir do seu formulário, coloque o seguinte código:
Dim blRet As Boolean
blRet = MouseWheelOFF(False)

De seguida no evento do form ao fechar:
' Turn the MouseWheel On
Dim blRet As Boolean
blRet = MouseWheelON

E pronto, a rodinha vai ficar sossegada e só activa no fechar do form

Não se esqueça de dar retorno e bom trabalho

Ola Mary seja bem vinda ao fórum;

Veja este exemplo também, sem DLL

http://dl.dropbox.com/u/771097/BloqueiaMouse.rar

pois é... não deu certo com a dll.. vem a mensagem.. "sub ou função não definida"... vou tentar sem a dll..
obrigada..
gracy mary

Uma outra forma é:

Abra as propriedades do formulário e localize Ciclo.

Por padrão vem selecionado: todos os registros, altere para registro atual.

Em tempo:

Isso só funciona para a tecla TAB.

O exemplo que o Mestre apontou não usa DLL e é muito bom, só não o apontei porque o hábito faz o monge e uso este por hábito mesmo. Contudo alguma coisa você fez mal Gracy, pois o exemplo que lhe enviei era e talvez ainda seja o mais usado de todos para resolver esta questão da roda.

Gracy

Peço desculpa pelo anterior. Você não fez nada errado, quem errou fui eu. Estava convicto que no download efectuado por si seguia tudo dentro de um Pasta e que o Módulo MouseHook ia lá dentro junto com a DLL. Dei-lhe o link errado, só da DLL.

Se pretender testar ou outro qualquer colega aqui vai tudo retificado:

Abrir um Módulo e colar o código abaixo:


Option Compare Database
Option Explicit

Private Declare Function LoadLibrary Lib "kernel32" _
Alias "LoadLibraryA" (ByVal lpLibFileName As String) As Long

Private Declare Function FreeLibrary Lib "kernel32" _
(ByVal hLibModule As Long) As Long

Private Declare Function StopMouseWheel Lib "MouseHook" _
(ByVal hwnd As Long, ByVal AccessThreadID As Long, Optional ByVal blIsGlobal As Boolean = False) As Boolean

Private Declare Function StartMouseWheel Lib "MouseHook" _
(ByVal hwnd As Long) As Boolean

Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long

' Instance returned from LoadLibrary call
Private hLib As Long


Public Function MouseWheelON() As Boolean
MouseWheelON = StartMouseWheel(Application.hWndAccessApp)
If hLib <> 0 Then
hLib = FreeLibrary(hLib)
End If
End Function

Public Function MouseWheelOFF(Optional GlobalHook As Boolean = False) As Boolean
Dim s As String
Dim blRet As Boolean
Dim AccessThreadID As Long

On Error Resume Next
' Our error string
s = "Sorry...cannot find the MouseHook.dll file" & vbCrLf
s = s & "Please copy the MouseHook.dll file to your Windows System folder or into the same folder as this Access MDB."

' OK Try to load the DLL assuming it is in the Window System folder
hLib = LoadLibrary("MouseHook.dll")
If hLib = 0 Then
' See if the DLL is in the same folder as this MDB
' CurrentDB works with both A97 and A2K or higher
hLib = LoadLibrary(CurrentDBDir() & "MouseHook.dll")
If hLib = 0 Then
MsgBox s, vbOKOnly, "MISSING MOUSEHOOK.dll FILE"
MouseWheelOFF = False
Exit Function
End If
End If

' Get the ID for this thread
AccessThreadID = GetCurrentThreadId()
' Call our MouseHook function in the MouseHook dll.
' Please not the Optional GlobalHook BOOLEAN parameter
' Several developers asked for the MouseHook to be able to work with
' multiple instances of Access. In order to accomodate this request I
' have modified the function to allow the caller to
' specify a thread specific(this current instance of Access only) or
' a global(all applications) MouseWheel Hook.
' Only use the GlobalHook if you will be running multiple instances of Access!
MouseWheelOFF = StopMouseWheel(Application.hWndAccessApp, AccessThreadID, GlobalHook)

End Function


'******************** Code Begin ****************
'Code courtesy of
'Terry Kreft & Ken Getz
'
Function CurrentDBDir() As String
Dim strDBPath As String
Dim strDBFile As String
strDBPath = CurrentDb.Name
strDBFile = Dir(strDBPath)
CurrentDBDir = Left$(strDBPath, Len(strDBPath) - Len(strDBFile))
End Function
'******************** Code End ****************

Guardar o módulo com o nome ModuloMouseHook

Assim funciona tudo direitinho.

Abraço

Pessoal.. deu certo a segunda opção... adaptei a minha necessidade.. abrindo o form o "botão desabilita"... ao fechar... "ele habilita"...
obrigada a todos...
gracy mary