[Resolvido]Abrir uma pasta (diretório) escolher arquivo a carregar para importação

Preciso abrir uma pasta (diretório) escolher arquivo a carregar para importação em uma tabela, sendo que a pasta(diretório)contem diversos arquivos para importação e quero fazer a importação de um de cada vez haja vista que todo mês vou importar um arquivo novo acrecentando os dados à tabela.

Como abrir uma janela escolher arquivo que vai ser importado ao executar uma macro-importação clicando em botão comando.
De modo que o usuario informe o local e nome do arquivo a ser importado, quando executar a macro de importação de dados.

Att.

Ervin de Menezes
Campo Mourão - PR
e_mail: ervindemenezes@gmail.com

teste


Private Sub teubotao_Click()
Call BrowsingWindow
End Sub

'habilite a referencia VBA Microsoft Office xx.x Object Library
Sub BrowsingWindow()

Dim Dlg As FileDialog
Dim txtFilePath As String
Dim varFile As Variant

Set Dlg = Application.FileDialog(msoFileDialogFilePicker)
With Dlg
.Title = "Select the file you want to import"
.AllowMultiSelect = False
If .Show = True Then

For Each varFile In .SelectedItems
txtFilePath = varFile
Next
DoCmd.TransferText acImportDelim, ";", "NovaTabela", txtFilePath
Else
Exit Sub
End If
End With

End Sub

OK, màs ao executar apresentou a seguinte mensagem:
Erro de compilação: O tipo definido pelo usuário não foi definido

Pode me ajudar ?

Ervin

Vc ativou a referência no VBA , conform o Ricardo te indicou ??

'habilite a referencia VBA Microsoft Office xx.x Object Library

Qual é versão do seu Access ?

OK deu certo, obrigado pela dica.

Boa noite fiz conforme anunciado no fórum e da erro

Private Sub importar_Click()
Call BrowsingWindow
End Sub

'habilitei a referencia VBA Microsoft Office 14.0 Object Library
Sub BrowsingWindow()

Dim Dlg As FileDialog
Dim txtFilePath As String
Dim varFile As Variant

Set Dlg = Application.FileDialog(msoFileDialogFilePicker)
With Dlg
.Title = "Select the file you want to import"
.AllowMultiSelect = False
If .Show = True Then

For Each varFile In .SelectedItems
txtFilePath = varFile
Next
DoCmd.TransferText acImportDelim, ";", "NovaTabela", txtFilePath
Else
Exit Sub
End If
End With

End Sub

Mas no campo Dlg As FileDialog da erro e não segue mais em frente e se eu mudo algo aí que nao funciona por favor me ajudem

Olá Edson Evangelista,
Testei aqui no 2010 e está a funcionar na perfeição.
Acho que será mesmo a questão das referencias, veja como fazer no editor do VBA:


Anexo o meu teste.
Abraço

Bom dia Amigos!
É possível fazer a importação de um arquivo em Excel, e já utilizando uma tabela existente com os parâmetros de entrada em cada campo?

Olá Lourandir Ramos, seja bem-vindo ao fórum.
Sim, é possível, pode importar como está (tabela temporária)
E depois será uma consulta adicionar da tabela temporária para a tabela pretendida.
No final eliminar tabela temporária.
Abraço

Alguém pode me ajudar?

Dá erro na parte  DoCmd.TransferText acImportDelim, ";", "NovaTabela", txtFilePath

Diz: "Não é possível importar este arquivo."

Sendo q a tabela q eu testei só tem 3 linhas


Essa "NovaTabela" é criada automaticamente?
Se não, o que preciso fazer na estrutura dela pra q consiga?

Olá Carol,

Que tipo de ficheiro está a tentar importar?
Pode disponbilizr exemplo com dados de amostragem para se verificar?.

Abraço

Então, testei primeiro a tabela que está em anexo. Aí deu esse erro.

Depois tentei importar uma tabela que so tinha "A","B","C" escrito e deu erro tbm.

Eu todo mês tenho q substituir os valores da tabela do access com os dados da nova tabela q eu vou importar

Olá Carol,

Deveria também ter enviado o código que está a usar.
Teste com o exemplo da mensagem nº 5 deste tópico já de 2016 e funcionou direitinho:
https://www.maximoaccess.com/t25383p4-resolvidodocmd-o-objeto-e-obrigatorio-erro-424

Depois será ajustar conforme este tópico para escolher o ficheiro.
Se continuar com dúvida, partilhe base de dados apenas com o código que esta a utilizar para se testar.

Abraço

O código que eu usei é igual ao q vc mandou. Só copiei e colei.



Mas resolvi através do código:
Obrigada!

Código:

Private Sub Comando145_Click()
  Dim Ficheiro As String
   
    With Application.FileDialog(msoFileDialogOpen)
        .AllowMultiSelect = False
        .Filters.Clear
        .Filters.Add "Excel", "*.xls,*.xlsx"
        .FilterIndex = 1

        If .Show = 0 Then
            'Cancelado
        Else
            Ficheiro = .SelectedItems(1)
            DoCmd.DeleteObject acTable, "TabSaldo"
            ' importa 7 colunas de uma folha de excel com os nomes dos campos na primeira linha
            DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel12, "TabSaldo", Ficheiro, True, "A:H"
            MsgBox "O arquivo " & Ficheiro & " foi importado com sucesso!", , "Atualização de Saldo"
        End If

    End With


End Sub

Olá Carol,

Obrigado pelo retorno, que bom que resolveu.
Já tinha efetuado um exemplo, veja como ficou:

Código:

Private Sub cmdExcel_Click()
'ahteixeira 2020 para MaximoAccess
'habilitar a referencia VBA Microsoft Office xx.x Object Library
Dim Dlg            As FileDialog
Dim txtFilePath    As String
Dim varFile        As Variant

Set Dlg = Application.FileDialog(msoFileDialogFilePicker)

    With Dlg
        .Title = "Escolha o ficheiro para importar"
        .AllowMultiSelect = False
        If .Show = True Then
            For Each varFile In .SelectedItems
                txtFilePath = varFile
            Next
            DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel9, "tbl_importada", txtFilePath, True
        Else
            Exit Sub
        End If
    End With
End Sub


Abraço

Olá carolinesilva115

obrigado por compartilhar esse código, funcionou perfeitamente.