[Resolvido]Erro ao importar arquivo

Bom dia.
Uso Access 2010 - 64 bits.

Tenho um formulário para fazer a importação de arquivos textos para o meu banco de dados.
Quando usava o access de 32 bits essa importação funcionava, agora no 64 bits quando eu clico no botão localizar arquivos ele não funciona.

O procedimento do evento do botão é o seguinte:

Private Sub BtLocalizar_Click()
Dim sFilter As String
sFilter = "Arquivos de Texto (*.txt)" & Chr(0) & "*.txt" & Chr(0)
Me.Arq = LocalizarArquivo("c:\caminho", "Localizando Arquivo", sFilter)
End Sub

E a função "LocalizarArquivo" é a seguinte:

Option Compare Database
Option Explicit

Private Declare PtrSafe Function GetOpenFileName Lib "comdlg32.dll" Alias _
"GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long

Private Type OPENFILENAME
lStructSize As LongLong
hwndOwner As LongLong
hInstance As LongLong
lpstrFilter As String
lpstrCustomFilter As String
nMaxCustFilter As LongLong
nFilterIndex As LongLong
lpstrFile As String
nMaxFile As LongLong
lpstrFileTitle As String
nMaxFileTitle As LongLong
lpstrInitialDir As String
lpstrTitle As String
flags As LongLong
nFileOffset As Integer
nFileExtension As Integer
lpstrDefExt As String
lCustData As LongLong
lpfnHook As LongLong
lpTemplateName As String
End Type

Public Function LocalizarArquivo(strDirIni As String, strTitulo As String, _
strFiltro As String)
Dim OpenFile As OPENFILENAME
Dim lReturn As Long
OpenFile.lStructSize = Len(OpenFile)
OpenFile.lpstrFilter = strFiltro
OpenFile.nFilterIndex = 1
OpenFile.lpstrFile = String(257, 0)
OpenFile.nMaxFile = Len(OpenFile.lpstrFile) - 1
OpenFile.lpstrFileTitle = OpenFile.lpstrFile
OpenFile.nMaxFileTitle = OpenFile.nMaxFile
OpenFile.lpstrInitialDir = strDirIni
OpenFile.lpstrTitle = strTitulo
OpenFile.flags = 0
lReturn = GetOpenFileName(OpenFile)
If lReturn = 0 Then
LocalizarArquivo = ""
Else
LocalizarArquivo = Trim(OpenFile.lpstrFile)
End If
End Function

Por favor alguém me ajude a localizar o erro.
Grato
Elias

teste por favor;


Private Declare Sub PathStripPath Lib "shlwapi.dll" _
Alias "PathStripPathA" (ByVal pszPath As String)
Private Declare Function GetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long

Private Type OPENFILENAME
lStructSize As LongLong
hwndOwner As LongLong
hInstance As LongLong
lpstrFilter As String
lpstrCustomFilter As String
nMaxCustFilter As LongLong
nFilterIndex As LongLong
lpstrFile As String
nMaxFile As LongLong
lpstrFileTitle As String
nMaxFileTitle As LongLong
lpstrInitialDir As String
lpstrTitle As String
flags As LongLong
nFileOffset As Integer
nFileExtension As Integer
lpstrDefExt As String
lCustData As LongLong
lpfnHook As LongLong
lpTemplateName As String
End Type

Public Function LocalizarArquivo(strDirIni As String, strTitulo As String, _
strFiltro As String)
Dim OpenFile As OPENFILENAME
Dim lReturn As Long
OpenFile.lStructSize = Len(OpenFile)
OpenFile.lpstrFilter = strFiltro
OpenFile.nFilterIndex = 1
OpenFile.lpstrFile = String(257, 0)
OpenFile.nMaxFile = Len(OpenFile.lpstrFile) - 1
OpenFile.lpstrFileTitle = OpenFile.lpstrFile
OpenFile.nMaxFileTitle = OpenFile.nMaxFile
OpenFile.lpstrInitialDir = strDirIni
OpenFile.lpstrTitle = strTitulo
OpenFile.flags = 0
lReturn = GetOpenFileName(OpenFile)
If lReturn = 0 Then
LocalizarArquivo = ""
Else
LocalizarArquivo = Trim(OpenFile.lpstrFile)
End If
End Function

Obrigado pela ajuda JPaulo, mas continua não funcionando.
Quando clico no botão não acontece nada, ele teria que abrir uma janela para procurar o arquivo.

Abraços

E o amigo tem a segurança de macros baixa ?

Veja isso no botão do Office lado esquerdo.

É que este PtrSafe no 64 bit não funfa mesmo, daí ter de ser assim como lhe passei.

JPaulo.
Sim todas as macros estão habilitadas.
Sem o PtrSafe da erro, pede para atualizar o Declare com o PtrSafe.
Grato
Elias

Declaração da estrutura OPENFILENAME para o Access 2010 - 64 bits


Option Explicit

#If VBA7 Then
Private Declare PtrSafe Sub PathStripPath Lib "shlwapi.dll" _
Alias "PathStripPathA" (ByVal pszPath As String)
Private Declare PtrSafe Function GetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long
#Else
Private Declare Sub PathStripPath Lib "shlwapi.dll" _
Alias "PathStripPathA" (ByVal pszPath As String)
Private Declare Function GetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long
#End If

Private Type OPENFILENAME
lStructSize As Long
#If VBA7 Then
hwndOwner As LongPtr
hInstance As LongPtr
#Else
hwndOwner As Long
hInstance As Long
#End If
lpstrFilter As String
lpstrCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
lpstrFile As String
nMaxFile As Long
lpstrFileTitle As String
nMaxFileTitle As Long
lpstrInitialDir As String
lpstrTitle As String
flags As Long
nFileOffset As Integer
nFileExtension As Integer
lpstrDefExt As String

#If VBA7 Then
lCustData As LongPtr
lpfnHook As LongPtr
#Else
lCustData As Long
lpfnHook As Long
#End If
lpTemplateName As String
End Type


'Constantes
'Declaração da estrutura OPENFILENAME de 64 bits
Private Const OFN_HIDEREADONLY = &H4

#If VBA7 Then
Public Function LocalizarArquivo(Handle As LongPtr, _
Titre As String, _
TypeRetour As Byte, _
Optional TitreFiltre As String, _
Optional TypeFichier As String, _
Optional RepParDefaut As String) As String
#Else
Public Function LocalizarArquivo(Handle As Long, _
Titre As String, _
TypeRetour As Byte, _
Optional TitreFiltre As String, _
Optional TypeFichier As String, _
Optional RepParDefaut As String) As String
#End If

Dim StructFile As OPENFILENAME
Dim sFiltre As String

'Construção de filtro com base nos argumentos especificados

If Len(TitreFiltre) > 0 And Len(TypeFichier) > 0 Then
sFiltre = TitreFiltre & " (" & TypeFichier & ")" & Chr$(0) & "*." & TypeFichier & Chr$(0)
End If
sFiltre = sFiltre & "Tous (*.*)" & Chr$(0) & "*.*" & Chr$(0)

'Configuração da caixa de dialogo
With StructFile
.lStructSize = LenB(StructFile)
.hwndOwner = Handle
.lpstrFilter = sFiltre
.lpstrFile = String$(254, vbNullChar)
.nMaxFile = 254
.lpstrFileTitle = String$(254, vbNullChar)
.nMaxFileTitle = 254
.lpstrTitle = Titre
.flags = OFN_HIDEREADONLY
If ((IsNull(RepParDefaut)) Or (RepParDefaut = "")) Then
RepParDefaut = CurrentDb.Name
PathStripPath (RepParDefaut)
.lpstrInitialDir = Left(CurrentDb.Name, Len(CurrentDb.Name) - Len(Mid$(RepParDefaut, 1, _
InStr(1, RepParDefaut, vbNullChar) - 1)))
Else: .lpstrInitialDir = RepParDefaut
End If
End With

If (GetOpenFileName(StructFile)) Then
Select Case TypeRetour
Case 1: LocalizarArquivo = Trim$(Left(StructFile.lpstrFile, InStr(1, StructFile.lpstrFile, vbNullChar) - 1))
Case 2: LocalizarArquivo = Trim$(Left(StructFile.lpstrFileTitle, InStr(1, StructFile.lpstrFileTitle, vbNullChar) - 1))
End Select
End If

End Function

http://msdn.microsoft.com/pt-br/library/ee691831(office.14).aspx

JPaulo coloquei o código que vc me passou.
Agora quando clico no botão localizar arquivo está dando o seguinte erro:

Erro de compilação:
Tipo incompatível de argumento ByRef

e marca o sFilter dessa linha:

Me.Arq = LocalizarArquivo("c:\caminho", "Localizando Arquivo", sFilter)

Por enquanto obrigado pela ajuda

Ricardo
Vou dar uma olhada no site do msdn
Obrigado

teste assim;

Arq = LocalizarArquivo(Me.Hwnd, "Localizando Arquivo", 1, "Ficheiro Texto ", "txt")
DoCmd.TransferText acImportDelim, CSV_Format_Import, "Tabela temp", Arq, True
Exit Sub

JPaulo
Beleza, agora funcionou.
Muito obrigado
Abraços
Elias

Dar o tópico por terminado. Obrigado