[Resolvido]Abrir Um Formulário Filtrado De Outro BD

Bom dia a todos

depois de muito pesquisar sem sucesso resolvi pedir mais uma vez a ajuda de vcs do forum.

Não sei se fui muito claro no titulo do topico entao vou explicar melhor:

Estou tentando abrir um registro passado pela função de um certo banco de dados, ao qual vamos chamar de MeuBD1 e quero abrir um outro Formulario do MeuBD2 filtrando o registro que eu passei como criterio na função. Pois bem eu tenho partes da minha necessidade, mas não sei como unir... eis o que eu tenho.

Por enquanto so sei abrir o MeuBD2 que no caso chama Ger_Micros, quando eu abro esse banco ele ja abre o formulario que eu tenho a informação que eu preciso. Se fosse para abrir o formulários específico não sei como faria. Por favor, Se vcs puderem tirem essa dúvida tb? se não for abusar.

Segue Codigo:


Sub OpenDB(codigo)

'Abri o outro banco de dados
'************************************************************************
Dim MinhaPassword As Variant
MinhaPassword = "suporteltr"

strDbName = "D:\Meus Documentos\Pessoal\My Programs\Projeto Access\Ger Micros\Ger_Micros.accdb"

Set objaccess = New Access.Application
Set db = objaccess.DBEngine.OpenDatabase(strDbName, False, False, ";PWD=" & MinhaPassword)

objaccess.OpenCurrentDatabase filepath:=strDbName
'FIM
'/////////////////////////////////////////////////////////////////////////


End Sub

Eu uso a seguinte o codigo para abrir um formulario filtrado:

sub openMeuFormulario(codigo as long)

DoCmd.OpenForm "MeuFormulario", , , "[Codigo] = " & [SN]

End Sub

Como eu faço para unir os dois codigos para abrir um formulário filtrado de outro bd.


Grato

Ola Ronaldo bom dia !

Utilize este meu código;

Cole num modulo novo e salve sem alterar nada, excepto a senha:

Function AbreExternoFormFiltrado(strCaminhoBanco As String, strNomeForm As String, strCampoFiltro As String, strCampoValorFiltro As Long)
'By JPaulo ® Maximo Access
    Dim AccessObj As Object
    Dim Accessform As Object
    Dim rst As DAO.Recordset
    Dim db As DAO.Database
    Dim strBookmark As String
    Dim MinhaPassword As Variant
    
    'defina a senha do banco externo
    MinhaPassword = "suporteltr"

    DoCmd.RunCommand acCmdAppMinimize
    
    Set AccessObj = CreateObject("Access.Application")
    Set db = AccessObj.DBEngine.OpenDatabase(strCaminhoBanco, False, False, ";PWD=" & MinhaPassword)
    AccessObj.OpenCurrentDatabase (strCaminhoBanco)

    AccessObj.DoCmd.OpenForm strNomeForm
    With AccessObj.Forms(strNomeForm)
        Set rst = .RecordsetClone
        rst.FindFirst strCampoFiltro & "=" & strCampoValorFiltro
        If rst.NoMatch Then
            MsgBox "Registro não encontrado...", vbCritical
        Else
            .Bookmark = rst.Bookmark
        End If
    End With
    AccessObj.UserControl = True
End Function

Para chamar esta função, por exemplo no evento ao pressionar de um botão:



Private Sub SeuBotão_Click()
AbreExternoFormFiltrado "D:\Meus Documentos\Pessoal\My Programs\Projeto Access\Ger Micros\Ger_Micros.accdb", "MeuFormulario", "Codigo", Me.SN
End Sub


http://maximoaccess.forumeiros.com/t11-102-codigos-vba-para-access#14

Nossa JPaulo, vc é fera. vlw era isso mesmo.

Muito obrigado pela ajuda.

se nao for abusar de vc, vc tem algum link ou site que ensina a utilizar os objetos access. Ja pesquisei pra caramba, mas só acho codigos prontos eu quero aprender a manipular os objetos como vc e os cara fera do forum faz.

Grato

Obrigado pelo retorno o fórum agradece.

Na minha opinião, você deveria de ler muitos tutoriais, alguns encontram-se aqui mesmo, na sala de Documentação.

Alguns sites que recomendo, para o ajudar;

http://msdn.microsoft.com/en-us/library/office/aa191636(v=office.10).aspx

http://www.usandoaccess.com.br/index.htm

http://www.accessruncommand.com/list/lista.htm

http://www.accessfaq.com.br/webroot/

http://allenbrowne.com/binary/Access_Basics_Crystal_080220_Chapter_02.pdf

Obrigado pela ajuda. Esses link vao me auxiliar muito. Vlw

Se te ver como me responder uma última dúvida eu ficaria agradecido.

No codigo que vc me passou o ultimo parametro da função é do tipo long

eu tb preciso fazer a mesma função pra tipo de dado string, então eu mudei o ultimo parametro pra tipo string, a função da um erro de Operador faltando nessa parte:

rst.FindFirst strCampoFiltro & "=" & strCampoValorFiltro

O q eu tenho que mudar pra não dar erro?

Intão, se é string tem de levar com as aspas simples;

rst.FindFirst strCampoFiltro & "='" & strCampoValorFiltro & "'"

Grato