[Resolvido]Deletar vinculos não as tabelas

Boa tarde!
Venho mais uma vez solicitar a ajuda dos colegas para o seguinte: Gostaria que o código abaixo só delete as tabelas que estão vinculadas, mas, este código deleta todas as tabelas.

Desde já agradeço a todos!

Public Function DeletaTabelas()
Dim dbs As DAO.Database
Dim i As Integer
Set dbs = CurrentDb
For i = dbs.Relations.Count - 1 To 0 Step -1
dbs.Relations.Delete dbs.Relations(i).Name
Next i
For i = dbs.TableDefs.Count - 1 To 0 Step -1
If Left(dbs.TableDefs(i).Name, 4) <> "MSys" Then
dbs.TableDefs.Delete dbs.TableDefs(i).Name
End If
Next i
Set dbs = Nothing
End Function

Boa tarde, pode demora a excluir, mas exclui as tabelas de dentro do access, somente.

Código:

Private Sub Comando0_Click()
    Call DeletaTabelas
End Sub
Public Function DeletaTabelas()
    Dim dbs As DAO.Database
    Dim i As Integer
    Set dbs = CurrentDb
   
    For i = dbs.Relations.Count - 1 To 0 Step -1
        dbs.Relations.Delete dbs.Relations(i).Name
    Next i
  For i = dbs.TableDefs.Count - 1 To 0 Step -1
        With dbs.TableDefs(i)
            If .Connect <> "" And Left(.Name, 4) <> "MSys" Then
                dbs.TableDefs.Delete .Name
            End If
        End With
    Next i
   
    Set dbs = Nothing
End Function


Boa noite

Código:

Public Function DeletaTabelasLigadas()
    Dim dbs As DAO.Database, i As Integer
    Set dbs = CurrentDb
    For i = dbs.Relations.Count - 1 To 0 Step -1
        dbs.Relations.Delete dbs.Relations(i).Name
    Next i
    For i = dbs.TableDefs.Count - 1 To 0 Step -1
        If Left(dbs.TableDefs(i).Name, 4) <> "MSys" And Len(CurrentDb.TableDefs(i).Connect) > 0 Then
            dbs.TableDefs.Delete dbs.TableDefs(i).Name
        End If
    Next i
    Set dbs = Nothing
End Function

Desculpe amigo crysostomo. Estava a preparar resposta quando respondeu. O colega fica com 2 ajudas que é melhor que uma só.
Abraço

Boa noite!

Muito obrigado, mais uma vez, pela ajuda. Consegui resolver.

Fiquem com Deus!