Backup de 3 tabelas

Olá a todos

Procurei no fórum algo parecido com a minha dúida para adaptar ao meu caso mas não encontrei

Até achei tópicos interessantes como do mestre JPaulo que faz backup de todas as tabelas, mas gostaria de fazer backup de apenas 3 tabelas

Desde já, se alguem puer me ajudar ficarei muito grato

Olá

Colar num módulo novo e alterar para o nome correto das tabelas pretendidas para o seu backup, na linha do novo IF;

(If tblTabelas.Name = "SuaTabela1" Or tblTabelas.Name = "SuaTabela2" Or tblTabelas.Name = "SuaTabela3" Then)

Código:

Public Function CriaBackupTabelas() As Boolean
'Criado por JPaulo
'www.maximoaccess.com
'02-02-2011
Dim strCaminhoPastaBackup As String
Dim strNomeParaBancoBackup$
Dim strFormataDataHora$
Dim StrCaminhoFinal$
Dim strCaminhoFinalCompleto$
Dim objFSO As Object
Dim tblTabelas As DAO.TableDef
Dim db As DAO.Database

strCaminhoPastaBackup = "C:\temp"
strNomeParaBancoBackup = "Backup_2022"
strFormataDataHora = Format(Now(), "_mm-dd-yyyy hh-mm AM/PM")

'caminho completo e novo nome para o banco de backup
strCaminhoFinalCompleto = strCaminhoPastaBackup & "\" & strNomeParaBancoBackup & strFormataDataHora & ".accdb"

Set db = CurrentDb

        Set objFSO = CreateObject("Scripting.FileSystemObject")
'se já existir com a data hora acima, apaga
        If objFSO.FileExists(strCaminhoFinalCompleto) Then
            Kill strCaminhoFinalCompleto
        End If
'se não existir, cria o novo banco de backup, com o idioma do computador, ou inglês, português, etc...
        DBEngine.CreateDatabase strCaminhoFinalCompleto, dbLangGeneral
        With db
'percorre as tabelas e ignora as tabelas de sistema interno
            For Each tblTabelas In .TableDefs
                Select Case True
                Case Left(tblTabelas.Name, 1) = "~"
                Case Left(tblTabelas.Name, 4) = "msys"
                Case Else
'Aqui é uma alteração a pedido da duvida
'Escreva o nome das tabelas pretendidas para fazer o backup
            If tblTabelas.Name = "SuaTabela1" Or tblTabelas.Name = "SuaTabela2" Or tblTabelas.Name = "SuaTabela3" Then
               
'copia as tabelas para o banco de backup
                    .Execute "SELECT * INTO [" & strCaminhoFinalCompleto & "].[" & tblTabelas.Name & "] from [" & tblTabelas.Name & "]"
            End If
           
                End Select
            Next
            MsgBox "Backup efetuado com sucesso", vbInformation, "Sucesso"
        End With
   
Set objFSO = Nothing
End Function