[Resolvido]Criar atalho de pasta na área de trabalho do pc

Olá pessoal!

Tenho uma subpasta chamada "boletins" que está dentro da pasta "meusistema" na unidade C:\.
Como posso, via vba, ao clicar em um botão criar um atalho da pasta boletins na área de trabalho do pc?


grato...

Bom dia.

Melhor fazer via Windows mesmo, com o botão direito do mouse sobre a pasta que quer criar atalho.
Mais fácil e simples.


Mas, se quiser via vba, segue o link.

https://www.maximoaccess.com/t10398-resolvidocriar-atalho-de-uma-macro-para-fora-do-access-via-codigo

Oi Sílvio. Obrigado pelo retorno.

Criei uma rotina que gera os boletins de alunos de uma determinada turma, no seguinte caminho: C:\meusistema\Boletins
Para que o usuário não precise percorrer o caminho usando o explore, acho melhor que haja um atalho da pasta "boletins" na área de trabalho.

Quando o usuário for usar este recurso pela primeira vez, caso a pasta "boletins" não exista, gostaria que o sistema criasse a pasta "boletins" dentro da pasta "meusistema" e também o atalho da pasta "boletins" na área de trabalho.

Já tentei aqui mas não consigo.

De experiência própria....crie a pasta e um atalho para ela no desktop manualmente....vai ganhar muito mais tempo.

Com todo respeito ao profissional que você certamente é e a sua generosidade em querer me ajudar, acho que não é o melhor caminho para um sistema. Vou tentar explicar porque acho isso. Caso instale o sistema e esqueça de criar esta pasta manualmente, o que pode acontecer, pois somos falhos, quando o usuário executar esta função pela primeira vez, poderá ficar frustrado. Esperarei um pouco mais aqui, caso ninguém possa me ajudar nisto, darei o tópico como reslçvido e usarei a sua ideia.

grato...

Eis alguns links para te auxiliar no desenvolvimento do teu sistema.

https://www.maximoaccess.com/t16745-resolvidocriar-pasta ...se encontra aqui no fórum

www.youtube.com/watch?v=Gq4EsK51Tlg&ab_channel=MarceloDavid-Treinamentos ...um dos membros aqui do fórum

Grato. Irei verificar.

Com a ferramenta de busca achei o tópico do link abaixo... e adaptei. Bem simples. (Salve, Marcelo)
https://www.maximoaccess.com/t38292-cria-atalho-do-projeto-no-desktop-do-usuario-atual

Código:

Public Sub subCriaAtalho()
'Autor: Marcelo David
'Data: 04/08/2020
'Propósito: criar ícone do aplicativo na área de trabalho do usuário ao executar o programa
Dim wsc As Object
Dim lnk
Dim strPathDesktop As String, strPasta As String

On Error GoTo TrataErro

    'Instancio o Windows Scripting Host
    Set wsc = CreateObject("wscript.shell")
    
    'Obtendo o path do desktop do usuário atual
    strPathDesktop = wsc.SpecialFolders("Desktop")
    
    strPasta = "c:\esd"
    
    'Instanciando um objeto do tipo atalho (lnk) e já definindo o desktop do usuário atual
    Set lnk = wsc.CreateShortcut(strPathDesktop & "\" & Split(strPasta, "\")(UBound(Split(strPasta, "\"))) & ".lnk")
    
    'Verificando se já existe atalho e caso sim, apaga para criar o novo
    If Dir(strPathDesktop & "\" & Split(strPasta, "\")(UBound(Split(strPasta, "\"))) & ".lnk") <> "" Then
        Kill strPathDesktop & "\" & Split(strPasta, "\")(UBound(Split(strPasta, "\"))) & ".lnk"
    End If
    
    'Difinindo o aplicativo a ser executado ao clicar no link
    lnk.TargetPath = strPasta
    
    'Definindo a propriedade de "Iniciar em" do atalho (diretório de trabalho)
    lnk.WorkingDirectory = strPasta
    
    'Salvando o link
    lnk.Save
    
    'Apagando da memória o objeto Windows Scripting Host e o link
    Set lnk = Nothing 'Nem precisava apagar esse, já que é filho de wsc, mas para manter o bom hábito de apagar variávais de objetos
    Set wsc = Nothing
    
Exit Sub
    
TrataErro:
    MsgBox Err.Description, vbExclamation, "Erro " & Err.Number & " ao criar atalho"
End Sub


PS: sugiro não ter uma função que crie um atalho, mas sim um botão que abra a pasta.

Estou tentando adaptar. Acho que vai dar certo!

Aguardamos...

Funcionou perfeitamente.

Apenas fiz uma alteração (linha vermelha) e criei um módulo. Transformei a sub em função para que possa usar em mais de um formulário.

Muito grato!!!!!

----------------------------------------------

Public Sub subCriaAtalho()
'Autor: Marcelo David
'Data: 04/08/2020
'Propósito: criar ícone do aplicativo na área de trabalho do usuário ao executar o programa
Dim wsc As Object
Dim lnk
Dim strPathDesktop As String, strPasta As String

On Error GoTo TrataErro

   'Instancio o Windows Scripting Host
   Set wsc = CreateObject("wscript.shell")
   
   'Obtendo o path do desktop do usuário atual
   strPathDesktop = wsc.SpecialFolders("Desktop")
   
  strPasta = CurrentProject.Path & "\Boletins"
   
   'Instanciando um objeto do tipo atalho (lnk) e já definindo o desktop do usuário atual
   Set lnk = wsc.CreateShortcut(strPathDesktop & "\" & Split(strPasta, "\")(UBound(Split(strPasta, "\"))) & ".lnk")
   
   'Verificando se já existe atalho e caso sim, apaga para criar o novo
   If Dir(strPathDesktop & "\" & Split(strPasta, "\")(UBound(Split(strPasta, "\"))) & ".lnk") <> "" Then
       Kill strPathDesktop & "\" & Split(strPasta, "\")(UBound(Split(strPasta, "\"))) & ".lnk"
   End If
   
   'Difinindo o aplicativo a ser executado ao clicar no link
   lnk.TargetPath = strPasta
   
   'Definindo a propriedade de "Iniciar em" do atalho (diretório de trabalho)
   lnk.WorkingDirectory = strPasta
   
   'Salvando o link
   lnk.Save
   
   'Apagando da memória o objeto Windows Scripting Host e o link
   Set lnk = Nothing 'Nem precisava apagar esse, já que é filho de wsc, mas para manter o bom hábito de apagar variávais de objetos
   Set wsc = Nothing
   
Exit Sub
   
TrataErro:
   MsgBox Err.Description, vbExclamation, "Erro " & Err.Number & " ao criar atalho"
End Sub

O fórum agradece o retorno. Sucesso.