[Resolvido]Filtro Grupos de Opções Combinados

Bom dia!
Eu tenho um formulário com dois grupos de opções - filtros, um se chama FiltroEntrevistador e o outro FiltroStatus.
Ambos funcionam porém independente um do outro. Ambos os Filtros tem a opção "TODOS".
Gostaria de fazer com que ambos se relacionassem.
Não sei se mudo algo nestes códigos ou se deve ser criado um terceiro. Enfim, sou novo nesse negócio e peço ajuda.
Grato,
Marco.

Segue código dos dois filtros:

Private Sub FiltroEntrevistador_AfterUpdate()

If FiltroEntrevistador = 1 Then
Me.FilterOn = False

Else
If FiltroEntrevistador = 2 Then
Me.Filter = "Entrevistador = 'LILIAN'"
Me.FilterOn = True
End If
If FiltroEntrevistador = 3 Then
Me.Filter = "Entrevistador = 'REZENDE'"
Me.FilterOn = True
End If

End If
End Sub
________________________________________
Private Sub FiltroStatus_AfterUpdate()

If FiltroStatus = 1 Then
Me.FilterOn = False

Else
If FiltroStatus = 2 Then
Me.Filter = "Status_da_Entrevista = '2' "
Me.FilterOn = True
End If
If FiltroStatus = 3 Then
Me.Filter = "Status_da_Entrevista = '1' "
Me.FilterOn = True
End If
If FiltroStatus = 4 Then
Me.Filter = "Status_da_Entrevista = '3' "
Me.FilterOn = True
End If

End If
End Sub

como assim ambos se relacionem ?

Hoje da forma como estão, eles funcionam independentes. Ou seleciono Entrevistador com Status em outros, ou seleciono Status com Entrevistador em outros. Desta forma eles funcionam, de outra forma o resultado fica errado.

O que desejo:
Quando eu clicar no filtro entrevistador e selecionar o entrevistador, o formulário abre apenas os registros das suas entrevistas e se após eu clicar no filtro Status, o filtro seleciona daquele entrevistador do filtro 1, quais são as entrevistas com o status selecionado no filtro 2, e vice versa...

Desta forma conseguirei exibir por Entrevistador, os Status das entrevistas desse, após seleção no filtro 1 e 2 e vice versa.

É como se um filtro fosse o escravo do outro, ou subfiltro.

Ex: Entrevistador REZENDE, Status 3

Para entendimento: Status 1 = Agendada, 2 = Pendente, 3 = Finalizada

Não sei se consegui ser claro, peço ajuda.

Obrigado pela atenção.

Se você tem o relacionamento de bancos esse ajuda

Código:

DoCmd.OpenForm "AreaDoEntrevistador", , , "Entrevistaor= """ & Me!colunaEntrevistador.Column(1) & """"

Se não for , coloque o Bd aqui

Marco, basta procurar no fórum por "filtros dependentes" ou "filtros em cascata". Este assunto é constantemente tocado aqui.

https://www.maximoaccess.com/search

Pesquisei, tentei alguns códigos, mas não consegui fazer funcionar os dois filtros em cascata.

O que desejo:
Quando eu clicar no filtro entrevistador e selecionar o entrevistador, o formulário abre apenas os registros das suas entrevistas e se após eu clicar no filtro Status, o filtro seleciona daquele entrevistador do filtro 1, quais são as entrevistas com o status selecionado no filtro 2, e vice versa...

Segue arquivo BD.

Obrigado.

Função criada para ser colocada junto do código do formulário

Código:

Private Sub FavorFiltrar()

    Dim strFiltro As String

    If Me!FiltroEntrevistador.Value = 1 And Me!FiltroStatus.Value = 1 Then
        Me.Filter = ""
        Me.FilterOn = False
    Else
   
        If Me!FiltroEntrevistador.Value > 1 Then
            strFiltro = "Entrevistador = """ & Choose(Me!FiltroEntrevistador.Value - 1, "LILIAN", "REZENDE") & """"
        End If
       
        If Me!FiltroStatus.Value > 1 Then
            If strFiltro <> "" Then strFiltro = strFiltro & " And "
            strFiltro = strFiltro & "Status_da_Entrevista = """ & Choose(Me!FiltroStatus.Value - 1, 2, 1, 3) & """"
        End If
       
        Me.Filter = strFiltro
        Me.FilterOn = True
       
    End If

End Sub

Eventos que chamam o código

Código:

Private Sub FiltroEntrevistador_AfterUpdate()
    Call FavorFiltrar
End Sub
Private Sub FiltroStatus_AfterUpdate()
    Call FavorFiltrar
End Sub

Excelente!

Agradeço demais, funcionou perfeitamente, porém identifiquei uma situação que só percebi na prática:

Supondo que não há registro encontrado na combinação das duas seleções, é possível exibir uma caixa de mensagem "Registro não encontrado", sendo que ao clicar no OK da mensagem, a tela retorna o filtro para a condição todos, tanto quando não localizado no filtro Status, como no entrevistador?

Por exemplo: Não existe registro do Entrevistador "Rezende" com o Status "1" (no caso agendado).

Aparece a mensagem e ao clicar em OK, o filtro Status retorna para a condição todos.

Da forma como está o formulário parece que fecha, fica tela em branco sem nenhuma informação e opção de voltar.

Mais uma vez agradeço se puder me ajudar com isso.

Desculpe a falta de previsibilidade da situação.

Eu entendi o código, porém não sei como colocar esta condicional.

Código:

Private Sub FiltroEntrevistador_AfterUpdate()

    dim objrs as dao.recordset
    dim j as boolean

    Call FavorFiltrar

    set objrs = me.recordsetclone
    j = (objrs.recordcount = 0)
    set objrs = nothing

    if j = true then
        me!FiltroEntrevistador.value = 1
        call FiltroEntrevistador_AfterUpdate
    end if

End Sub

Cara, muito obrigado.

Ficou muito legal.

Adicionei ainda ao seu código uma mensagem informando que entrevistado não possui registro com este status, seleção automática para Todos.

Estou aprendendo muito.

Valeu mesmo.

Abração.

O fórum agradece o retorno. Sucesso.