[Resolvido]Esconder ficheiro, alterar Atributo de normal para oculto

Boa noite

O código abaixo cria um ficheiro de texto "Locked.txt". Como criar o mesmo mas "Oculto" ?

Código:

Private Sub cmdLock_Click()

On Error GoTo Err_Handler

Dim fso As Object, aFile As Object
Dim blnLock As Boolean
Dim strText1 As String, strText2 As String

'Set fso = CreateObject("Scripting.FileSystemObject")

blnLock = False
   
If Me.cmdLock.Caption = "&Lock Database" Then
   Me.lblLocked.Visible = False
   If Nz(Me.txtFile, "") = "" Then
       strPath = CurrentProject.Path
       
       If FormattedMsgBox("Are you SURE you want to LOCK the current database?      " & _
           "@ @", vbExclamation + vbYesNo + vbDefaultButton2, "Lock current database?") = vbNo Then Exit Sub
   Else
       strPath = Me.txtPath
   End If
   
  ' Debug.Print strPath
 
   strText1 = "This will create a textfile 'Locked.txt' in the selected database folder.            "
   
   strText2 = "If this file is present in a database folder, users will see a message when the database is opened.      " & vbNewLine & _
   "The message states that the database is not available due to system maintenance then the database exits.           " & vbNewLine & vbNewLine & _
   "NOTE: For this to work successfully:         " & vbNewLine & _
   "1. COPY the module 'modLockedOut' from the 'CheckCurrentUsers' database to the destination database            " & vbNewLine & _
   "2. ADD the line 'Call LockedOut' to the Form_Load event of the destination database         "
   
   If FormattedMsgBox(strText1 & "@" & strText2 & vbNewLine & vbNewLine & "Do you want to do this now?    @", _
       vbExclamation + vbYesNo + vbDefaultButton2, "Lock selected database?") = vbYes Then
       
       blnLock = True
       strMsg = strText2
   
       Open strPath & "\Locked.txt" For Output As #1
       Print #1, strMsg
       Close #1
     
       Me.cmdLock.Caption = "&Unlock Database"
       Me.lblLocked.Visible = True
   End If
   
Else
   strPath = Nz(Me.txtPath, CurrentProject.Path)
   strFileName = strPath & "\Locked.txt"
   
   'delete locked.txt file
   If Dir(strFileName) <> "" Then
       'First remove read only attribute, if set
       SetAttr strFileName, vbNormal
       Kill strFileName
   End If
   
   Me.cmdLock.Caption = "&Lock Database"
   Me.lblLocked.Visible = False
End If

Olá Assis,

Será isto o que pretende:
https://www.maximoaccess.com/t31973-resolvidooculta-pasta-exibir-pasta-deletar-pasta

Não se esqueça da "busca" do fórum.

Abraço

Boa noite Teixeira

Se isso ocultar o ficheiro "Locked.txt do código da mensagem Nº 1 , sim

Mas como ?

Obrigado

Olá Assis,

Como? O simples seria colocar SetAttr e apertar a tecla F1 que está tudo lá

Código:

SetAttr "C:\SuaPasta\Locked.txt", vbHidden

Veja se fica mais atento, e volto a lembrar o que lhe tenho dito "Indentação no código Assis".

Abraço

Nota: Não se esqueça de fechar o outro tópico

Aonde coloco isso?

Assis,

Imprime numa folha e coloca num quadro, brincadeira

Tente depois da instrução que encerra a criação do ficheiro, sabe que parte é essa do código que partilhou?

Abraço

Aqui

Open strPath & "\Locked.txt" For Output As #1
Print #1, strMsg
Close #1

Bom dia Assis,

Sim o codigo da mensagem nr 4 (com o caminho e nome ficheiro correto) a segir à ultima linha que partilhou na mensagem anterior.

Abraço

Teixeira

Já envia para o destino o ficheiro "Locked.txt" ---------> oculto

A duvida para já está no quadrado azul.

Olá Assis,

A dúvida deste tópico ficou resolvida conforme você indicou a vermelho.
Ou seja já está a criar o ficheiro oculto, até para ser mais correto, cria o ficheiro e depois é modificado o atributo para oculto através da instrução SetAttr.

Você diz "A duvida para já está no quadrado azul." para mim não tem dúvida é a parte que elimina o ficheiro e faz parte do código original.
Na minha opinião tópico encerrado.

Nota: Vou ajustar o título do tópico para ser mais fácil nas pesquisas do fórum do que aqui foi apresentado.

Abraço

Teixeira

Veja a imagem



Código do botão "Procure"

Código:

On Error GoTo Err_Handler

   Dim LastSlash As Integer, strPwd As String
       
   strFullName = CurrentProject.FullName
   
   strPwd = ""
   
   'CR 10/08/2017 - Code rewritten to ensure compatibility with 64-bit Office

   ' Set options for the dialog box.
       Dim F As FileDialog
       Set F = Application.FileDialog(msoFileDialogFilePicker)
       F.Title = "Locate the file to be attached and click on 'Open'"
       F.AllowMultiSelect = False
       
   ' Clear out the current filters, and add our own
       F.Filters.Clear
       F.Filters.Add "Access databases", "*.accdb;*.accde;*.accdr;*.mdb"

   ' Set the start folder
   'Use existing database folder or current folder
       If Nz(Me.txtPath, "") <> "" Then
           F.InitialFileName = Me.txtPath
       Else
           F.InitialFileName = Nz(CurrentProject.Path, "c:\")
       End If
       
   ' Call the Open dialog routine.
       F.Show
   
   ' Return the path and file name.
       strFileName = F.SelectedItems(1)
       
    'clear existing textbox values
       Me.txtPath = ""
       Me.txtFile = ""
   
   'check if current DB selected
   If strFileName = strFullName Then
       MsgBox "Você selecionou o Banco de Dados Atual", vbExclamation, "Current DB"
       
        'detect file type (accdb/mdb)
       strFileType = Mid(strFullName, InStrRev(strFullName, ".") + 1)
   Else
       LastSlash = InStrRev(strFileName, "\")
   
       Me.txtPath = Left(strFileName, LastSlash - 1)
       Me.txtFile = Mid(strFileName, LastSlash + 1)
       
        'detect file type (accdb/mdb)
       strFileType = Mid(Me.txtFile, InStrRev(Me.txtFile, ".") + 1)
   End If
   
   'populate list
   UpdateList
   
   'check for existing lock file in destination db folder
   If Dir(Me.txtPath & "\Locked.txt") <> "" Then
   
       Me.cmdLock.Caption = "&Desbloqueie Base de Dados"
       Me.lblLocked.Visible = True
   Else
       Me.cmdLock.Caption = "&Bloqueie Base de Dados"
       Me.lblLocked.Visible = False
   End If
   

Exit_Handler:
   Exit Sub

Err_Handler:
   strProc = "cmdBrowse_Click"
   
   'If Err = 438 Then Resume Next
   If Err = 5 Then Exit Sub 'user cancelled
   MsgBox "Error " & Err.Number & " in " & strProc & " procedure : " & vbNewLine & _
       Err.Description, vbExclamation, "Program error"
   Resume Exit_Handler

Teixeira

Alterei esta linha
If Dir(Me.txtPath & "\Locked.txt") <> "" Then

Por esta

If Dir(Me.txtPath & "\Locked.txt", vbHidden) <> "" Then

Obrigado

Boa tarde

Assis não insista, começo a perder a paciência e pode ter como consequência deixar de o ajudar.



Quanto à sua nova dúvida nem se deu ao trabalho de procurar.

Repito, Na minha opinião tópico encerrado.

Abraço

Olá Assis,

Fico feliz por ter conseguido, mas mantenho a minha mensagem anterior.
Não misturar dúvidas nos tópicos, mesmo que relacionadas.

Abraço