Duplicar registro atual com subformulário

Boa noite amigo mais uma vez venho pedir ajuda tenho o formulário principal(pedido) com um subformulario (detalhe do pedido). gostaria de duplicar esse pedido com todos os dados do subformlário para um novo pedido, e como fazer isso?

Bom dia!

Segue um código que utilizo. Faça a adaptação ao seu projeto.

Código:

Private Sub btn_vender_Click()
   

Dim dbOrc As Database, rs1, rs2, rs3 As DAO.Recordset

    If MsgBox("Deseja Repetir?", vbYesNo + vbQuestion, "Repatição") = vbYes Then
   
        Set dbOrc = CurrentDb
       
        Set rs1 = dbOrc.OpenRecordset("Tbl_Orcamento", dbOpenTable)
           
        With rs1
       
        .AddNew
        ![idOrcamento] = DMax("idorcamento", "Tbl_Orcamento") + 1 'Me.idOrcamento + 1
        ![cliente] = Me.cliente
        ![endereco] = Me.endereco
        ![telefone] = Me.telefone
        .Update
       
        End With
       
       
        Set rs2 = dbOrc.OpenRecordset("SELECT * FROM Tbl_DetalheOrcamento WHERE Id_Ligacao=" & Me.idOrcamento)
        Set rs3 = dbOrc.OpenRecordset("Tbl_detalheOrcamento", dbOpenTable)
       
     
        While (Not rs2.EOF)
            With rs3
                .AddNew
                ![Id_ligacao] = DMax("idorcamento", "Tbl_Orcamento")
                ![codProduto] = rs2![codProduto]
                ![produto] = rs2![produto]
                ![descricao] = rs2![descricao]
                ![marca] = rs2![marca]
                .Update
                rs2.MoveNext
            End With
        Wend
       
        rs1.Close
        Set rs1 = Nothing
       
        rs2.Close
        Set rs2 = Nothing
       
        rs3.Close
        Set rs3 = Nothing
       
        Set dbOrc = Nothing
       
        DoCmd.OpenForm "frm_orcamento", acNormal, , "idOrcamento = " & Me.idOrcamento & ""
       
        MsgBox "Documento Repetido Criado com Sucesso. ", vbInformation, "Terminado"
     
        DoCmd.Close acForm, "frm_orcamento"
        DoCmd.OpenForm "frm_orcamento"
      Else
     
      DoCmd.CancelEvent
     
    End If

End Sub


Cumprimentos,

Bruno Nunes