[Resolvido]Imprimir e PDF no mesmo botão de comando

Bom dia Amigos

No comando abaixo confirmo a abertura da ficha de um produto e pergunto se quer criar PDF desse produto.

A ficha aberta está certo, abre só uma.

Mas o PDF é criado para todos os Produtos, como criar só para o Produto desejado.

Obrigado


If MsgBox("Confirma a Impressão da Ficha Técnica da Ref. da " & [ref] & "" & Chr(13) & " Tipo " & [Tipo] & "", vbYesNo, "Aviso") = vbYes Then

If MsgBox("Criar Documento em P. D. F. ? ", vbYesNo, "P. D. F.") = vbYes Then
Dim Caminho As String
Caminho = BackEndPath & "\PDF\"
Dim strArquivo As String
Dim strLocal As String
strArquivo = "Ficha de Custo da Ref - " & [ref] & " - " & [Tipo] & " " & [Prod_Descricao] & ""
strLocal = Caminho & strArquivo & ".PDF"
'Gera arquivo pdf do relat?rio previamente aberto.

DoCmd.OutputTo acOutputReport, "Produtos", acFormatPDF, strLocal

If err = 2501 Then
err.Clear
DoCmd.Close
End If
DoCmd.OpenReport "Produtos", acViewPreview, "", "[Produtos]![sysid]=[Forms]![FrmProduto]![sysid]"
Else
End If
End If

Boa tarde Assis....

Não está faltando a chave primária ai no código não ?

strArquivo = "Ficha de Custo da Ref - " & [ref] & " - " & [Tipo] & " " & [Prod_Descricao] & ""

Veja abaixo um código que eu uso para o mesmo fim ...

Código:


Private Sub bt_GPdf_Click()
Dim strArquivo As String
Dim strLocal As String

' nome do arquivo a ser salvo    
strArquivo = "Pedido  " & Me!NossoPedido & " - " & Me!Cliente & "-" & Me.Forneoculta & ".pdf"
strLocal = CurrentProject.Path & "\Pedidos\" & strArquivo ' criar essa pasta ( pedidos ) onde está o banco de dados

 'Abre o relatório devidamente filtrado e oculto
DoCmd.OpenReport "RptPedido", acViewPreview, , "codped=" & Me!CodPed, acHidden ' codped é a chave primária, onde realizo a filtragem
 '                           nome do relatorio                  chave prima       chave prima

'Gera arquivo pdf do relatório previamente aberto e filtrado.
DoCmd.OutputTo acOutputReport, "RptPedido", acFormatPDF, strLocal

 'Fecha o relatório
DoCmd.Close acReport, "RptPedido"

End Sub

Obrigado Silvio

Abraço

 A chave é tudo  

Isso mesmo...

Qualquer coisa, estamos aqui.

Abraços.

Obrigado

Olha o resolvido … ehehehe