[Resolvido]Distribuição de Processos/tarefas Equipe por Programa

Pessoal, Boa tarde.
Estou patinando em uma situação e gostaria do apoio de vocês nessa situação.

Pesquisei em vários e vários lugares alguma função que me serva como distribuidor de processos na minha equipe. Para melhor entendimento, seria algo para que pegasse uma lista de demanda e atribui-se a um operador que em loop, deixando uma mesma quantidade de processos pra cada um de maneira justa.

Consegui com a ajuda da internet gerar um código que atenda em parte o que é preciso, mas não estou conseguindo incluir mais condições na função.
Exemplo prático.

Existe uma Tabela chamada "TAB_PROCESSOS_MKT", que é a tabela onde está os processos. Nessa tabela tem um campo chamado "Responsável" que deverá ser o nome do agente que irá trata-lo. Até aqui tudo OK.

Existe a segunda Tabela que é a "TAB_AGENTES_PROD", aqui está a relação dos agentes.

O que é necessário:
- Na TAB_PROCESSOS_MKT incluir na coluna RESPONSÁVEL o AGENTE, com as condições por PROGRAMA e NUMERO OCORRÊNCIA (Processo).

Essa segunda parte que tá pegando pra mim.


A função teria que contar quantos processos o programa tem em branco e distribuir pela lista de agentes que cada programa possui, da maneira mais igual possível, evitando que um agente fiquei com muito mais processos que o outro;

* O processo pode se repetir e deverá ser atribuído a mesma pessoa, por exemplo:
- Porto Seguro, processo: 1 - Responsavel: Jonathan
- Porto Seguro, processo: 1 - Responsavel: Jonathan
- Porto Seguro, processo: 2 - Responsavel: Fellipe


Esse código, já distribui, porém é aleatório não consegui abribuir que deve ser por PROGRAMA x AGENTE na tabela TAB_AGENTES_PROD.

Código:

Sub DistribuidorProcessos()

    Dim rstTAB_PROCESSOS_MKT As Recordset
    Dim rstTAB_AGENTES_PROD As Recordset
    Dim strSql As String
    
    'Montado o código para buscar os processos cujo
    'campo responsável esteja vazio
    strSql = "Select * From TAB_PROCESSOS_MKT Where RESPONSÁVEL Is Null"
    
    'Buscando as processos
    Set rstTAB_PROCESSOS_MKT = CurrentDb.OpenRecordset(strSql)
    
    'Montando o código para buscar os
    'agentes na tabela TAB_AGENETES_PROD
    strSql = "Select AGENTE From TAB_AGENTES_PROD"
    
    'Buscando os agentes
    Set rstTAB_AGENTES_PROD = CurrentDb.OpenRecordset(strSql)
    
    'Iniciando o Loop nos processos
    While Not rstTAB_PROCESSOS_MKT.EOF
        
        'Editando o campo responsável
        'para inserir o operador atual
        rstTAB_PROCESSOS_MKT.Edit
        rstTAB_PROCESSOS_MKT("RESPONSÁVEL") = rstTAB_AGENTES_PROD("AGENTE")
        rstTAB_PROCESSOS_MKT.Update
        
        'Próximo processo
        rstTAB_PROCESSOS_MKT.MoveNext
        
        'Próximo agente ou volta ao início
        rstTAB_AGENTES_PROD.MoveNext
        If rstTAB_AGENTES_PROD.EOF Then rstTAB_AGENTES_PROD.MoveFirst
        
    Wend

End Sub

Desculpe pelo enorme teste e agradeço desde já a atenção.

Boa noite,
Veja se atende ao que precisa

Código:

Sub DistribuidorProcessos()
    Dim rstTAB_PROCESSOS_MKT As Recordset
    Dim rstTAB_AGENTES_PROD As Recordset
    
    'Buscando as processos
    Set rstTAB_PROCESSOS_MKT = CurrentDb.OpenRecordset("SELECT Programa, [NÚMERO OCORRÊNCIA] FROM Tab_Processos_MKT WHERE IsNull(RESPONSÁVEL) GROUP BY Programa, [NÚMERO OCORRÊNCIA];")
    'Buscando os agentes
    Set rstTAB_AGENTES_PROD = CurrentDb.OpenRecordset("Select AGENTE From TAB_AGENTES_PROD")
    
    'Iniciando o Loop nos processos
    While Not rstTAB_PROCESSOS_MKT.EOF
        'Editando o campo responsável
        'para inserir o operador atual
        CurrentDb.Execute "UPDATE Tab_Processos_MKT SET RESPONSÁVEL ='" & rstTAB_AGENTES_PROD("AGENTE") & "' WHERE Programa='" & rstTAB_PROCESSOS_MKT("Programa") & "' and [NÚMERO OCORRÊNCIA]=" & rstTAB_PROCESSOS_MKT("[NÚMERO OCORRÊNCIA]")
        'Próximo processo
        rstTAB_PROCESSOS_MKT.MoveNext
        'Próximo agente ou volta ao início
        rstTAB_AGENTES_PROD.MoveNext
        If rstTAB_AGENTES_PROD.EOF Then rstTAB_AGENTES_PROD.MoveFirst
    Wend

End Sub


Alexandre, bom dia.
Obrigado pela disposição. É a primeira resposta que recebo a dias HAHAHA.

Testei o código e funcionou perfeitamente para o número da ocorrência, no entanto não respeitou PROGRAMA x AGENTE.
Por exemplo:

No arquivo de teste na coluna de programa, deveríamos distribuir as ocorrências entre agentes apenas daquele programa
- PROGRAMA DE RELACIONAMENTO PORTO SEGURO - Agente Porto Seguro
- PROGRAMA DE RELACIONAMENTO PORTO SEGURO - Agente Porto Seguro
- PROGRAMA DE RELACIONAMENTO PORTO SEGURO - Agente Porto Seguro
- PROGRAMA DE RELACIONAMENTO PORTO SEGURO - Agente Porto Seguro

O Teste jogou um agente que pertence a outro programa, entende?

Mais uma vez fico agradecido pela atenção.

Boa tarde
Não entendi bem
Tinha entendido que em cada par programa+ocorrência tinha que ser o mesmo agente
Explique com todos os detalhes e indique qual resultado em cada situação devia acontecer para entender a lógica

Alexandre,

vamos supor que a lista tenha 2 Programas, cada programa tenha agentes especificos que atendam ele, por exemplo:

Programa 1 = 50 Ocorrências

Agentes do Programa 1
Maria = 10 Ocorrências
João = 10 Ocorrências
José = 10 Ocorrências
Pedro = 10 Ocorrências
Davi = 10 Ocorrências

Programa 2 = 50 Ocorrências

Agentes do Programa 2
Lucas = 25 Ocorrências
Daniel = 25 Ocorrências

O seu código já faz certo a questão da ocorrência que se repete. Só falta aplicar a logica acima que está pegando pra mim. Conseguir identificar, distribuir as ocorrências por agentes que atendem cada programa.

Será isto?

Código:

Sub DistribuidorProcessos()
    Dim RstProgramas As DAO.Recordset, RstAgentes As DAO.Recordset
   
    Set RstProgramas = CurrentDb.OpenRecordset("SELECT DISTINCT Programa, [NÚMERO OCORRÊNCIA] FROM Tab_Processos_MKT WHERE IsNull(Responsável);")
    Do Until RstProgramas.EOF
        Set RstAgentes = CurrentDb.OpenRecordset("SELECT AGENTE From TAB_AGENTES_PROD WHERE Programa='" & RstProgramas(0) & "'")
        Do Until RstAgentes.EOF
            CurrentDb.Execute "UPDATE Tab_Processos_MKT SET RESPONSÁVEL ='" & RstAgentes("AGENTE") & "' WHERE Programa='" & RstProgramas("Programa") & "' and [NÚMERO OCORRÊNCIA]=" & RstProgramas("[NÚMERO OCORRÊNCIA]")
            RstAgentes.MoveNext
            If RstAgentes.EOF Then RstAgentes.MoveFirst
        Loop
        RstProgramas.MoveNext
    Loop
    Set RstProgramas = Nothing: Set RstAgentes = Nothing
End Sub


Alexandre,
Testei no BD que deixei como teste aqui no fórum, no entanto, o mesmo ficou executando infinitamente e não chegou a nenhuma conclusão :/
Não consegui ver se foi o resultado esperando

Você conseguiu simular ai?

Veja agora

Código:

Sub DistribuidorProcessos()
    Dim RstProgramas As DAO.Recordset, RstAgentes As DAO.Recordset
   
    Set RstProgramas = CurrentDb.OpenRecordset("SELECT DISTINCT Programa, [NÚMERO OCORRÊNCIA] FROM Tab_Processos_MKT WHERE IsNull(Responsável);")
    Do Until RstProgramas.EOF
        Set RstAgentes = CurrentDb.OpenRecordset("SELECT AGENTE From TAB_AGENTES_PROD WHERE Programa='" & RstProgramas(0) & "'")
        CurrentDb.Execute "UPDATE Tab_Processos_MKT SET RESPONSÁVEL ='" & RstAgentes("AGENTE") & "' WHERE Programa='" & RstProgramas("Programa") & "' and [NÚMERO OCORRÊNCIA]=" & RstProgramas("[NÚMERO OCORRÊNCIA]")
        RstAgentes.MoveNext
        If RstAgentes.EOF Then RstAgentes.MoveFirst
        RstProgramas.MoveNext
    Loop
    Set RstProgramas = Nothing: Set RstAgentes = Nothing
End Sub

Alexandre, acho que estamos chegando lá.
Testei e a formula pegou o agente que trata ao programa, porém pegou só o primeiro da lista de cada programa. Veja.

Resultado da função

Programa 1 = 50 Ocorrências

Agentes do programa 1
Maria = 50 Ocorrências
João = 0 Ocorrências
José = 0 Ocorrências
Pedro = 0 Ocorrências
Davi = 0 Ocorrências

Identificou o agente de cada Programa, mas não todos.

Veja agora

Código:

Sub DistribuidorProcessos()
    Dim strPrograma As String, RstProgramas As DAO.Recordset, RstAgentes As DAO.Recordset
   
    Set RstProgramas = CurrentDb.OpenRecordset("SELECT DISTINCT Programa, [NÚMERO OCORRÊNCIA] FROM Tab_Processos_MKT WHERE IsNull(Responsável);")
    Set RstAgentes = CurrentDb.OpenRecordset("SELECT AGENTE From TAB_AGENTES_PROD WHERE Programa='" & RstProgramas(0) & "'")
    strPrograma = RstProgramas("Programa")
    Do Until RstProgramas.EOF
        If strPrograma <> "'" & RstProgramas("Programa") & "'" Then
            Set RstAgentes = CurrentDb.OpenRecordset("SELECT AGENTE From TAB_AGENTES_PROD WHERE Programa='" & RstProgramas(0) & "'")
            strPrograma = RstProgramas("Programa")
        End If
        CurrentDb.Execute "UPDATE Tab_Processos_MKT SET RESPONSÁVEL ='" & RstAgentes("AGENTE") & "' WHERE Programa='" & RstProgramas("Programa") & "' and [NÚMERO OCORRÊNCIA]=" & RstProgramas("[NÚMERO OCORRÊNCIA]")
        RstAgentes.MoveNext
        If RstAgentes.EOF Then RstAgentes.MoveFirst
        RstProgramas.MoveNext
    Loop
    Set RstProgramas = Nothing: Set RstAgentes = Nothing
End Sub

Alexandre,
Continuou preenchendo com o primeiro agente :/

Não sei se ajuda, mas fiz um modelo na mão de como deveria ficar +/-
A sua função está no modulo, perceba que não fica dessa maneira ainda.

Veja agora

Código:

Sub DistribuidorProcessos()
    Dim strPrograma As String, RstProgramas As DAO.Recordset, RstAgentes As DAO.Recordset
   
    CurrentDb.Execute "UPDATE Tab_Processos_MKT SET RESPONSÁVEL =Null"
    Set RstProgramas = CurrentDb.OpenRecordset("SELECT DISTINCT Programa, [NÚMERO OCORRÊNCIA] FROM Tab_Processos_MKT WHERE IsNull(Responsável) and Not IsNull(Programa);")
    Set RstAgentes = CurrentDb.OpenRecordset("SELECT AGENTE From TAB_AGENTES_PROD WHERE Programa='" & RstProgramas(0) & "'")
    strPrograma = RstProgramas("Programa")
    Do Until RstProgramas.EOF
        If strPrograma <> RstProgramas("Programa") Then
            Set RstAgentes = CurrentDb.OpenRecordset("SELECT AGENTE From TAB_AGENTES_PROD WHERE Programa='" & RstProgramas(0) & "'")
            strPrograma = RstProgramas("Programa")
        End If
        CurrentDb.Execute "UPDATE Tab_Processos_MKT SET RESPONSÁVEL ='" & RstAgentes("AGENTE") & "' WHERE Programa='" & RstProgramas("Programa") & "' and [NÚMERO OCORRÊNCIA]=" & RstProgramas("[NÚMERO OCORRÊNCIA]")
        RstAgentes.MoveNext
        If RstAgentes.EOF Then RstAgentes.MoveFirst
        RstProgramas.MoveNext
    Loop
    Set RstProgramas = Nothing: Set RstAgentes = Nothing
End Sub


Alexandre, bom dia!
Agora sim!!!!

Funcionou perfeitamente, dessa maneira posso organizar de maneira mais justa possível as ocorrências na Equipe.

Muito obrigado pelo apoio e paciência.

Foi sensacional.

Faltou o "Resolvido"

Feito!

Obrigado novamente.