[Resolvido]Erro ao gravar dados em tabela com subformulário

Boa noite!
Galera to criando um sistema de faltas e preciso gravar os dados que estão na tabela cad_alunos para tabela cad_faltas, para isso criei um formulário onde ao selecionar a turma aparecem os alunos que estão cadastrados nela e um botão para fazer esta gravação, fiz o teste e ele grava normalmente os campos do formulário, mais os campos do sub-formulário apresentam o seguinte erro:

Erro de compilação
Método ou membro de dados não encontrado

Segue o código que coloquei no botão para gravar ao clicar:

Código:


CurrentDb.Execute "INSERT INTO Cad_faltas (código,presença,matéria,turma,aula,data) Values('" & Me.código & "','" & Me.presença & "','" & Me.matéria & "','" & Me.Turma & "','" & Me.aula & "','" & Me.Data & "')"


Se alguém puder me ajudar agradeço, deixei em anexo o bd para verificação.

desde já agradeço

Tente no seu botão o código

Código:

Dim rs As Recordset
   
    'tirando uma cópia dos registros do subformulário para a memória do vba
    Set rs = Me!Sub_Faltas.Form.RecordsetClone
   
    'se a cópia possuir registros então
    If rs.RecordCount > 0 Then
       
        'garanto que começarei do começo
        rs.MoveFirst
       
        'ponto inicial do loop
        Do
           
            'se a coluna presença não estiver marcada então
            If Not rs.Fields("presença").Value Then
       
                'insiro as informações do registro atual e algumas informações do formulário na tabela cad_faltas
                CurrentDb.Execute "INSERT INTO Cad_faltas (cod_aluno,matéria,turma,aula,data) " & _
                                                    "Values(" & rs.Fields("Código").Value & ",'" & Me.matéria & "','" & Me.Turma & "'," & Me.aula & ",#" & Format(Me.Data, "mm/dd/yyyy") & "#)"
           
            End If
           
            'movo-me para o próximo registro
            rs.MoveNext
         
        'ponto final do loop que verifica se já cheguei ao final dos registros copiados, do contrário volto ao ponto inicial do loop 
        Loop Until rs.EOF
   
    'fim da estrutura condicional que verificou se a cópia possuia registros
    End If
   
    'descarto a cópia criada da memória do vba
    rs.Close: Set rs = Nothing

Boa tarde,
Obrigado pela informação, vou testar então

Atenciosamente

Olá,
Deu certo sim, mais com uma pequena inversão na lógica, eu precisava que gravasse todos os alunos e com presença e com falta, no campo presença eu apenas diferencio marcando que veio ou não com uma caixa de seleção, e pra isso tirei o IF que você criou ai deu certo.

Obrigado pelo retorno. O fórum agradece. Sucesso.