[Resolvido]Verificando apenas primeiro registro

Bom dia Pessoal,
Preciso de uma ajudinha,
Preciso que ao digitar o RG verifique se já existe o rg cadastrado e iforme por mensagem que já existre cadastrado.

Com esse código abaixo até funciona,mas está reconhecendo apenas o primeiro registro os demais não reconhece.Só envia mensagem se eu tentar cadastrar o rg igual ao primeiro.Como faço pra reconhecer os outros também?

Contem:
1 form com o campo CÓD_VISITANTE,RG_CPF,NOME,EMPRESA,TELEFONE.
1 Tabela com chave primária no campo CÓD_VISITANTE e RG_CPF

Segue o código que estou usando:

Private Sub RG_CPF_BeforeUpdate(Cancel As Integer)
Dim rst As Recordset
Set rst = CurrentDb.OpenRecordset("SELECT * FROM Tab_CADASTROVISITANTE")

With rst
If rst![RG_CPF] = Me.RG_CPF.Value Then
MsgBox "Documento já cadastrado...", vbCritical
Me.Undo
Else
End If
End With
rst.Close
End Sub


Desde já agradeço.

Verifique no link da minha assinatura os 102 Códigos VBA Gratuitos

Código = "Deteta e Mostra Registros Duplicados"

Ou assim;

Código:

Private Sub RG_CPF_BeforeUpdate(Cancel As Integer)
On Error GoTo TrataErro
Dim DB As DAO.Database
Dim RS As DAO.Recordset

' Testa se o código já existe na tabela
    If IsNull(DLookup("RG_CPF", "Tab_CADASTROVISITANTE", "([RG_CPF] = '" & Me.RG_CPF.Value & "')")) Then
        GoTo Saida
    End If
' Dá opção de alterar dados
    If MsgBox("O CPF " & Me.RG_CPF.Value & " já existe. Deseja alterá-lo?", vbExclamation + vbYesNo, "Já existe...") = vbNo Then
        Me.Undo
        GoTo Saida
    End If
   
'Abre o registro já existente
    Set RS = Me.RecordsetClone
    RS.FindFirst "RG_CPF = '" & Me.RG_CPF.Value & "'"
    Me.Undo
    Me.Bookmark = RS.Bookmark
    Set RS = Nothing
Saida:
   
    Exit Sub
TrataErro:
    MsgBox Err.Description, vbExclamation + vbOKOnly, "Erro: " & CStr(Err.Number)
#If DESENV Then
    Stop
    Resume
#End If
    Resume Saida
End Sub

Obrigado JPaulo,
Vou testar e já retorno.

JPaulo deu certinho,
Muito obrigado mesmo,
Deus abençoe seu conhecimento.

A propósito,
Esse fórum e todos os participantes estão de parabéns pela dedicação em ajudar.
Abraço a todos.

Obrigado pelo retorno o forum agradece.