[Resolvido]inserir dados apos confirmação

boa tarde meu queridos !!!

Me tirem um duvida...

Peguei BD aqui do fórum aos créditos de Criquio Calavera

Seria um sistema de vendas, estou adaptando ao meu BD.


Eu precisaria que na hora de finalizar, inserisse pelo txt (codigo do cliente) o numero.

se alguem poderia me explicar sobre Column(0, NLinha) didaticamente seria um prazer.

BASICAMENTE, tudo que queria esta na tblVendasDetalhes

codigo abaixo:

Private Sub btnFinaliza_Click()
If Me.btnObs.Caption = "Confirmar" Then
MsgBox "O campo Observações está em modo de edição. Clique no botão ""Confirmar"" antes de realizar essa operação.", vbOKOnly + vbCritical, "ATENÇÃO"
Else
Me.txtCalcula.SetFocus
If Me.lstCompras.RowSource = "" Then
MsgBox "Lista de compras vazia.", vbOKOnly + vbCritical, "ATENÇÃO"
Me.txtCalcula.SetFocus
Me.txtDinheiro.Enabled = False
Me.txtDinheiro.Locked = True
ElseIf IsNull(Me.txtDinheiro) Or Me.txtDinheiro.Value = "" Then
MsgBox "Insira o valor do pagamento em dinheiro", vbOKOnly + vbCritical, "ATENÇÃO"
Me.txtDinheiro.Enabled = True
Me.txtDinheiro.Locked = False
Me.txtDinheiro.SetFocus
ElseIf Me.txtDinheiro < Me.txtTotalCompra Then
MsgBox "Valor em dinheiro menor que o valor da compra", vbOKOnly + vbCritical, "ATENÇÃO"
Me.txtDinheiro.Enabled = True
Me.txtDinheiro.Locked = False
Me.txtDinheiro.SetFocus
Else

Dim db1 As Database, db2 As Database, rs1 As Recordset, rs2 As Recordset, NLinha As Long
If MsgBox("Confirma a venda?", vbYesNo + vbQuestion, "CONFIRMAR") = vbYes Then

Set db1 = CurrentDb
Set db2 = CurrentDb

Set rs1 = db1.OpenRecordset("tblVendas", dbOpenTable)
Set rs2 = db2.OpenRecordset("tblVendasDetalhes", dbOpenTable)

rs1.AddNew

rs1("DataVenda") = Date
rs1("HoraVenda") = Time
rs1("Observações") = Me.txtObs
rs1.Update
rs1.Close
Set rs1 = Nothing
Set db1 = Nothing

For NLinha = 0 To Me.lstCompras.ListCount - 1
rs2.AddNew
rs2("CódigoVenda") = DMax("Código", "tblVendas")
rs2("CódigoProduto") = Me.lstCompras.Column(0, NLinha)
rs2("Quantidade") = Me.lstCompras.Column(2, NLinha)
rs2("vlUnitário") = Me.lstCompras.Column(3, NLinha)
rs2.Update
Next NLinha

rs2.Close
Set rs2 = Nothing
Set db2 = Nothing

MsgBox "Venda confirmada.", vbOKOnly + vbInformation, "Concluído"
Call VerificaCampos
Else
If MsgBox("Deseja alterar ou cancelar essa venda?" & vbCrLf & "Escolha ""OK"" para alterar ou ""Cancelar"" para cancelar.", vbOKCancel + vbQuestion, "ESCOLHA") = vbCancel Then
Call VerificaCampos
Else
Exit Sub
End If
End If
End If
End If
End Sub

Amigo, acredito que seja isso:

For NLinha = 0 To Me.lstCompras.ListCount - 1
Aqui ele Calcula o Loop, que inicia em zero e vai até (Quantidade de Linhas que tem na cxLIstagem "Me.lstCompras" (To Me.lstCompras.ListCount).


Digamos que nessa CxListagem tenha 10 Itens...
O Loop Inicia em Zero (For NLinha = 0) e Vai até 9 (To Me.lstCompras.ListCount - 1) pois subtrai 1. "-1".


rs2("CódigoProduto") = Me.lstCompras.Column(0, NLinha)


No Campo CódigoProduto do RecordSet rs2 será aplicado o Valor que está na Caixa de Listagem, o valor da Coluna ZERO da Linha (valor que tiver na variavel NLinha, que depende do loop, que vimos na explicação anterior).

rs2("Quantidade") = Me.lstCompras.Column(2, NLinha)
Observe que aqui agora ele pega o Valor da Coluna 2, e da Linha corrente...

Isso serve para buscar os Valores corretamente de acordo com a linha corrente...

Pois a cada passagem do Loop a variavel NLinha muda para proxima linha.

Fabio, obg a explicação.

estou tentando aqui, porem ele nao localiza a variavel que estou declarando do box nao aclopado.

rs2("CodigoCliente") = Me.codcliente.Column(0)

CodigoCliente = nome da coluna da tabela

codcliente = txt declarado


estou fazendo algo errado?


como eu declaro o txt nesse metado de tag ? com rs addnew ETC
se puder me passa o caminho das pedras pra pesquisas a respeito dessa linhagem...

abraços

É variavel ou Nome de Campo?
Pois Me.xxxx é nome de Campo...

Outra coisa, so especificamos coluna (Column(xxx)) para Caixa de Listagem ou Caixa de Combinação... E elas devem ter a qnd de colunas correta.

Ex: Minha caixa de combinação possue 5 Colunas declarada na configuração... Mas e faço referencia a column(6) Nao ira rolar...

Tentei no exemplo que vc me disse porem nao deu certo.

rs2("CodCliente") = Me.CodigoCliente

metados ou membro não encontrado

Verifique se o Nome desse Campo realmente esta escrito correto...

Verifique também na tabela o nome co campo/Coluna.


Se mesmo assim nao conseguir, poste aqui exemplo somente com as partes envolvidas, e me diga como proceder...

Fabio, bom dia !

Não consegui.

Segue o codigo completo do formulario.


abraços


Option Compare Database
Option Explicit
Private Function TCompra()
Dim TTotal As Integer, TSoma As Currency
TSoma = 0
For TTotal = 0 To Me.lstCompras.ListCount - 1
TSoma = TSoma + Me.lstCompras.Column(4, TTotal)
Next TTotal

If Me.lstCompras.RowSource = "" Then
Me.txtTotalCompra = Null
Me.txtDinheiro = Null
Me.txtTroco = Null
Else
Me.txtTotalCompra = TSoma
End If
End Function

Private Sub VerificaCampos()
Me.txtCalcula = Null
Me.lstCompras.RowSource = ""
Me.txtTotalCompra = Null
Me.txtDinheiro = Null
Me.txtCalcula.SetFocus
Me.txtTroco = Null
Me.txtDinheiro.Enabled = False
Me.txtDinheiro.Locked = True
End Sub

Private Sub btnAjuda_Click()
DoCmd.OpenForm "frmAjuda"
End Sub

Private Sub btnCancela_Click()
If Me.btnObs.Caption = "Confirmar" Then
MsgBox "O campo Observações está em modo de edição. Clique no botão ""Confirmar"" antes de realizar essa operação.", vbOKOnly + vbCritical, "ATENÇÃO"
Me.txtObs.SetFocus
Else
If Me.lstCompras.RowSource = "" Then
MsgBox "Não há nenhuma compra a ser cancelada.", vbOKOnly + vbCritical, "Carro vazio"
Me.txtCalcula.SetFocus
Else
If MsgBox("Tem certeza que deseja cancelar a venda?", vbYesNo + vbQuestion, "Cancelar") = vbYes Then
Call VerificaCampos
Else
Exit Sub
End If
End If
End If
End Sub

Private Sub btnFinaliza_Click()
If Me.btnObs.Caption = "Confirmar" Then
MsgBox "O campo Observações está em modo de edição. Clique no botão ""Confirmar"" antes de realizar essa operação.", vbOKOnly + vbCritical, "ATENÇÃO"
Else
Me.txtCalcula.SetFocus
If Me.lstCompras.RowSource = "" Then
MsgBox "Lista de compras vazia.", vbOKOnly + vbCritical, "ATENÇÃO"
Me.txtCalcula.SetFocus
Me.txtDinheiro.Enabled = False
Me.txtDinheiro.Locked = True
ElseIf IsNull(Me.txtDinheiro) Or Me.txtDinheiro.Value = "" Then
MsgBox "Insira o valor do pagamento em dinheiro", vbOKOnly + vbCritical, "ATENÇÃO"
Me.txtDinheiro.Enabled = True
Me.txtDinheiro.Locked = False
Me.txtDinheiro.SetFocus
ElseIf Me.txtDinheiro < Me.txtTotalCompra Then
MsgBox "Valor em dinheiro menor que o valor da compra", vbOKOnly + vbCritical, "ATENÇÃO"
Me.txtDinheiro.Enabled = True
Me.txtDinheiro.Locked = False
Me.txtDinheiro.SetFocus
Else

Dim db1 As Database, db2 As Database, rs1 As Recordset, rs2 As Recordset, NLinha As Long
If MsgBox("Confirma a venda?", vbYesNo + vbQuestion, "CONFIRMAR") = vbYes Then

Set db1 = CurrentDb
Set db2 = CurrentDb

Set rs1 = db1.OpenRecordset("tblVendas", dbOpenTable)
Set rs2 = db2.OpenRecordset("tblVendasDetalhes", dbOpenTable)

rs1.AddNew

rs1("DataVenda") = Date
rs1("HoraVenda") = Time
rs1("Observações") = Me.txtObs
rs1.Update
rs1.Close
Set rs1 = Nothing
Set db1 = Nothing

For NLinha = 0 To Me.lstCompras.ListCount - 1
rs2.AddNew
rs2("CódigoVenda") = DMax("Código", "tblVendas")
rs2("CódigoProduto") = Me.lstCompras.Column(0, NLinha)
rs2("Quantidade") = Me.lstCompras.Column(2, NLinha)
rs2("vlUnitário") = Me.lstCompras.Column(3, NLinha)
rs2("CodCliente") = Me.CodigoCliente
rs2.Update
Next NLinha

rs2.Close
Set rs2 = Nothing
Set db2 = Nothing

MsgBox "Venda confirmada.", vbOKOnly + vbInformation, "Concluído"
Call VerificaCampos
Else
If MsgBox("Deseja alterar ou cancelar essa venda?" & vbCrLf & "Escolha ""OK"" para alterar ou ""Cancelar"" para cancelar.", vbOKCancel + vbQuestion, "ESCOLHA") = vbCancel Then
Call VerificaCampos
Else
Exit Sub
End If
End If
End If
End If
End Sub

Private Sub btnLista_Click()
If Me.btnObs.Caption = "Confirmar" Then
MsgBox "O campo Observações está em modo de edição. Clique no botão ""Confirmar"" antes de realizar essa operação.", vbOKOnly + vbCritical, "ATENÇÃO"
Else
If Me.lstCompras.RowSource = "" Then
MsgBox "Não há nenhum ítem na lista de ítens comprados.", vbOKOnly + vbCritical, "Carro vazio"
Me.txtCalcula.SetFocus
Else
Me.txtDinheiro.Enabled = True
Me.txtDinheiro.Locked = False
Me.txtDinheiro.SetFocus
End If
End If
End Sub

Private Sub btnObs_Click()
If Me.txtObs.Visible = False Then
Me.btnObs.Caption = "Confirmar"
Me.btnObs.ForeColor = vbRed
Me.lstCompras.Height = 3650
Me.txtObs.Visible = True
Me.txtObs.SetFocus
Me.txtCalcula.Enabled = False
ElseIf Me.txtObs.Visible = True Then
Me.btnObs.Caption = "Observações"
Me.btnObs.ForeColor = vbBlack
Me.lstCompras.Height = 6146.28
Me.txtCalcula.Enabled = True
Me.txtCalcula.SetFocus
Me.txtObs.Visible = False
End If

End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)

Select Case KeyCode

Case vbKeyF3
Call btnLista_Click
Case vbKeyF4
Call btnCancela_Click
Case vbKeyF6
Call btnFinaliza_Click
End Select
End Sub

Private Sub Form_Timer()
Me.txtData.Requery
Me.txtHora.Requery
End Sub

Private Sub lstCompras_KeyDown(KeyCode As Integer, Shift As Integer)

On Error GoTo NErr

If KeyCode = vbKeyDelete Then
If Me.lstCompras.RowSource = "" Then
Me.txtCalcula.SetFocus
Exit Sub
Else

Dim Cond As String

Cond = MsgBox("Tem certeza que deseja alterar a lista de compras? Você tem as seguintes opções:" & vbCrLf & vbCrLf & "Sim: opção de alterar a quantidade do ítem." & vbCrLf & "Não: exclui o ítem da lista." & vbCrLf & "Cancel: cancela alteração", vbYesNoCancel + vbExclamation, "CONFIRMA ALTERAÇÃO?")

Select Case Cond
Case vbYes
Me.txtCalcula = Me.lstCompras.Column(2) & "*" & Me.lstCompras.Column(0)
Me.lstCompras.RemoveItem Index:=Me.lstCompras.Value
Me.txtDinheiro = Null
Me.txtTroco = Null
Me.txtCalcula.SetFocus
Case vbNo
Me.lstCompras.RemoveItem Index:=Me.lstCompras.Value
Me.txtCalcula = Null
Me.txtDinheiro = Null
Me.txtTroco = Null
Me.txtCalcula.SetFocus
Case Else
Exit Sub
End Select
End If
Call TCompra

NErr:

If Err.Number = 6013 Then
Exit Sub
End If

End If

End Sub

Private Sub txtCalcula_AfterUpdate()

On Error GoTo TErro

Dim Quant As Double, Cod As Double, Pos As Double, Sobra As Double

If IsNull(Me.txtCalcula) Or Me.txtCalcula.Value = "" Or Len(Me.txtCalcula) < 2 Then
MsgBox "Não foi digitado um código de produto válido.", , "ATENÇÃO"
Me.txtCalcula.SetFocus
Me.txtCalcula = Null
Me.txtDinheiro = Null
Me.txtTroco = Null
Else

Pos = 1

Do
If Mid(Me.txtCalcula, Pos, 1) <> "*" Then
Pos = Pos + 1
End If
Loop Until Mid(Me.txtCalcula, Pos, 1) = "*" Or Pos = Len(Me.txtCalcula)

Sobra = Len(Me.txtCalcula) - Pos

If Pos = Len(Me.txtCalcula) Then
Quant = 1
Cod = Me.txtCalcula
Else
Quant = Mid(Me.txtCalcula, 1, Pos - 1)
Cod = Mid(Me.txtCalcula, Pos + 1, Sobra)
End If

If IsNull(DLookup("ValorUnitário", "tblProdutos", "Código=" & Cod)) Then
MsgBox "O código """ & Cod & """é inexistente." & vbCrLf & "Por favor, verifique e tente novamente.", vbOKOnly + vbCritical, "ATENÇÃO"
Me.txtCalcula.SetFocus
Me.txtCalcula = Null
Else
Me.txtDinheiro = Null
Me.lstCompras.RowSourceType = "value list"
Me.lstCompras.AddItem Item:=Cod & ";" & DLookup("Descrição", "tblProdutos", "Código=" & Cod) & ";" & Quant & ";" & Format(DLookup("ValorUnitário", "tblProdutos", "Código=" & Cod), "currency") & ";" & Format(Quant * DLookup("ValorUnitário", "tblProdutos", "Código=" & Cod), "currency")
Me.txtCalcula = Null
Call TCompra
End If

End If

TErro:

If Err.Number = 2471 Then
MsgBox "Nesse campo não deve ser digitado texto, apenas ""quantidade*código"" ou apenas o ""código"".", vbOKOnly + vbCritical, "ERRO"
ElseIf Err.Number = 3075 Then
MsgBox "Nesse campo deve ser digitado apenas ""quantidade*código"" ou apenas o ""código"".", vbOKOnly + vbCritical, "ERRO"
Else
Resume Next
End If

End Sub

Private Sub txtDinheiro_AfterUpdate()
If Me.txtDinheiro < Me.txtTotalCompra Then
Me.txtDinheiro = Null
Me.txtCalcula.SetFocus
MsgBox "Dinheiro menor do que total da compra.", vbOKOnly + vbCritical, "ATENÇÃO"
Me.txtDinheiro.SetFocus
Else
Me.txtTroco = Me.txtDinheiro - Me.txtTotalCompra
Me.txtCalcula.SetFocus
Me.txtDinheiro.Enabled = False
Me.txtDinheiro.Locked = True
End If
End Sub

Private Sub txtObs_LostFocus()
Me.txtCalcula.SetFocus
Me.txtObs.Enabled = False
End Sub

Amigão, me desculpe mas sem o exemplo e impossivel eu saber onde esta o Erro...

Demoraria uma eternidade eu recriar seu Formulario e Tabelas para testar.

Poste um aplicativo de exemplo!

Fabiao !

Desculpa ae !

Segue o bd

https://www.dropbox.com/s/0nrke6273drw380/churrasshow.mdb?dl=0


obg

Amigo, vc se confundiu nos nomes: Nome do Campo na Tabela e Nome do Campo no Formulario.


Mude a linha com erro para:

rs2("CodigoCliente") = Me.codcliente



Me.CodigoCliente <=== Esse Campo nao existe no Formulario, seu Nome é (Me.codcliente)

rs2("CodCliente") <=== Esse Campo não existe na tabela, seu nome é (CodigoCliente)

Outra coisa, adicione mais uma Linha, a baixo da indicada a cima... Para que seja enviado também o Total pois faltou la no recordSet.

rs2("Total") = (Me.lstCompras.Column(3, NLinha) * Me.lstCompras.Column(2, NLinha)) 'Preenche o Total do Produto (Quantidade*ValorUnitario)

Fabio, vc é zika...


OBG mais uma vez.

Agr faz sentido a logica... proximas ja saberei como escrever.

fabio surgiu uma duvida. quando lanço dois produtos ele insere 2 na tabela, porem somente um vai com codcliente. como eu poderia estar fazendo aqui ?

Amigão, aqui esta indo todos... Testei aqui varias vezes e esta indo para todos os produtos.

So um detalhe no seu relacionamento:
Ele esta errado, o relacionamento entre as tabelas Vendas e DetalheVendas e entre o Código (tbVendas) e o CódigoVenda (tblDetalheVenda). <== Este e o Correto.

ja sei o que esta dando pau....

Me.codcliente = ""

como posso desenvolver nesta linhagem que limpe os campos? codcliente


abraços

Amigo, o codigo do cliente ja esta sendo limpado com o "", mas ele deve ser limpado apenas qnd fechar avenda... No momento em que é realizado a limpeza dos outros campos...

Ele deve ser incluído aqui nessa Função, pois é ela que limpa os campos:

Private Sub VerificaCampos()

FABIOOO,

mto obrigado... sanou todas as minhas duvidas. e como sempre obg. vc é fera. a cada topico me ajuda nos conhecimentos.

Segue o codigo pra negada ae... que estiver com duvidas fabiao vc é zika. Eu fiz sozinho aqui. nao tinha visto seu repost
quebrei a cabeça aqui, consegui mas depois ve seu post.

abraço ae meu querido.

Private Sub VerificaCampos()
Me.txtCalcula = Null
Me.lstCompras.RowSource = ""
Me.txtTotalCompra = Null
Me.txtDinheiro = Null
Me.txtCalcula.SetFocus
Me.txtTroco = Null
Me.txtDinheiro.Enabled = False
Me.txtDinheiro.Locked = True
Me.codcliente = Null
End Sub

ElseIf IsNull(Me.codcliente) Or Me.codcliente.Value = "" Then
MsgBox "Insira o codigo do cliente.", vbOKOnly + vbCritical, "ATENÇÃO"
Else

Grato pelo retorno amigo! Até a próxima se Deus quiser!

quebrei a cabeça aqui, consegui mas depois ve seu post.

Foi bom que aee vc aprendeu mesmo, rerererererere!

TMJ... meu querido.

abraço.