Exportar Vendas, Notas Fiscais com Delimitador para TXT.

Este é um exemplo simples de como pode ser feito para exportar Os dados de uma Venda para um arquivo de texto .txt.

Neste exemplo ele exporta todas as vendas ou apenas a Venda visualizada na tela. Mostra também como fazer para gerar o Arquivo pegando dados de Varias tabelas com relacionamento de um para Muitos entre si.

Fica aberto para os colegas com maior experiencia, para que ao acharem erros ou sugestões de Melhorias, que por favor poste para que possamos aprender ainda mais...

Foi utilizado alguns separadores (---------------- ============== _______________) para facilitar o aprendizado o entendimento do arquivo de Saída.

Codigo para Exportar Tudo da tabela:

Código:

Private Sub ExportaVenda_Click()
'------------------------------------------------------'
'Criado por Fabio Paes em 31/05/2016   '
'Para o Maximo access                             '
'------------------------------------------------------'
Dim strArquivo As String
Dim DB As Database
Dim rs As DAO.Recordset ' Dados tbVendas
Dim rs1 As DAO.Recordset ' Dados tbVendasDet
Dim F As Integer

strArquivo = Application.CurrentProject.Path & "\Vendas.txt" 'Caminho e Nome do Arquivo
Set DB = CurrentDb()
F = DCount("CodVenda", "TbVendas")
Set rs = DB.OpenRecordset("SELECT TbVendas.CodCli, TbCadCli.NomeCliente,TbCadCli.Endereco, TbCadCli.CPF, TbCadCli.RG, TbVendas.CodVenda, TbVendas.DataVenda, " & _
"TbVendas.FormaPgto, TbVendas.Dt_1Parcela,TbVendas.TotalPago, TbVendas.QtdeParcelas FROM TbCadCli INNER JOIN TbVendas ON TbCadCli.CodCli = TbVendas.CodCli ORDER BY TbVendas.CodVenda")

Open strArquivo For Output As #1 'Abre o arquivo para iniciar a escrita

Do While Not rs.EOF 'Inicia o Primeiro Loop para gravar os dados do primeiro registro da tabela tbVendas
Print #1, "|" & rs("CodCli") & "-" & rs("NomeCliente") & "|" & rs("CPF") & "|" & rs("RG") & "|" & rs("Endereco") & "|"
Print #1, "|" & Format(rs("CodVenda"), "00000") & "|" & rs("DataVenda") & "|"
Print #1, "--------------------------------------------------------------------------------------------------------"

    Set rs1 = DB.OpenRecordset("SELECT TbVendasDet.Produto, TbCadProd.Descricao, TbVendasDet.ValorUnit, " & _
    "TbVendasDet.Quantidade FROM TbCadProd INNER JOIN TbVendasDet ON TbCadProd.CodProd = TbVendasDet.Produto WHERE  CodVenda = " & rs!CodVenda & " ")
    
    Do While Not rs1.EOF 'Inicia o Segundo Loop para gravar os dados da tbVendasDet (os produtos e afins)
    Print #1, "   |" & rs1("Produto") & "-" & rs1("Descricao") & "|" & Format(rs1("ValorUnit"), "##,###.00") & "|" & rs1("Quantidade") & "|" & Format(rs1("ValorUnit") * rs1("Quantidade"), "##,###.00") & "|"
    rs1.MoveNext
    Loop
    
    'Totalizadores da Venda
Print #1, "=========================================="
Print #1, "|Forma Pagamento: " & rs("FormaPgto") & "|Qnt Parcelas: " & rs("QtdeParcelas") & "|"
Print #1, "|Data Primeira Parcela: " & rs("Dt_1Parcela") & "|"
Print #1, "|Total da Venda: " & Format(DSum("ValorUnit * Quantidade", "TbVendasDet", "CodVenda = " & rs!CodVenda & ""), "##,###.00")
Print #1, "|Total Pago: " & Format(rs("TotalPago"), "##,###.00") & "|"
Print #1, "=========================================="

'Adiciona dois Espaços ao final de cada Venda para facilitar a visualização
Print #1,
Print #1,

rs.MoveNext
Loop

'Fecha as conexoes
rs.Close
rs1.Close
DB.Close
Close #1
    
MsgBox "Foram Exportados " & F & " Vendas para o Aquivo: " & vbNewLine & strArquivo, vbInformation, ""
End Sub

Mestre Fabio! Muito bom o post! poderia me ajudar com o mesmo raciocinio, porém para exportar dados contidos em um formulário ao invés de um DB?

desde já muito obrigado!

Obrigado pela partilha!
Os seus preciosos exemplos enriquecem a cada dia este site magnífico.  
Cumprimentos