[Resolvido]Retornar os e-mails de vários usuários em uma tabela

Ola pessoal,

Estou usando o método SendObject para enviar um relatório pdf para alguns usuários. Normalmente digitando os e-mails no VBA conforme abaixo (e-mails exemplo):

DoCmd.SendObject acSendReport, "RT_Empregados", acFormatPDF, "joaoninguem@yahoo.com.br; marceloninguem@yahoo.com.br", "marianinguem@yahoo.com.br", , "Relatório Mensal", , False

Porém estes e-mails estão na tabela empregados e queria busca-los no VBA ao inves de digitar. Ou seja, buscar todos os e-mails da tabela onde a profissão é METROLOGISTA.
Tentei buscar estes e-mails e coloca-los numa string para usar depois no sendobject mas não deu certo:

Dim db As Database
Dim rs As DAO.Recordset
Set db = CurrentDb
Set rs = db.OpenRecordset("SELECT * Tabela1.email FROM Tabela1 WHERE (((Tabela1.Profissão)='METROLOGISTA'));"

A intenção é que a string rs = "joaoninguem@yahoo.com.br; marceloninguem@yahoo.com.br; marianinguem@yahoo.com.br"

Para que eu possa usa-la no SendObject assim:

DoCmd.SendObject acSendReport, "RT_Empregados", acFormatPDF, rs , , , "Relatório Mensal", , False

Se eu fizer uma consulta funciona mas no VBA não consegui. Alguém tem uma dica?


OBS: Obrigado pela ajuda que vocês tem me dado. Sem o Maximo seria impossível aprender a programar em VBA. Obrigado a todos

Ao pressionar de um botão no seu formulario;

Código:

Private Sub SeuBotão_Click()
Dim rst As DAO.Recordset
Dim strDestinatarios
Dim i As Integer

Set rst = CurrentDb.OpenRecordset("SELECT * FROM Tabela1 WHERE Profissão='METROLOGISTA'")
i = 0

Do Until rst.EOF
    strDestinatarios = strDestinatarios & rst("Email") & ";"
    i = i + 1
    rst.MoveNext
Loop
   
    strDestinatarios = Left(strDestinatarios, Len(strDestinatarios) - 1)
 
DoCmd.SendObject acSendReport, "RT_Empregados", acFormatPDF, strDestinatarios, , , "Relatório Mensal", , False
   
rst.Close
Set rst = Nothing
End Sub

JPaulo, o código funcionou perfeito!

Muito Obrigado pela ajuda.

Sucesso a todos...

Obrigado pelo retorno o forum agradece.