[Resolvido]Enviar todo os Arquivos de Uma Pasta Via E-mail

Bom dia,

Gostaria da ajuda de vocês.

Tenho uma ferramenta e estou precisando enviar todos os arquivos de uma determinada pasta por e-mail de uma única vez.

É tudo PDF.

Alguém tem alguma ideia de como fazer?

Preciso só da parte de anexar, as demais linhas do código já está OK.

Rodrigo

Ola;

Espero que o ajude, aqui funfa a mil;

Código:

Function EnvioAutomaticoDeEmail()
'By JPaulo ® Maximo Access
'Requer que a referencia VBA
'Microsoft Outlook xx.0 Object Library
'seja marcada
Dim strAplicacao As Outlook.Application
Dim objMail As Outlook.MailItem
Dim strCaminho As String
Dim strFicheiros As String

'Caminho da pasta onde se encontram os PDF`s
strCaminho = "C:\temp\"
'Pesquisa apenas por ficheiros PDF
strFicheiros = Dir(strCaminho & "*.pdf")
'Cria uma noca instância no Outlook
Set strAplicacao = New Outlook.Application
Set objMail = strAplicacao.CreateItem(olMailItem)
'Monta o email
With objMail
    .Subject = "Teste"
    .Body = "teste de envio"
    .To = "jpaulo65@gmail.com"
'Percorre e adiciona todos os ficheiros
Do While Len(strFicheiros) > 0
        .Attachments.Add (strCaminho & strFicheiros)
    strFicheiros = Dir
Loop
    
    On Error Resume Next
    '.Send
    .Display
 
    If Err.Number = 287 Then
        End
    End If
End With
End Function


Aguardo seu retorno para encerrar o tópico.

JPaulo,

Muito obrigado, perfeito como sempre. Funcionou do jeito que eu queria.

Estou finalizando o tópico.

E abrindo mais um com outra dúvida..rsrs

Rodrigo

Obrigado pelo retorno o fórum agradece.