[Resolvido]Dias úteis após data de inicio com feriados

Bom dia

Necessito uma vez mais de ajuda na resolução deste código.
Este ficheiro de access estava como o 2000 e reconverti para 2007, a função deu erro no código: rs_fer.FindFirst "[FerData] = #" & Format(DataFinal, "mm/dd/yy") & "#"

Dim DataFinal As Date
Dim Dias, Semana As Integer
Dim db As Database
Dim rs_fer As Recordset

Set db = CurrentDb
Set rs_fer = db.OpenRecordset("tblFeriados", dbOpenDynaset)

Dias = 0
DataFinal = DataInicial

While Dias < QtdDiasUteis
DataFinal = DataFinal + 1
Semana = Weekday(DataFinal)
If Semana <> 1 And Semana <> 7 Then ' 1=Domingo 7=Sábado


rs_fer.FindFirst "[FerData] = #" & Format(DataFinal, "mm/dd/yy") & "#"
If rs_fer.NoMatch Then



Dias = Dias + 1
End If
End If
Wend

DataUtil = DataFinal

Bom dia
Teste asim
rs_fer.FindFirst "[FerData] = #" & Format(DataFinal, "dd/mm/yyyy") & "#"

Continua a dar erro.

"Method or data not found"

tenta esta função cortesia do nosso amigo Jpaulo

Public Function DiasUteis(dtInicio As Date, dtFim As Date) As Long
'By JPaulo ® Maximo Access
'Total de Dias entre duas datas sem fins de semana
Dim TotalDiasActuais As Long, TotalDiasTrab As Long
Dim strIniciaContagem As Long

DoCmd.Hourglass (-1)
strIniciaContagem = -2
TotalDiasActuais = (dtFim - dtInicio) + 1

Do
If Weekday(dtInicio) = 7 Or Weekday(dtInicio) = 1 Then
strIniciaContagem = strIniciaContagem + 1
End If

dtInicio = dtInicio + 1

Loop Until dtInicio = dtFim + 1

TotalDiasTrab = TotalDiasActuais - strIniciaContagem
DoCmd.Hourglass (0)
DiasUteis = TotalDiasTrab
Exit Function
End Function


Abraço

O problema é que tenho uma data de inicio e preciso que me devolva a data de fim, após 12 dia úteis (indo buscar os feriados a uma tabela).

Public Function DataUtil(DataInicial As Date, QtdDiasUteis As Integer) As Date

Agradeço a vossa ajuda, mas já encontrei um código que me resolve o que eu queria, mantendo a tabela de feriados.


Public Function DiasUteisComNumero(dtInicio As Date, NumDias As Integer) As Date
'---------------------------------------------------------------------------------------
' Procedimento : DiasUteisComNumero
' Data e Hora : 22/08/07 18:47
' Autor : Osmar José Correia Júnior
' O que faz : Devolve um dia útil a partir de uma data inicial fornecido um número de dias
'
' Entradas : dtInicio - Data inicial
' : NumDias - Número de dias úteis a serem acrescentados
'
' Saída : Data
'
' Utilize à vontade mas não altere este cabeçalho.
' Valorize quem o ajuda.
'---------------------------------------------------------------------------------------

On Error GoTo Erro_DiasUteisComNumero

Dim dtTrab As Date
Dim DB As DAO.Database
Dim rst As DAO.Recordset

Set DB = CurrentDb
Set rst = DB.OpenRecordset("SELECT [FerData] FROM tblFeriados", dbOpenSnapshot)

dtTrab = DateAdd("d", NumDias, dtInicio)

Do While dtInicio <= dtTrab
If Weekday(dtInicio) = vbSunday Or Weekday(dtInicio) = vbSaturday Then
dtTrab = dtTrab + 1
Else
rst.FindFirst "[FerData] = #" & Format(dtInicio, "mm/dd/yyyy") & "#"
If Not rst.NoMatch Then dtTrab = dtTrab + 1
End If
dtInicio = dtInicio + 1
Loop
DiasUteisComNumero = dtTrab
Saida:
Exit Function
Erro_DiasUteisComNumero:
MsgBox Err.Description & vbCrLf & vbCrLf & "No módulo fDUteis, tipo Módulo, procedimento DiasUteisComNumero", _
vbExclamation + vbOKOnly, "Erro: " & CStr(Err.Number)
Resume Saida
End Function

Obrigado

Olá Caros colegas,
Peguei esse código do nosso colega Sérgio e foi tudo o que estava precisando para calcular datas futuras com dias úteis
Criei um módulo com esse código

Criei uma campo calculado com essa função e ficou assim.
DtPrevista:DiasUteisComNumero([DtProcesso];30).
Tenho um arquivo com 40.000 linhas, demora um pouco para processar mas Ok, até  aí tudo bem mas, o problema é que quando vou copiar ou exportar essa consulta para o excel, isso leva 5 horas para processar, não importa o método, alguém saberia o que pode estar ocorrendo?

Obrigado,
Cleniro.

Olá Avelino,

Fiz a indexação dos campos da tabela de origem mas, infelizmente não funcionou, demora do mesmo jeito. Testei excluindo esse campo calculado e deixei todos os outros campos, inclusive os campos com critérios de filtragem e tudo rodou rápido, seja para Ctrl C, seja para exportar para o excel através de macro, ou para consulta criar nova tabela, ou seja, será que o problema deve estar com o método de cálculo usado no VB que deixa o processamento pesado? O interessante é que o cálculo funciona bem e a consulta não demora abrir.

Obrigado pela disposição em ajudar,
Abs,