[Resolvido]Consulta Access

Oi pessoal, bom dia!

Estou fazendo um banco de dados para uma creche. Consegui fazer os códigos para cadastrar, foi difícil mas consegui. Agora o meu problema é a consulta, fiz o código, quero consultar todos os dados através do nome completo da criança só que posso colocar qualquer nome e a consulta só me retorna o mesmo aluno. Gostaria muito da ajuda de vocês.
Vou colocar o código que estou usando:
Private Sub CmdConsultar_Click()

Dim Banco As Database
Dim Tabela As Recordset
Dim Comando As String

If TxtNome <> "" Then

Comando = "SELECT * From TabCadAluno Where Nome = "" &TxtNome&"""
Set Banco = CurrentDb
Set Tabela = Banco.OpenRecordset("TabCadAluno", dbOpenDynaset)

If Tabela.RecordCount <> 0 Then
TxtCodigo = Tabela("Código")
TxtNome = Tabela("Nome")
TxtNascimento = Tabela("Nascimento")
TxtNaturalidade = Tabela("Naturalidade")
TxtEndereco = Tabela("Endereço")
TxtCEP = Tabela("CEP")
TxtTelefone = Tabela("Telefone")
TxtCelular = Tabela("Celular")
TxtMatricula = Tabela("Matrícula")
TxtDesligamento = Tabela("Desligamento")
TxtMae = Tabela("Mãe")
TxtPai = Tabela("Pai")
TxtNIS = Tabela("NIS")
TxtBolsa_Familia = Tabela("Bolsa Família")
TxtCodigo_Certidao = Tabela("Código Certidão")
TxtObservacao = Tabela("Observação")

CmdAlterar.Enabled = True
CmdExcluir.Enabled = True
CmdCadastrar.Enabled = False
CmdConsultar.Enabled = True

Else

MsgBox ("Não foi encontrado nenhum registro com o nome informado!"), vbInformation + vbOKOnly, "Nenhum Registro"
End If

Else

MsgBox ("Necessário Informar o nome completo para efetuar a consulta!"), vbInformation + vbOKOnly, "Nome Completo Necessário"
End If

End Sub

Tente assim. Modifiquei um pouco a sua SQL, e coloquei a variável Comando no lugar do nome da tabela quando você abre o RecordSet, pois já que você construiu uma SQL para filtrar o nome do aluno, não precisa abrir também a tabela. Caso contrário, só abrir a tabela não adianta, você teria que movimentar o RecordSet até o registro do aluno.

Código:

Dim Banco As DAO.Database
Dim Tabela As DAO.Recordset
Dim Comando As String

If Me.TxtNome <> "" Then

Comando = "SELECT * From TabCadAluno Where TabCadAluno.Nome ='" & Me.TxtNome & "'"
Set Banco = CurrentDb
Set Tabela = Banco.OpenRecordset(Comando, dbOpenDynaset)

If Tabela.RecordCount <> 0 Then
    With Me
        .TxtCodigo = Tabela("Código")
        .TxtNome = Tabela("Nome")
        .TxtNascimento = Tabela("Nascimento")
        .TxtNaturalidade = Tabela("Naturalidade")
        .TxtEndereco = Tabela("Endereço")
        .TxtCEP = Tabela("CEP")
        .TxtTelefone = Tabela("Telefone")
        .TxtCelular = Tabela("Celular")
        .TxtMatricula = Tabela("Matrícula")
        .TxtDesligamento = Tabela("Desligamento")
        .TxtMae = Tabela("Mãe")
        .TxtPai = Tabela("Pai")
        .TxtNIS = Tabela("NIS")
        .TxtBolsa_Familia = Tabela("Bolsa Família")
        .TxtCodigo_Certidao = Tabela("Código Certidão")
        .TxtObservacao = Tabela("Observação")
    
        .CmdAlterar.Enabled = True
        .CmdExcluir.Enabled = True
        .CmdCadastrar.Enabled = False
        .CmdConsultar.Enabled = True
    End With
    Else
         MsgBox ("Não foi encontrado nenhum registro com o nome informado!"), vbInformation + vbOKOnly, "Nenhum Registro"
End If

Tabela.Close
Banco.Close

Julio Lustosa, bom dia!

Deu certo!!! Muito obrigada, problema resolvido.
Agradeço muito ao Fórum também.

Obrigada!
Problema resolvido!
Gil