Programa de Nota Fiscal avulsa

Estou criando um sistema de Nota Fiscal Avulsa no Acces,tenho 3 tabelas e 3 formularios: Nota Fiscal,Recibo e DAM,para cada Nota emitida tem que gerar um recibo e um Dam,como procedo para isso?

Olá Romulo,

Imaginando que você utilizaria um estrutura semelhante à figura_1.jpg (anexa).
Sugiro criar um módulo com os métodos de inclusão em cada tabela para serem chamados em sequência.

Código:


Option Compare Database
Option Explicit

Private db As Database
Private rs As Recordset

Public Sub incluirNotaFiscal( _
            intNumeroNotaFiscal As Integer, _
            dtDataEmissaoNotaFiscal As Date)
On Error GoTo erro:

    Set db = CurrentDb()
    Set rs = db.OpenRecordset("tblNotaFiscal", dbOpenTable)
    
    rs.AddNew
        rs!numeroNotaFiscal = intNumeroNotaFiscal
        rs!dataEmissaoNotaFiscal = dtDataEmissaoNotaFiscal
    rs.Update
    
saida:
    Set rs = Nothing
    Set db = Nothing
    Exit Sub
erro:
    MsgBox "INCLUIR_NOTA_FISCAL: " & vbNewLine & Err.Description
    Resume saida:
End Sub

Public Sub incluirRecibo( _
            intIdNotaFiscal As Integer, _
            intNumeroRecibo As Integer, _
            dtDataEmissaoRecibo As Date)
On Error GoTo erro:

    Set db = CurrentDb()
    Set rs = db.OpenRecordset("tblRecibo", dbOpenTable)
    
    rs.AddNew
        rs!idNotaFiscal = intIdNotaFiscal
        rs!numeroRecibo = intNumeroRecibo
        rs!dataEmissaoRecibo = dtDataEmissaoRecibo
    rs.Update

saida:
    Set rs = Nothing
    Set db = Nothing
    Exit Sub
erro:
    MsgBox "INCLUIR_RECIBO: " & vbNewLine & Err.Description
    Resume saida:
End Sub

Public Sub incluirDAM( _
            intIdNotaFiscal As Integer, _
            intNumeroDAM As Integer, _
            dtDataEmissaoDAM As Date)
On Error GoTo erro:

    Set db = CurrentDb()
    Set rs = db.OpenRecordset("tblDAM", dbOpenTable)
    
    rs.AddNew
        rs!idNotaFiscal = intIdNotaFiscal
        rs!numeroDAM = intNumeroDAM
        rs!dataEmissaoDAM = dtDataEmissaoDAM
    rs.Update

saida:
    Set rs = Nothing
    Set db = Nothing
    Exit Sub
erro:
    MsgBox "INCLUIR_DAM: " & vbNewLine & Err.Description
    Resume saida:
End Sub


A partir de um formulário qualquer você chamaria os 3 métodos sequencialmente passando os parâmetros desejados.

Espero ter sido útil.
Att.
Sampaio