[Resolvido]Filtro entre datas(Data Geral)

Boa tarde galera!

Tem alguns dias que já venho tentando fazer um filtro entre datas via VB apartir de uma consulta que contem um campo do tipo DataGeral(dd/mm/aaaa hh:mm:ss)

Mas até então não consegui, revirei todos os exemplos, todas os topicos e nada!

Tenho formulário que contem 2 campos do tipo data abreviada e um botão para executar o código que irá preencher o formulário com os dados que estão entre as datas informadas.

Código:

    'Expressão para busca de datas
    If Not IsNull(Me.Data_Inicio) And Not IsNull(Me.Data_Fim) Then

        'Funciona + ou -
        strWhere = strWhere & "Data_Registro Between " & Me.Data_Inicio & " and " & Me.Data_Fim & " and"
        
    End If

Como posso resolver isso?

Desde já agradeço a atenção!

Boa tarde,
Veja se a variável strWhere termina em espaço
Veja a formatação das datas Format(Me.Data_Inicio,"dd-mm-yyyy") ou outras variantes
Dê continuidade à(s) condição(ões) para dar completar a expressão strWhere

Boa Tarde Alexandre!

Já fiz boas tentativas aqui nesse sentido mas não tive exito! Já converti as data em string, já formatei as datas em dd/mm/aaaa e nada!

Esse é meu codigo completo da StrWere:

Código:

Private Function BuildWhereString() As String
    Dim strWhere As String
    Dim varItemSel As Variant

    On Error Resume Next

    strWhere = ""

    'Expressão para Busca por Tipo de veículos
    Select Case Me.fraOTipo.Value
    Case 1  '  Próprio
        strWhere = strWhere & "Tipo = 1 And "
    Case 2  '  Terceiro
        strWhere = strWhere & "Tipo = 2 And "
    End Select

    'Expressão para busca de datas
    If Not IsNull(Me.Data_Inicio) And Not IsNull(Me.Data_Fim) Then
        'Funciona + ou -
        strWhere = strWhere & "Data_Registro Between " & Me.Data_Inicio & " and " & Me.Data_Fim & " and"
    End If

    'Expressão para Busca_Placa
    If Len(Me.Busca_Placa.Value & "") > 0 Then
        strWhere = strWhere & "Placa "
        strWhere = strWhere & Choose(Me.fraOName.Value, strNoStartWildCard, strStartWildCard, strEqual_1)
        strWhere = strWhere & Me.Busca_Placa.Value
        strWhere = strWhere & Choose(Me.fraOName.Value, strContainWildCard, strContainWildCard, strEqual_2)
        strWhere = strWhere & " And "
    End If
    
    'Expressão para Busca_Num
    If Len(Me.Busca_Num.Value & "") > 0 Then
        strWhere = strWhere & "ID_Checklist "
        strWhere = strWhere & Choose(Me.fraOName.Value, strNoStartWildCard, strStartWildCard, strEqual_1)
        strWhere = strWhere & Me.Busca_Num.Value
        strWhere = strWhere & Choose(Me.fraOName.Value, strContainWildCard, strContainWildCard, strEqual_2)
        strWhere = strWhere & " And "
    End If

    If Len(strWhere) > 0 Then strWhere = Left(strWhere, Len(strWhere) - Len(" And "))

    BuildWhereString = strWhere
    Exit Function
End Function

e esse é o codigo do botão pesquisar:

Código:

Private Sub bt_Pesquisar_Click()
    Dim strSQL As String

    On Error Resume Next

    DoCmd.Hourglass True

    ' move focus to clear button
    Me.Bt_Limpar.SetFocus
    ' Verifica se foi informado algum filtro
    If BuildWhereString <> "" Then
        strSQL = BuildWhereString
        strSQL = "SELECT * FROM " & strMainformRecordSource & _
                 IIf(strSQL = "", "", " WHERE ") & strSQL & ";"
    Else
        strSQL = "SELECT * FROM " & strMainformRecordSource & ";"
    End If

    Me.RecordSource = ""
    Me.RecordSource = strSQL

    Call SetVisibility(True)

    DoCmd.Hourglass False
End Sub

Os demais campos funcionam perfeitamente, mas quando usa os campos datas ai não vai de jeito nenhum!

Deverá ser
strWhere = strWhere & "Data_Registro Between " & Me.Data_Inicio & " and " & Me.Data_Fim & " and "

Caro Alexandre!

Já tem + de mês que tento resolver questão e não havia conseguido! E quando a gente menos espera nos vem a solução!

veja como resolvi!

Código:

'Expressão para busca de datas
    If Not IsNull(Me.Data_Inicio) And Not IsNull(Me.Data_Fim) Then
        strWhere = strWhere & "Data_Registro >= #" & Format(Me!Data_Inicio, "mm/dd/yyyy") & "#" _
                & " And Data_Registro <= #" & Format(Me!Data_Fim + 1, "mm/dd/yyyy") & "#"
        strWhere = strWhere & " And "
    End If

Eu estava preso between, e quando resolvi mudar a linha de raciocínio a coisa da certo!

ainda bem que conseguiste eu ainda não consegui mas o teu código de data ajuda muito