[Resolvido]Problemas com o Dlookup em busca de dados em duas tabelas ao mesmo tempo

Colegas da selva bom dia e feliz 2014 a todos.
Tenho o seguinte código que esta me dando dor de cabeça:

Código:

Private Sub cbocliente_AfterUpdate()
DoCmd.ApplyFilter , "idprop = " & Me!cbocliente.Column(0) 
 
Me!cbocliente = Null 

If (DLookup("pendencia", "proprietarios", "Idprop = " & Me.IdProp)) And (DLookup("proprietarios", "animal", "caixa", "idprop= " & Me.IdProp)) Then
            'campo      tabela            pk              pk                                          'campo          ´campo  'tabela
 MsgBox "Cliente" & Prop & "  está com débitos em haver !" & " do animal" & Animal, vbCritical, "SIS CLIN"
           
End If
DoCmd.RunCommand acCmdRefresh
End Sub

não estou conseguindo fazer com que o mesmo me mostre os resultados desejados. ele me mostra a seguinte mensagem:
erro de compilação
Número de argumentos incorreto ou atribuição de propriedade inválida.


Se alguém puder me dar uma luz, fico agradecido.

Abraços e novamente feliz 2014 a todos.

And DLookup("proprietarios", "animal", "caixa", "idprop= " & Me.IdProp)

ao quê se refere o caixa na parte de critério do dlookup?

Boa tarde jungli....

Caixa é outra tabela.

Então como o Dlookup tem esta forma Dlookup(Expressão,Dominio,Critério), eu penso que a falha está aí

DLookup("proprietarios", "animal", "caixa", "idprop= " & Me.IdProp)
__________ 1 _______,__ 2 __,__ 3 __,______ 4 ___________

Não seria:

DLookup("animal", "caixa", "idprop= " & Me.IdProp)

a ser usado?

Tens razão nobre amigo.

Acho que estou fazendo alguma besteira aqui.

Vou anexar um exemplo do que estou a desenvolver.

abraços

Jungli, em anexo parte do projeto que estou a desenvolver.  Nele há um frm explicativo.

Grato dede já pela tua ajuda.

Silvio

ok, vou dar uma olhada e já te retorno.

ok, estou no aguardo então !

Tente assim:


Private Sub cbocliente_AfterUpdate()
DoCmd.ApplyFilter , "idprop = " & Me!cbocliente.Column(0)  ' idcliente chave primaria, cbocliente, onde vai buscar o nome desejado

Me!cbocliente = Null  'deixa a combo vazia, limpa.

'Adicionei....
Dim nAnimal As String, nPendencia As Boolean, nValor As Double

'Usando o Dlookup, pegando vários campos com uma ida apenas na tabela
Dim cps As String, k
cps = "[Animal] & '|' & [Valor]" 'informando os campos
cps = DLookup(cps, "caixa", "Proprietario = '" & Me.Prop & "'")  ' executando o comando
k = Split(cps, "|") 'quebrando (eliminando o caractere "|")
nAnimal = k(0) 'preenchendo as variáveis
nValor = k(1)
'executando o comando "verificando pendencia"
nPendencia = DLookup("pendencia", "proprietarios", "Idprop = " & Me.idprop)

   If nPendencia = True Then
       MsgBox "Cliente   " & Me.Prop & "   está com débitos em haver !" & _
              " do animal  " & nAnimal & _
              ", no valor de:  " & Format(nValor, "currency"), vbInformation, "Sis Clin"
   End If

DoCmd.RunCommand acCmdRefresh
End Sub

OBS: não encontrei o campo Idprop na tabela Caixa, no exemplo busquei as informações pelo nome do proprietário.
evite nomear campos como Valor pois o access tem internamente a propriedade Value, e vais ter problemas depois.

espero ter ajudado,

Na mosca.....fiz apenas uma alteração, pois no meio do caminho, optei por usar uma listbox por ser mais abrangente. Ficou assim:

Código:

Private Sub lstcliente_Click()
On Error Resume Next
Dim intrecord As Integer
intrecord = Me!lstcliente.Column(0)
Forms!proprietarios.SetFocus
DoCmd.GoToControl "idprop"
DoCmd.FindRecord intrecord

Dim nAnimal As String, nPendencia As Boolean, nValor As Double

'Usando o Dlookup, pegando vários campos com uma ida apenas na tabela
Dim cps As String, K
cps = "[Animal] & '|' & [Valor]" 'informando os campos
cps = DLookup(cps, "caixa", "Proprietario = '" & Me!lstcliente.Column(1) & "'")  ' executando o comando
K = Split(cps, "|") 'quebrando (eliminando o caractere "|")
nAnimal = K(0) 'preenchendo as variáveis
nValor = K(1)
'executando o comando "verificando pendencia"
nPendencia = DLookup("pendencia", "proprietarios", "Idprop = " & Me!lstcliente.Column(0))

  If nPendencia = True Then
      MsgBox "Cliente  " & Me!lstcliente.Column(1) & "    está com débitos em haver " & _
              " do animal  " & nAnimal & _
              ", no valor de:  " & Format(nValor, "currency"), vbInformation, "Sis Clin"
  End If




Exit Sub
End Sub

Grato meu amigo, aprendi mais uma com você ! Feliz 2014 a ti e aos teus.

Silvio

  Fico Feliz
   Em ajudar

Feliz 2014 para você e seus familiares também.