[Resolvido]Ajuda criação de Grafico

Option Compare Database
Option Explicit
'Variável para comportar o ítem clicado
Dim Critério1 As String
'Variável para comportar o departamento clicado
Dim Critério  As String
'------------------------------------------------

'---------------------------------------------------------------------------------------
' Procedure     : GeraGraficoPiloto
' Author        : Harysohn P. Pina (PILOTO) - Harysohn@hotmail.com
' Fórum         : Fórum Máximo Access -  http://maximoaccess.forumeiros.com/
' Date          : 04/07/2013
' Comentários   : Carrega um gráfico baseado no botão clicado segundo o critério
'                 do nome do botão (Departamento)
'---------------------------------------------------------------------------------------
Sub GeraGraficoPiloto()
Dim Rs As DAO.Recordset
    Dim SQL As String
    Grafico1.RowSource = ""
    Grafico1.Visible = True 'Torna visível o gráfico.
    
    'Coloca na variável que servirá ao filtro, o nome do controle ativo no formulário
    'Este controle será o nome do botão clicado. As declarações desta variável fica nas declarações do módulo
    'e se deve ao fato de ter que manter o seu valor em qualquer procedimento sendo assim utilizado no segundo filtro
    Critério = Me.ActiveControl.Name
    
    'Guarda o nome da Despesa na textbox oculta.
    Me.txtDespesa = Critério
    'Carrego na SQL uma consulta agrupada, com a soma dos meses, filtrada pelo campo departamento
    SQL = "SELECT Tbl_Produtos.[Departamento], Sum(Tbl_Produtos.[Jan]) AS Jan, Sum(Tbl_Produtos.[Fev]) AS Fev," _
        & "Sum(Tbl_Produtos.[Mar]) AS Mar, Sum(Tbl_Produtos.[Abr]) AS Abr,  Sum(Tbl_Produtos.[Mai]) AS Mai," _
        & "Sum(Tbl_Produtos.[Jun]) AS Jun, Sum(Tbl_Produtos.[Jul]) AS Jul, Sum(Tbl_Produtos.[Ago]) AS Ago," _
        & "Sum(Tbl_Produtos.[Set]) AS [Set], Sum(Tbl_Produtos.[Out]) AS Out, Sum(Tbl_Produtos.[Nov]) AS Nov," _
        & "Sum(Tbl_Produtos.[Dez]) AS Dez FROM Tbl_Produtos WHERE Departamento='" & Critério & "'" _
        & " GROUP BY Tbl_Produtos.[Departamento];"
    
    Grafico1.RowSource = SQL 'Define a origem do gráfico.
    lblCredor.Caption = Critério 'Altera o título do form.

End Sub

'---------------------------------------------------------------------------------------
' Procedure     : GeraGraficoPiloto
' Author        : Harysohn P. Pina (PILOTO) - Harysohn@hotmail.com
' Fórum         : Fórum Máximo Access -  http://maximoaccess.forumeiros.com/
' Date          : 04/07/2013
' Comentários   : Carrega um gráfico baseado no botão clicado segundo dois critérios
'                 baseado nos nomes de dois botões, Departamento/Item
'---------------------------------------------------------------------------------------
Sub GeraGraficoPiloto1()
    Dim SQL As String
    Grafico1.RowSource = ""
    Grafico1.Visible = True 'Torna visível o gráfico.
    
    'Coloca na variável que servirá ao filtro, o nome do controle ativo no formulário
    'Este controle será o nome do botão clicado. As declarações desta variável fica nas declarações do módulo
    'e se deve ao fato de ter que manter o seu valor em qualquer procedimento.
    Critério1 = Me.ActiveControl.Name
    'Guarda o nome do Item na textbox oculta.
    Me.txtDespesa = Critério
    'Esta SQL não há necessidade de ser agrupada pois sempre retornará um ítem
    SQL = "SELECT * FROM Tbl_Produtos WHERE Departamento='" & Critério & "' And Item='" & Critério1 & "';"

    Grafico1.RowSource = SQL 'Define a origem do gráfico.
    lblCredor.Caption = Critério & " - " & Critério1 'Altera o título do form.

End Sub

'Carrega o gráfico segundo o critério do botão ativo na hora que carrega o formulário
'para o botão ficar ativo envia o foco para o mesmo
Private Sub Form_Load()
Me.Congelados.SetFocus
Me.GeraGraficoPiloto
End Sub

'//////////////////////////////////////////////////////////////////////////////////
'Inicio dos botões
'Está feito para os departamentos: Congelados e Frios
'E para os botões: Dourada,Paes,Piau e Repolho
'Basta criar demais botões e o nomear com o nome do departamento ou item
'A Sub GeraGraficoPiloto  >>>> Departamento
'A Sub GeraGraficoPiloto1 >>>> Item
'//////////////////////////////////////////////////////////////////////////////////
Private Sub Congelados_AfterUpdate()
Me.GeraGraficoPiloto
End Sub

Private Sub Frios_Click()
Me.GeraGraficoPiloto
End Sub

Private Sub Dourada_Click()
Me.GeraGraficoPiloto1
End Sub

Private Sub Paes_Click()
Me.GeraGraficoPiloto1
End Sub

Private Sub Piau_Click()
Me.GeraGraficoPiloto1
End Sub

Private Sub Repolho_Click()
Me.GeraGraficoPiloto1
End Sub