[Resolvido]Pesquisa caixa de combinação, modicicar codigo

Peguei como exemplo esse codigo

Código:

Private Sub Report_Open(Cancel As Integer)

  '  Create underlying recordset for report using criteria entered in
  '  frmTeste form.
   
  Dim intX As Integer
  Dim qdf As QueryDef
  Dim frm As Form

  '  Set database variable to current database.
  Set dbsReport = CurrentDb
  Set frm = Forms!frmTeste
  '  Open QueryDef object.
  Set qdf = dbsReport.QueryDefs("EmployeeSales")
  ' Set parameters for query based on values entered
  ' in frmTeste form.
  qdf.Parameters("Forms!frmTeste!BeginningDate") _
    = frm!BeginningDate
  qdf.Parameters("Forms!frmTeste!EndingDate") _
    = frm!EndingDate

  '  Open Recordset object.
  Set rstReport = qdf.OpenRecordset()
 
  '  Set a variable to hold number of columns in crosstab query.
  intColumnCount = rstReport.Fields.Count
   
End Sub




só que ele faz a pesquisa entre duas datas e eu tenho um formulario com uma caixa de combinacao onde o cambo regiao vai ser filtrado.

estou tendo dificuldades, em modificar.. alquem ajuda?

Tente trocar a parte abaixo:

Código:

  qdf.Parameters("Forms!frmTeste!BeginningDate") _
    = frm!BeginningDate
  qdf.Parameters("Forms!frmTeste!EndingDate") _
    = frm!EndingDate

para:

Código:

  qdf.Parameters("Forms!frmTeste!NomeDoCampo") = frm!NomeDoCombo.Value

ou, no lugar do Value, coloque Column(0). Se a coluna aonde está o filtro não for a primeira, alterar para o número correto.

criquio, tentei mas não deu..
o que eu quero fazer é gerar um formulario atraves de uma consulta de referencia cruzada, aqui no forum tem bastante coisa disso.. o exemplo que peguei é daqui

http://maximoaccess.forumeiros.com/t215-relatorio-referencia-cruzada

mas estou tendo dificuldades, o botao de gerar relatorio nao funciona de geito nenhum, e pior nao apresenta nenhum erro.

se tu ja viu um outro exemplo, me ajude

Depois de Muita Luta consegui..

Pra quem quer gerar um relatorio com referencia cruzada, sem ter que colocar quais campos terao no relatorio..

Código:



é para relatório.

No cabeçalho deve ter os rotulos:
lblCabec1,lblCabec2, lblCabec3....

No Detalhe:
txtDet1;txtDet2;txtDet3.... (aqui eu usei label, pois o rotulo nao funcionou)

No rodapé:
txtSoma1;txtSoma2;txtSoma3....

-----------------------------------------------

Private Sub Report_Open(Cancel As Integer)
'Atribui o nome e origem dos controles conforme
'o resultado da consulta de referência cruzada
Dim Db As DAO.Database
Dim rst As DAO.Recordset
Dim intQtColunas As Integer
Dim intQtControles As Integer
Dim i As Integer
Dim strNome As String

On Error Resume Next

DoCmd.Maximize

'Para pegar o nome dos campos, o Recordset deve
'ser o mesmo da origem da consulta
Set Db = CurrentDb()
Set rst = Db.OpenRecordset(Me.RecordSource)

'Verifica o número de colunas
intQtColunas = rst.Fields.Count

'Verifica o número de controles disponíveis no relatório
intQtControles = Me.Detalhe.Controls.Count

'Limita o número de campos ao número de controles disponíveis
If intQtControles < intQtColunas Then
intQtColunas = intQtControles
End If

'Coloca as informações nos controles
For i = 1 To intQtColunas
'Pega o nome da coluna
strNome = rst.Fields(i - 1).Name
'Coloca a legenda nos rótulos
Me.Controls("lblCabec" & i).Caption = strNome
'Informa a origem dos controles
Me.Controls("txtDet" & i).ControlSource = strNome
Me.Controls("txtSoma" & i).ControlSource = _
"=Sum([" & strNome & "])"
Next i

'Oculta os controles não usados
For i = intQtColunas + 1 To intQtControles
Me.Controls("txtDet" & i).Visible = False
Me.Controls("lblCabec" & i).Visible = False
Me.Controls("txtSoma" & i).Visible = False
Next i

'Fecha o recordset e libera a memória
rst.Close
Db.Close
Set rst = Nothing
Set Db = Nothing
End Sub


Aldo Cres

Depois no relatório coloque a consulta cruzada em 'Fonte de Registro'

o link que eu consegui a resposta é esse:


http://comunidade.itlab.com.br/eve/forums/a/tpc/f/273606921/m/1221030791

acredito que vai ajudar muita gente, pois é simples e direto. pois no codigo nao precisa modificar nada

.

Grato pelo retorno. O fórum agradece.