[Resolvido]Excluir dados duplicados sem chave

Prezados,

Sou leigo no assunto banco de dados e estou precisando de ajuda, testei a exclusão de duplicadas conforme pesquisas no forum mas não consegui efetuar o mesmo, poderiam me ajudar, os campos para verificação são DATA, XPROCESSO e XEVENTO.
Detalhe, minha tabela não possui chave.

Agradeço a ajuda.

Aconselho a colocar a chave. Ela é essencial para evitar problemas com filtragens por exemplo. Agora, para o que você precisa, acredito que um Recordset em companhia do DCount resolva. Algo como:

Código:

Dim rs As Recordset

Set rs = CurrentDb.OpenRecordset("NomeDaTabela")

Do While Not rs.EOF

    If DCount("*", "NomeDaTabela", "Campo1='" & rs!Campo1 & "' And Campo2='" & rs!Campo2 & "' And Campo3='" & rs!Campo3 & "'") > 1 Then

          CurrentDb.Execute "DELETE * FROM NomeDaTabela WHERE Campo1='" & rs!Campo1 & "' And Campo2='" & rs!Campo2 & "' And Campo3='" & rs!Campo3 & "'"

    End If

rs.MoveNext
Loop

rs.Close
Set rs = Nothing

Teste em uma cópia do aplicativo para ver se funciona sem dar problema.

OBS.: Como diz JPaulo, existem mil maneiras de se chegar ao resultado e como eu já tinha preparado o post, vou postar para não perder o trabalho.
Espero que o mestre não se importe

Retirei o que disse porque não tinha entendido que era para excluír.

Obrigado pela ajuda, mas ainda não funcionou, ou estou fazendo errado ( que é o mais provavel )

Quando gero este código no VBA me da erro de depuração 3464.

Sub Excluir()

Dim rs As Recordset
Set rs = CurrentDb.OpenRecordset("d_pr_eventos")
Do While Not rs.EOF
If DCount("*", "d_pr_eventos", "DATA='" & rs!Data & "' And XEVENTO='" & rs!XEVENTO & "' And XPROCESSO='" & rs!XPROCESSO & "'") > 1 Then
CurrentDb.Execute "DELETE * FROM d_pr_eventos WHERE DATA='" & rs!Data & "' And XEVENTO='" & rs!XEVENTO & "' And XPROCESSO='" & rs!XPROCESSO & "'"
End If
rs.MoveNext
Loop
rs.Close
Set rs = Nothing

End Sub

Agradeço a ajuda.

Sempre que ocorrer erros, informe todos os dados sobre o mesmo por gentileza, incluindo a linha para a qual o erro aponta e tambem a descrição do mesmo. Como enes coisas podem ocasionar um mesmo tipo de erro, fica mais fácil para a gente analisar.

Linha do erro:


Sub teste()
Dim rs As Recordset
Set rs = CurrentDb.OpenRecordset("d_pr_eventos")
Do While Not rs.EOF
If DCount("*", "d_pr_eventos", "DATA='" & rs!Data & "' And XEVENTO='" & rs!XEVENTO & "' And XPROCESSO='" & rs!XPROCESSO & "'") > 1 Then
CurrentDb.Execute "DELETE * FROM d_pr_eventos WHERE DATA='" & rs!Data & "' And XEVENTO='" & rs!XEVENTO & "' And XPROCESSO='" & rs!XPROCESSO & "'"
End If
rs.MoveNext
Loop
rs.Close
Set rs = Nothing
End Sub

Agradeço desde já a ajuda.

Faça sempre backup antes de se aventurar.

Este código foi testado e está 100% funcional;

Não altere nada, supondo eu que os seus campos a analisar serão os "rst.Fields(0) & rst.Fields(1) & rst.Fields(2)"

Para chamar o Sub no evento ao pressionar de um botão, utilize;

Private Sub SeuBotão_Click()
Call DeletaDuplicatasSemChavePrimaria
End Sub

 Sub DeletaDuplicatasSemChavePrimaria()
 On Error Resume Next

  Dim db As DAO.Database, rst As DAO.Recordset
  Dim strDupName As String, strSaveName As String
  
  Set db = CurrentDb()
  Set rst = db.OpenRecordset("d_pr_eventos")
 
  If rst.BOF And rst.EOF Then
    MsgBox "Não existem registros..."
  Else
    rst.MoveFirst
    Do Until rst.EOF
      strDupName = rst.Fields(0) & rst.Fields(1) & rst.Fields(2)
      If strDupName = strSaveName Then
        rst.Delete
      Else
        strSaveName = rst.Fields(0) & rst.Fields(1) & rst.Fields(2)
      End If
      rst.MoveNext
    Loop
    
    Set rst = Nothing
    Set db = Nothing

  End If
End Sub

Não dá mensagem de erro porque tem um On Error Resume Next. Desabilite essa linha e execute novamente para ver qual erro o vba exibirá. Os nomes dos controles precisam ser os corretos tambem.

Pessoal, desculpe-me, acabei entendendo errado, vou explicar como é meu ambiente:

Trabalho como suporte de um software jurídico feito em Delphi, e o mesmo utiliza vários tipos de banco de dados, um dele o Access. Estou com o banco de um cliente em que, por algum motivo, criou alguns eventos duplicados, onde consigo lista quais são e quantas repetições, mas como são mais de 30.000 eventos para excluir, por este motivo estava procurando ou um comando ou um script que fizesse esta exclusão.

Não sei como proceder, pois trabalho a pouco tempo com Access e tem muita coisa que eu não sei fazer.

Gostaria muito da ajuda de vocês.

Fico grato desde já.

Sim,

Fiz o solicitado, mandei executar, não fez a exclusão e não gerou erro.

Vamos entender de uma só vez ????

Então vamos lá;

1º O código está a funcionar a 100%

2º Foi testado mais de 20 vezes

3º Quando eu coloquei rst.Fields(0) & rst.Fields(1) & rst.Fields(2)
Estava a supor que você teria apenas 3 campos

4º Pela imagem da sua tabela:

rst.Fields(0) = 1º Campo = DATA
rst.Fields(1) = 2º Campo = XEVENTO
rst.Fields(15) = 15º Campo = XCOMPROMISSO

JPaulo,

Fiz a alteração, mas continuo com os dados duplicados e não gerando erro.

Teria como lhe enviar a tabela para verificar?

Grato.

Basta zipar o seu banco e anexar aqui.

Segue o link para download:

http://download.virtuem.com.br/Banco_de_dados/ACCESS/projuris.rar

Grato desde já.

Amigo, use o compactar e reparar e exclua componentes desnecessários para a resolução da sua dúvida para diminuir seu aplicativo, pois o mesmo está com 490 Mb...

Bom dia,

Fiz isso antes de enviar, mas o banco tem quase 700MB, esse foi o máximo de compactação que eu consegui.

Então, exclua o que não interessa a sua dúvida...

700 megas ?????????????

Você já fez o Compactar/Reparar dentro do banco ???

Tem imagens ????

Uma dica adicional para diminuir o tamanho do arquivo: se tiver tabelas com muitas linhas de dados, exclua uma boa parte deles. Pode deixar apenas umas cinco linhas no máximo. E se tiver imagens, retire-as tambem. Depois, repita o Compactar/Reparar.

Pessoal,

Fiz a troca do arquivo, esta somente com dados a tabela que eu preciso excluir os duplicados que é a D_PR_EVENTOS.

Grato.

Ora vamos lá ver isso.....

Eu não me atrevo a limpar essa tabela.

Você tem registos em que os campos DATA,XEVENTO,XCOMPROMISSO (mencionados por si) está repetido 11 vezes, mas que toda a informação dos restantes campos não se repete.

DATA	XEVENTO	XPROCESSO	XFASE	NOTA_CUMPRIMENTO	ULTIMA_MODIFICACAO
29-06-2007	324	297	37	Peticao 156063/2007(--):  PROTOCOLO	18-05-2011 17:19:39
29-06-2007	324	297	37	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	20-01-2012 11:36:44
29-06-2007	324	297	39	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	20-01-2012 11:37:15
29-06-2007	324	297	37	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	23-01-2012 15:45:05
29-06-2007	324	297	39	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	23-01-2012 15:45:52
29-06-2007	324	297	37	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	24-01-2012 9:38:21
29-06-2007	324	297	39	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	24-01-2012 9:38:39
29-06-2007	324	297	37	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	24-01-2012 11:52:18
29-06-2007	324	297	39	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	24-01-2012 11:52:57
29-06-2007	324	297	37	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	24-01-2012 13:31:06
29-06-2007	324	297	39	Protocolo 156063/2007 (---Diversos (--)):  PROTOCOLO	24-01-2012 13:32:06

JPaulo,

Na verdades, se você verificar, existe um unico campo na maioria das linha que não muta, que é o ULTIMA_MODIFICACAO, mas este campo é somente a data que a linha foi gerada novamente, o restante das colunas estão iguais.

Bom dia,

Tente criar uma consulta usando o Dmáx no campo da última atualização.

Bom dia Fabio;

Se ainda quiser apagar os registros duplicados, fica aqui a correção do código, colocando as 3 colunas na mesma ordem Ascendente, porque a validação deste código é feita, olhando sempre para o registro anterior;

Public Sub DeletaDuplicadosSemChavePrimaria()
 On Error Resume Next

  Dim db As DAO.Database, rst As DAO.Recordset
  Dim strNome As String, strSaveName As String
  
  Set db = CurrentDb()
  Set rst = db.OpenRecordset("select * from D_PR_EVENTOS order by DATA, XEVENTO, XPROCESSO ASC;")
 
  If rst.BOF And rst.EOF Then
    MsgBox "Não existem registros..."
  Else
    rst.MoveFirst
    Do Until rst.EOF
      strDupName = rst.Fields("DATA") & rst.Fields("XEVENTO") & rst.Fields("XPROCESSO")
      If strDupName = strSaveName Then
        rst.Delete
      Else
        strSaveName = rst.Fields("DATA") & rst.Fields("XEVENTO") & rst.Fields("XPROCESSO")
      End If
      rst.MoveNext
    Loop

    Set rst = Nothing
    Set db = Nothing

  End If
End Sub

Cara, muito obrigado, funcionou muito bem.

Vlw mesmo pela ajuda.

Obrigado pelo retorno, o forum agradece.