[Resolvido]Extrair nome e sobrenome

Olá pessoal!

Como faço para extrair o nome e o sobrenome de pessoas?

Exemplo:
Se o nome for "Pedro Silva do Carmo", deve extrair "Pedro Silva"
Se o nome for "Pedro da Silva Carmo", deve extrair "Pedro da Silva"

Quero digitar o nome no campo "nome" do formulário e aí o campo "apelido" já recebe o nome extraído.

grato...

Caro Amigo,

Veja esse post abaixo se ajuda. Peguei aqui no fórum e me serviu demais.

Abraço

Olá, Finformática.

Muito bom seu exemplo. Estou trabalhando algumas adaptações aqui, pois preciso que o resultado seja conforme o exemplo na minha mensagem: Preciso que me retorne "Pedro Silva" ou "Pedro da Silva" quando tem o "da", mas seu exemplo já mim trouxe grande auxílio. Caso possa me mostrar como quero, fique a vontade enquanto tento por aqui também.

grato...

Boa tarde senhores,

Ronaldo,
pensando na sua necessidade, elaborei essa função.
Cole em um módulo:

Código:

Public Function FncNomeSobrenome(strNomeCompleto As String) As String
    'Função criado por Marcelo David
    'Data: 06/09/2021 - 15:11
    '---------------------------------------------------------------------------
    Dim strNS As String, strSN As String, bArtigo As Boolean, iAux As Integer, iISN As Integer, iFSN As Integer
    
    'Deterninando o primeiro nome:
    strNS = Mid(strNomeCompleto, 1, InStr(strNomeCompleto, " ") - 1)
    
    'A função InStr retorna a posição da primeira ocorrencia encontrada.
    'Por exemplo: Marcelo David
    'Eu quero saber qual a posição inicial do nome David (se contarmos os caracteres da esquerda para direita, será na posição 9.)
    'Aplico assim: InStr("Marcelo David","David")
    'O Resultado será 9, conforme explicação anterior
    
    'A função MID retorna parte de uma cadeia de caracteres baseado em posições predeterminadas.
    'Marcelo Dias David
    'Preciso retornar apenas Dias
    'Dias inicia na posição 9 e mais 4 caracteres para direita compõe Dias
    'Exemplo:
    'Mid("Marcelo Dias David",9 , 4)
    'Retornará Dias
    
    
    'Determinando preposições
    'Determinando "e"
    If InStr(strNomeCompleto, strNS & " e ") > 0 Then strNS = strNS & Mid(strNomeCompleto, InStr(strNomeCompleto, " e "), 2): bArtigo = True
    'Determinando "do"
    If InStr(strNomeCompleto, strNS & " do ") > 0 Then strNS = strNS & Mid(strNomeCompleto, InStr(strNomeCompleto, " do "), 3): bArtigo = True
    'Determinando "dos"
    If InStr(strNomeCompleto, strNS & " dos ") > 0 Then strNS = strNS & Mid(strNomeCompleto, InStr(strNomeCompleto, " dos "), 4): bArtigo = True
    'Determinando "da"
    If InStr(strNomeCompleto, strNS & " da ") > 0 Then strNS = strNS & Mid(strNomeCompleto, InStr(strNomeCompleto, " da "), 3): bArtigo = True
    'Determinando "das"
    If InStr(strNomeCompleto, strNS & " das ") > 0 Then strNS = strNS & Mid(strNomeCompleto, InStr(strNomeCompleto, " das "), 4): bArtigo = True
    
    'Determinar o sobrenome
    'Primeiro verifico se foi usado artigos, para saber a partir de onde é o sobrenome
    If bArtigo = True Then
        'Como foi usado artigo, sei que o sobrenome está a partir do segundo espaço em branco.
        

        'Determino o início do sobrenome
        For i = 1 To Len(strNomeCompleto)
            If Mid(strNomeCompleto, i, 1) = " " Then
                iAux = iAux + 1
            End If
            'Quando iAux for 2, significa que estamos no segundo espaço em branco, logo, teremos a referencia do inicio do sobrenome
            If iAux = 2 Then
                iISN = i
                Exit For
            End If
        Next
        
       'Como já sei onde inicio o sobrenome e o mesmo é a partir do segundo caractere em branco +1, determino o final, que está
       'dentro da cadeia de caracteres iniciado a partir do inicio do sobrenome obtido acima
       strSN = Mid(strNomeCompleto, (iISN + 1), (InStr((iISN + 1), strNomeCompleto, " ")) - (iISN + 1))
        
    End If
    
    FncNomeSobrenome = strNS & " " & strSN
End Function

Pode usar a função onde necessitar.
Por exemplo, para exibir em uma caixa de texto:

Me!SuaCaixaTexto = FncNomeSobrenome("NomeCompleto")

NomeCompleto pode ser uma variável, caixa de texto, nome direto, etc.

Teste, por gentileza.

Existe aqui desde 2009;

http://maximoaccess.forumeiros.com/t11-102-codigos-vba-para-access#14

Código: Separa Nomes

Bom dia.
Algum posicionamento nesse assunto? Algumas das instruções atendeu?

Fiz o seguinte:

Num módulo criei 3 funções.

Public Function fncSplitNome(VarNome As String)

'Pegar apenas o primeiro nome

Dim VarSplit As Variant
Dim i As Integer

VarSplit = Split(VarNome, " ")

fncSplitNome = Trim(VarSplit(0))

End Function

Public Function fncSplitNomeSeg(VarNome As String)

'Pegar apenas o primeiro nome

Dim VarSplit As Variant
Dim i As Integer

VarSplit = Split(VarNome, " ")

fncSplitNomeSeg = Trim(VarSplit(1))

End Function

Public Function fncSplitNomeTer(VarNome As String)

'Pegar apenas o primeiro nome
On Error Resume Next
Dim VarSplit As Variant
Dim i As Integer

VarSplit = Split(VarNome, " ")

fncSplitNomeTer = Trim(VarSplit(2))

End Function


No evento "ao atualizar do campo nome" coloquei o código abaixo que vai preencher o campo "apelido_func".

Dim nomeCompleto    As String
Dim nomePrimeiro    As String
Dim nomeSegundo     As String
Dim nomeTerceiro    As String

nomeCompleto = Me.func_nome
nomePrimeiro = fncSplitNome([nomeCompleto])
nomeSegundo = fncSplitNomeSeg([nomeCompleto])
nomeTerceiro = fncSplitNomeTer([nomeCompleto])

If nomeSegundo = "DO" Or nomeSegundo = "DOS" Or nomeSegundo = "DA" Or nomeSegundo = "DAS" Or nomeSegundo = "DE" Then
   Me.func_apelido = nomePrimeiro & " " & nomeSegundo & " " & nomeTerceiro
Else
   Me.func_apelido = nomePrimeiro & " " & nomeSegundo
End If

Ótimo que deu certo. Grato pelo retorno.