[Resolvido]Importar último arquivo gerado em pasta específica

Boa tarde amigos,
Tenho um pequeno banco de dados no qual faço algumas importações e exportações de planilhas de Excel.
Gostaria que ao clicar no botão "Importar Base" do meu formulário "FrmPrincipal", fosse importado o último arquivo de Excel gerado numa determinada pasta que da rede.

Poderiam me ajudar? Desde já agradeço!

Código:

Public Function ImportaUltimoFicheiroNumPasta()
'@www.maximoaccess.com
'JPaulo 2017-08-18
Dim objFSO As Object
Dim objFolder As Object
Dim objFile As Object
Dim strPath As String
Dim strPathFile As String
Dim strName As String
Dim varDate As Variant
Dim strTable As String
On Error GoTo 1
'Caminho da Pasta
strPath = "C:\Temp" 'sem a ultima barra
'Nome da sua tabela
strTable = "SuaTabela" 'Tabela já tem de existir

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strPath)

' Checka ultimo ficheiro alterado na pasta
For Each objFile In objFolder.Files
    If objFile.DateLastModified > varDate Then
    varDate = objFile.DateLastModified
    strName = objFile.Name
    End If
Next
'Obtem o caminho completo do ultimo ficheiro e nome
strPathFile = "C:\Temp\" & strName
'Importa para a tabela do banco
DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel9, strTable, strPathFile, True
     
Set objFSO = Nothing
Set objFolder = Nothing
Set objFile = Nothing

Exit_1:
    DoCmd.Hourglass False
    DoCmd.Echo True
    Exit Function

1:
    DoCmd.Hourglass False
    DoCmd.Echo True
    Msg = "Erro # " & str(Err.Number) & " gerado na " & Err.Source _
        & vbNewLine & vbNewLine & "Descrição: " & Err.Description _
        & vbNewLine & vbNewLine & "Por favor contate o Administrador do Sistema."
    MsgBox Msg, vbMsgBoxHelpButton + vbCritical, "Erro", Err.HelpFile, Err.HelpContext
    Resume Exit_1
End Function

Bom dia mestre, exatamente o que precisava.
Muito obrigado pela ajuda!

Fico feliz.

Obrigado pelo retorno o forum agradece.