[Resolvido]Abrir login fora da interface do Access

Boa Noite amigos!

Estou procurando o exemplo para deixar o BD mais profissional.

Estou com o formulário " LOGIN"

Queria que ele abrisse fora da interface do Access como se fosse uma aplicação.

* Ocultando a tela azul do Access como no exemplo do nosso amigo Silvio mais o BD dele não esta acessível a estrutura

SISTEMA DO SILVIO

Brother,


Salve as funções abaixo em módulo com o nome basAccessHider.

No evento AoAbrir dos seus forms, chame a função e opções:


Call basAccessHider.fAccessWindow("Minimize", False, False)

Código:


Option Compare Database
Option Explicit


Private Declare Function IsWindowVisible Lib "user32" (ByVal hwnd As Long) As Long
Dim dwReturn As Long

Const SW_HIDE = 0
Const SW_SHOWNORMAL = 1
Const SW_SHOWMINIMIZED = 2
Const SW_SHOWMAXIMIZED = 3

Private Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, _
    ByVal nCmdShow As Long) As Long
   
Public Function fAccessWindow(Optional Procedure As String, Optional SwitchStatus As Boolean, Optional StatusCheck As Boolean) As Boolean
If Procedure = "Hide" Then
    dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
End If
If Procedure = "Show" Then
    dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
End If
If Procedure = "Minimize" Then
    dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMINIMIZED)
End If
If SwitchStatus = True Then
    If IsWindowVisible(hWndAccessApp) = 1 Then
        dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
    Else
        dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
    End If
End If
If StatusCheck = True Then
    If IsWindowVisible(hWndAccessApp) = 0 Then
        fAccessWindow = False
    End If
    If IsWindowVisible(hWndAccessApp) = 1 Then
        fAccessWindow = True
    End If
End If
End Function


Obrigado Fera! Muito bom era o que precisava